Wie add default-Signatur in Outlook

Schreibe ich ein VBA script in Access erstellt und auto-füllt ein paar Dutzend E-Mails. Es war glatt Codierung so weit, aber ich bin neu in Outlook. Nach der Erstellung des mailitem-Objekt, wie füge ich die Standard-Signatur an die E-Mail?

Wäre dies die Standard-Signatur, die automatisch Hinzugefügt werden, beim erstellen einer neuen E-Mail.
Im Idealfall würde ich gerne, nur ObjMail.GetDefaultSignature, aber ich kann nichts finden, wie es ist.
Derzeit bin ich mit der Funktion unten (gefunden anderswo im internet) und verweisen auf den genauen Pfad & mit dem Namen der htm-Datei. Aber dies wird von mehreren Leuten benutzt wird und Sie können einen anderen Namen für Ihren Standard-HTML-Signatur-Datei. Dies funktioniert ja, aber es ist nicht ideal:
```
Function GetBoiler(ByVal sFile As String) As String
'Dick Kusleika
Dim fso As Object
Dim ts As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(sFile).OpenAsTextStream(1, -2)
GetBoiler = ts.readall
ts.Close
End Function
```
Genannt(mit getboiler(SigString = "C:\Users\" & Environ("username") & "\AppData\Roaming\Microsoft\Signatures\Mysig.txt"))

Bearbeiten

Dank JP (siehe Kommentare), merke ich, dass die Standard-Signatur zeigt sich auf den ersten, aber es verschwindet, wenn ich HTMLBody verwenden, um eine Tabelle hinzuzufügen, um die E-Mail. Also ich denke, meine Frage ist jetzt: Wie kann ich die Standard-Signatur und zeigen Sie noch eine html-Tabelle?

Sub X()
    Dim OlApp As Outlook.Application
    Dim ObjMail As Outlook.MailItem

    Set OlApp = Outlook.Application
    Set ObjMail = OlApp.CreateItem(olMailItem)

    ObjMail.BodyFormat = olFormatHTML
    ObjMail.Subject = "Subject goes here"
    ObjMail.Recipients.Add "Email goes here"

    ObjMail.HTMLBody = ObjMail.Body & "HTML Table goes here"
    ObjMail.Display

End Sub

Haben Sie ausgecheckt haben, das forum auf www.outlookcode.com es ist toll für alles, was outlook : )
Danke für den Tipp. Das führte mich zu den xtremevbtalk.com/archive/index.php/t-103235.html, wo jemand sagte, es war nicht möglich, die mit der Automatisierung. Ich bin mir sicher, dass es einen Weg gibt obwohl. Ich bin nicht die erste mit dieser Frage.
Haben Sie eine Standardsignatur für neue Nachrichten? Ich mache, wenn ich eine Nachricht programmgesteuert es wird automatisch gefüllt mit der Standard-Signatur.
Ja ich habe eine Signatur und es ist als Standard-Signatur für neue Nachrichten im Extras-Menü. Außer es ist nicht das Auffüllen der E-mail-Objekt wenn ich das erstellen von automation. Wenn Ihr mir sagen könnt, wie ich höre.
Getestet habe ich dies mit Outlook.CreateItem(olMailItem).Display im Direktfenster. Mit einer Standard-Signatur, die Meldung mit der Signatur schon da. Können Sie versuchen, den gleichen test?

InformationsquelleAutor PowerUser | 2012-01-24

47

Den folgenden code erstellen Sie eine outlook-Nachricht & halten Sie dann die auto-Signatur
```
Dim OApp As Object, OMail As Object, signature As String
Set OApp = CreateObject("Outlook.Application")
Set OMail = OApp.CreateItem(0)
    With OMail
    .Display
    End With
        signature = OMail.body
    With OMail
    '.To = "[email protected]"
    '.Subject = "Type your email subject here"
    '.Attachments.Add
    .body = "Add body text here" & vbNewLine & signature
    '.Send
    End With
Set OMail = Nothing
Set OApp = Nothing
```
Das ist ziemlich viel, was ging ich mit. Der einzige Unterschied ist, dass da meine E-Mail-body wird html verwendet habe ich .HTMLbody, nicht .body. Einfach und direkt.
Danke, das hat funktioniert für was ich war daran interessiert zu! Jeder zukünftige Nutzer, stellen Sie sicher, wenn Sie wollen, dass die .HTMLbody ändern, um es an beiden Orten.
Vielen Dank - ich bin versucht zu zählen die Anzahl der Standard-Signatur-Dateien.. also das funktioniert. .Anzeige folgte .Zählen und .Schließen Sie bekommt von mir, was ich will, aber es ist eine Art der Darstellung ausgeblendet?
Dies ist arbeiten und ich bin in der Lage, die auto-Signatur in E-Mail, aber irgendwie Unterschrift Hinzugefügt wird, auf die Spitze der E-Mail. kann mir jemand helfen zu erkennen, wie man hinzufügen, dass in das Ende.
wenn Sie verwenden möchten .HTMLbody dies ist keine saubere Lösung breause es erzeugt ungültiges HTML. Die Signatur (OMail.Körper) enthält eine Zeichenkette beginnend mit <html ... und endet mit </html> also kannst du nicht Schreibe einfach deinen text

InformationsquelleAutor Julia Jones
14

Meine Lösung ist die Anzeige ein leer Nachricht zuerst (mit Standard-Signatur!) und legen Sie die vorgesehene strHTMLBody in die bestehende HTMLBody.

Wenn, wie PowerUser Staaten, die Signatur ist ausgelöscht während der Bearbeitung HTMLBody Sie überlegen, ein speichern der Inhalte ObjMail.HTMLBody in variable strTemp sofort nach ObjMail.Display und fügen Sie strTemp danach aber das sollte nicht nötig sein.
```
Sub X(strTo as string, strSubject as string, strHTMLBody as string)

   Dim OlApp As Outlook.Application   
   Dim ObjMail As Outlook.MailItem 

   Set OlApp = Outlook.Application
   Set ObjMail = OlApp.CreateItem(olMailItem)

   ObjMail.To = strTo
   ObjMail.Subject = strSubject   
   ObjMail.Display
   'You now have the default signature within ObjMail.HTMLBody.
   'Add this after adding strHTMLBody
   ObjMail.HTMLBody = strHTMLBody & ObjMail.HTMLBody

   'ObjMail.Send 'send immediately or 
   'ObjMail.close olSave 'save as draft
   'Set OlApp = Nothing

End sub
```
Sie brauchen nicht, um die Nachricht anzuzeigen - ganz einfach Zugriff auf MailItem.GetInspector auf eine neue Nachricht, fügen Sie die Signatur. Sobald Sie haben die Signatur, Sie sollte nicht verketten von 2 HTML-strings - Sie müssen zusammengeführt werden: der einfachste Weg ist es, legen Sie Ihre HTML nach dem ersten vorkommen von ">" , folgt "<body".
Ich versuche die Objmail.GetInspecter.Activate und es sieht aus wie es tut die gleiche Sache wie Objmail.Display, so oder so, es zeigt die E-Mail (die ist für mich in Ordnung, da gibt es nicht viel zu schaffen)
Ich bin damit einverstanden - ich konnte'tfind einen Weg zu stoppen die E-Mail anzeigen
Ich Schätze, dass diese Antwort (anders als angenommen) war höflich genug, um fügen Sie einen Satz auf die Strategie, die der code verwendet, anstatt nur zu werfen Sie einen code-block, der bei Ihnen keine Erklärung überhaupt. Zugegeben, dies ist ein grundlegendes Beispiel. Aber mit einem einzigen Satz ist alles dauerte es. In der Beschreibung der Strategie vor dem eintauchen in die code ist nur eine gute Kommunikation und gute Manieren.

InformationsquelleAutor Rick van Dam

Dim OutApp As Object, OutMail As Object, LogFile As String
Dim cell As Range, S As String, WMBody As String, lFile As Long

S = Environ("appdata") & "\Microsoft\Signatures\"
If Dir(S, vbDirectory) <> vbNullString Then S = S & Dir$(S & "*.htm") Else S = ""
S = CreateObject("Scripting.FileSystemObject").GetFile(S).OpenAsTextStream(1,  -2).ReadAll

WMBody = "<br>Hi All,<br><br>" & _
         "Last line,<br><br>" & S 'Add the Signature to end of HTML Body

Dachte, ich würde teilen, wie ich dies erreichen. Nicht zu sicher, wenn es richtig in die Definition von Variablen Sinn, aber es ist klein und leicht zu Lesen, die ist, was ich mag.

Lege ich WMBody .HTMLBody innerhalb des Objekts Outlook.Anwendung OLE.

Hoffe, es hilft jemand.

Dank,
Wes.

Dies funktioniert perfekt !

InformationsquelleAutor Wesley

Baute ich diesen Ansatz, während die Suche nach gewusst wie: senden einer Nachricht auf einem sich wiederholenden Zeitplan.
Ich fand den Ansatz, wo Sie die Referenz der Inspector-Eigenschaft des erstellten Nachricht nicht fügen Sie die Signatur, die ich wollte (ich habe mehr als ein Konto einrichten in Outlook, mit separaten Signaturen.)

Den Ansatz unten ist ziemlich flexibel und dennoch einfach.

    Private Sub Add_Signature(ByVal addy as String, ByVal subj as String, ByVal body as String)
       Dim oMsg As MailItem
       Set oMsg = Application.CreateItem(olMailItem)
       oMsg.To = addy
       oMsg.Subject = subj
       oMsg.Body = body
       Dim sig As String
       ' Mysig is the name you gave your signature in the OL Options dialog 
       sig = ReadSignature("Mysig.htm")
       oMsg.HTMLBody = Item.Body & "<p><BR/><BR/></p>" & sig ' oMsg.HTMLBody
       oMsg.Send
       Set oMsg = Nothing
    End Sub

    Private Function ReadSignature(sigName As String) As String
       Dim oFSO, oTextStream, oSig As Object
       Dim appDataDir, sig, sigPath, fileName As String
       appDataDir = Environ("APPDATA") & "\Microsoft\Signatures"
       sigPath = appDataDir & "\" & sigName

       Set oFSO = CreateObject("Scripting.FileSystemObject")
       Set oTextStream = oFSO.OpenTextFile(sigPath)
       sig = oTextStream.ReadAll
       ' fix relative references to images, etc. in sig
       ' by making them absolute paths, OL will find the image
       fileName = Replace(sigName, ".htm", "") & "_files/"
       sig = Replace(sig, fileName, appDataDir & "\" & fileName)
       ReadSignature = sig
    End Function

InformationsquelleAutor Mozzis

6

Outlook fügt die Signatur der neuen unveränderten Nachrichten (die Sie nicht ändern sollten dem Körper vor, dass), wenn Sie anrufen MailItem.Display (die bewirkt, dass die Nachricht auf dem Bildschirm angezeigt werden) oder wenn Sie Zugriff auf die MailItem.GetInspector Eigenschaft - Sie nicht haben, etwas zu tun mit dem zurückgegebenen Objekt-Inspektor, aber Outlook wird das Auffüllen der Nachricht die Signatur.

Nachdem die Signatur Hinzugefügt wird, Lesen Sie die HTMLBody - Eigenschaft, und führen Sie Sie mit dem HTML-Zeichenfolge, die Sie festlegen möchten. Beachten Sie, dass Sie nicht einfach verketten von 2 HTML-strings - die Saiten müssen zusammengeführt werden. E. g. wenn Sie möchten, legen Sie die Zeichenfolge an der Spitze der HTML-Körper, der Blick für die "<body" substring, dann finden Sie das nächste vorkommen von ">" (dieser kümmert sich um die <body> element mit Attribute), dann legen Sie Ihre HTML-string nach, dass ">".

Outlook Objekt Modell nicht aussetzen Signaturen überhaupt.

Auf einen Allgemeinen Hinweis, der name ist die Signatur gespeichert, die im Konto-Profil-Daten zugänglich über die IOlkAccountManager Extended-MAPI-Schnittstelle. Da die Schnittstelle Extended MAPI, es kann nur zugegriffen werden, die mit C++ oder Delphi. Sie können sehen, die Schnittstelle und die Daten in OutlookSpy wenn Sie auf die IOlkAccountManager Taste.

Sobald Sie den Signatur-Namen, können Sie die HTML-Datei aus dem Datei-system (beachten Sie, dass der Ordner-name (Signaturen in Englisch) lokalisiert ist.

Beachten Sie auch, dass, wenn die Signatur Bilder enthält, müssen diese ebenfalls Hinzugefügt werden, um die Nachricht als Anhänge und die <img> - tags in der Signatur/Nachrichtentext angepasst, um die src Attribut der Anlagen eher als ein Unterordner der Signaturen-Ordner, wo die Bilder gespeichert werden.

Es wird auch Ihre Verantwortung sein, zu verschmelzen-die HTML-Stile, die in der Signatur HTML-Datei mit den Stilen der Nachricht selbst.

Wenn mit Erlösung ist eine option, die Sie verwenden können, seine RDOAccount Objekt (zugänglich in jeder Sprache, einschließlich VBA). Neue Nachricht-Signatur-name ist gespeichert in der 0x0016001F Eigenschaft, Antwort Signatur ist in 0x0017001F.
Sie können auch die RDOAccount.ReplySignature und NewSignature Eigenschaften.

Erlösung macht auch RDOSignature.ApplyTo Methode, die einen Zeiger auf die RDOMail - Objekt und fügt die Signatur an die angegebene Speicherort korrekt Zusammenführen der Bilder und die styles:
```
set Session = CreateObject("Redemption.RDOSession")
Session.MAPIOBJECT = Application.Session.MAPIOBJECT
set Drafts = Session.GetDefaultFolder(olFolderDrafts)
set   Msg = Drafts.Items.Add
Msg.To =   "[email protected]"
Msg.Subject =   "testing signatures"
Msg.HTMLBody =   "<html><body>some <b>bold</b> message text</body></html>"
set Account = Session.Accounts.GetOrder(2).Item(1)   'first mail account
if  Not (Account  Is  Nothing)  Then
   set Signature = Account.NewMessageSignature
   if  Not (Signature  Is  Nothing)  Then
    Signature.ApplyTo Msg,  false   'apply at the bottom
   End If
End If
Msg.Send
```
BEARBEITEN: Juli 2017, MailItem.GetInspector im Outlook 2016 nicht mehr fügt die Signatur. Nur MailItem.Display tut.

FFS Microsoft ist eine einfache Methode zum hinzufügen des Standard-Signatur für das aktuelle Profil, um eine E-Mail an wirklich, dass viel von einem Schmerz?

InformationsquelleAutor Dmitry Streblechenko
4

Ich habe eine Community-Wiki-Antwort, denn ich konnte es nicht geschaffen haben, ohne PowerUser Forschung und die Hilfe, die in früheren Kommentaren.

Nahm ich PowerUser ist Sub X und Hinzugefügt
```
Debug.Print "n------"    'with different values for n
Debug.Print ObjMail.HTMLBody
```
nach jeder Anweisung. Von dieser entdeckte ich die Signatur nicht innerhalb von .HTMLBody bis nach ObjMail.Display - und auch nur dann, wenn ich noch nicht alles zugegeben, um den Körper.

Ging ich zurück zum PowerUser die frühere Lösung, die verwendet werden C:\Users\" & Environ("username") & "\AppData\Roaming\Microsoft\Signatures\Mysig.txt"). PowerUser war unglücklich, weil er wollte, dass seine Lösung für andere zu arbeiten, wer würde haben unterschiedliche Signaturen.

Meine Signatur ist im gleichen Ordner und ich finde keine option um dies zu ändern Ordner. Ich habe nur eine Signatur, so dass durch das Lesen die einzige HTM-Datei in diesem Ordner, erhielt ich mein nur/Standard-Signatur.

Erstellte ich eine HTML-Tabelle eingefügt und es in die Signatur unmittelbar nach dem <body> - element, und legen Sie die html-Körper zur Folge haben. Ich schickte die E-Mail an mich und das Ergebnis war durchaus akzeptabel, vorausgesetzt, Sie wie meine Formatierung, die ich aufgenommen, um zu überprüfen, dass ich konnte.

Meiner modifizierten Unterprogramm:
```
Sub X()

  Dim OlApp As Outlook.Application
  Dim ObjMail As Outlook.MailItem

  Dim BodyHtml As String
  Dim DirSig As String
  Dim FileNameHTMSig As String
  Dim Pos1 As Long
  Dim Pos2 As Long
  Dim SigHtm As String

  DirSig = "C:\Users\" & Environ("username") & _
                               "\AppData\Roaming\Microsoft\Signatures"

  FileNameHTMSig = Dir$(DirSig & "\*.htm")

  ' Code to handle there being no htm signature or there being more than one

  SigHtm = GetBoiler(DirSig & "\" & FileNameHTMSig)
  Pos1 = InStr(1, LCase(SigHtm), "<body")

  ' Code to handle there being no body

  Pos2 = InStr(Pos1, LCase(SigHtm), ">")

  ' Code to handle there being no closing > for the body element

   BodyHtml = "<table border=0 width=""100%"" style=""Color: #0000FF""" & _
         " bgColor=#F0F0F0><tr><td align= ""center"">HTML table</td>" & _
         "</tr></table><br>"
  BodyHtml = Mid(SigHtm, 1, Pos2 + 1) & BodyHtml & Mid(SigHtm, Pos2 + 2)

  Set OlApp = Outlook.Application
  Set ObjMail = OlApp.CreateItem(olMailItem)
  ObjMail.BodyFormat = olFormatHTML
  ObjMail.Subject = "Subject goes here"
  ObjMail.Recipients.Add "my email address"
  ObjMail.Display

End Sub
```
Da beide PowerUser und ich gefunden haben unsere Unterschriften in C:\Users\" & Environ("username") & "\AppData\Roaming\Microsoft\Signatures ich schlage vor, dies ist der standard-Speicherort für jede Outlook-installation. Kann diese Standardeinstellung geändert werden? Ich kann nicht finden, etwas zu suggerieren, was es kann. Der obige code klar braucht es eine gewisse Entwicklung, aber es hat erreichen PowerUser Ziel der Schaffung eines E-Mail-Text mit einem HTML-Tabelle über eine Signatur.

Ich bin froh, Sie gefunden zu meinem Beitrag nützlich, aber ich bin auf der Suche nach etwas direkter. Ein Mitarbeiter wies darauf hin, dass ein Benutzer legen Sie die Standard-Signatur manuell über die commandbar Einfügen->Signaturen->(erste Unterschrift). Wie kann ich das in code? Ich experimentiere mit Kontrollen und Commandbars, aber nicht viel Fortschritte.
Ich bin mir nicht sicher was du meinst mit "direkter". Dieser code erstellt eine Tabelle über eine Signatur, die ist, was Sie wollte. Ich Stimme zu es ist nur ein dummy-Tabelle, aber ich weiß nicht, wo der eigentliche Tisch ist, zu kommen.

InformationsquelleAutor
4

Ich einen Weg herausgefunden, aber es ist vielleicht zu schlampig für die meisten. Ich habe eine einfache Db und ich will, dass es in der Lage sein zum generieren von E-Mails für mich, also hier die down and dirty Lösung, die ich verwendet:

Fand ich, dass der Anfang des body-Textes ist der einzige Ort, sehe ich die "<div class=WordSection1>" in den HTMLBody einer neuen E-Mail, so habe ich nur eine einfache ersetzen, ersetzen

"<div class=WordSection1><p class=MsoNormal><o:p>"

mit

"<div class=WordSection1><p class=MsoNormal><o:p>" & sBody

wo sBody ist der Körper, der Inhalt will ich eingefügt. Scheint soweit zu funktionieren.
```
.HTMLBody = Replace(oEmail.HTMLBody, "<div class=WordSection1><p class=MsoNormal><o:p>", "<div class=WordSection1><p class=MsoNormal><o:p>" & sBody)
```
Dies funktioniert HERVORRAGEND für mich! Weit entfernt von schnell und schmutzig, das war die elegante Antwort von allen. Wie bereits erwähnt, nur daran erinnern, zu nennen .Anzeige bevor rufen Sie die Funktion oben gezeigt, ansonsten gibt es keine Unterschrift eingefügt doch.

InformationsquelleAutor Eliot K
3

Ich brauche 50 rep, um einen Kommentar gegen die Signatur-Option fand ich sehr hilfreich, jedoch hatte ich ein Problem mit Bildern, die nicht korrekt angezeigt, so hatte ich, eine Arbeit zu finden um. Dies ist meine Lösung:

@Morris Maynard Antwort als Basis https://stackoverflow.com/a/18455148/2337102 ich musste dann gehen Sie durch die folgenden:

Hinweise:

Sichern .htm-Datei, bevor Sie beginnen, kopieren & einfügen in eine sekundäre Ordner
1. Arbeiten Sie mit der SignatureName.htm und die SignatureName_files Folder
2. Brauchen Sie nicht HTML Erfahrung, die Dateien öffnen sich in einem editing-Programm wie Notepad oder Notepad++ oder Ihre angegebene HTML-Programm
3. Navigieren Sie zu Ihrer Signatur-Datei Speicherort (standard sollte sein C:\Users\"username"\AppData\Roaming\Microsoft\Signatures)
4. Öffnen Sie die SignatureName.htm - Datei in einem text - /HTML-editor (Rechtsklick auf die Datei, "Bearbeiten" mit Programm")
5. Verwenden Ctrl+F und geben Sie .png; .jpg oder wenn Sie nicht wissen, Ihre Bild-Typ, verwenden image001
  Sie sehen etwas wie: src="signaturename_files/image001.png"
6. Müssen Sie ändern, um die gesamte Adresse der Speicherort des Bildes
  C:\Users\YourName\AppData\Roaming\Microsoft\Signatures\SignatureNameFolder_files\image001
  
  oder
  
  src="E:\location\Signatures\SignatureNameFolder_files\image001.png"
7. Speichern Sie Ihre Datei (überschreiben, Sie hatte natürlich gesichert das original)
8. Zurück zu Outlook, und Öffnen Sie eine Neue E-Mail-Element, fügen Sie Ihre Unterschrift. Ich erhielt eine Warnung, dass die Dateien geändert wurden, habe ich auf ok geklickt, ich musste das tun dies zweimal, dann einmal auf den "Signaturen Bearbeiten-Menü".
  
  Some of the files in this webpage aren't in the expected location. Do you want to download them anyway? If you're sure the Web page is from a trusted source, click Yes."
9. Führen Sie Ihr Makro-Ereignis, die Bilder sollten jetzt angezeigt werden.
Kredit

MrExcel - VBA-code-Signatur-code Fehler: http://bit.ly/1gap9jY

So, Ihr Vorschlag ist wie hinzufügen von Bildern zu einer Unterschrift. Interessant. Wenn ich die Frage gepostet, die ursprünglich, ich dachte nur über text-Signaturen. Aber dies könnte nützlich sein, auf andere Weise. Danke.
vielen Dank für die Kommentare. Es sei denn, Sie wissen, HTML-code, es ist am besten, wenn Sie legen Sie die Bilder während der Erstellung der Signatur in OL. Einige meiner sigs haben Sie, andere nicht. Meine nicht-Standard-sig hat die Bilder, die ist, warum ich war auf der Jagd für eine Lösung. 🙂 Deine Frage ist die am häufigsten verwendete und gerichtet, um für die Menschen zu wollen, Signaturen hinzufügen, mithilfe von VBA. Ich dachte, es kann durchaus sinnvoll sein, für einige. 🙂 Ich hoffe, es hilft anderen, die kommen auf der Suche. Haben Sie einen großen Tag!

InformationsquelleAutor MrsAdmin

Meisten anderen Antworten sind einfach die Verkettung zu Ihren HTML-body mit den HTML-Signatur. Dies bedeutet jedoch nicht, arbeiten mit Bildern, und es stellt sich heraus, es ist eine "standard" - Weg, dies zu tun.Eins

Microsoft Outlook-pre-2007, die konfiguriert ist, mit WordEditor die editor, und Microsoft Outlook 2007 und darüber hinaus, mit einem leicht cut-down-version der Word-Editor zum Bearbeiten von E-Mails. Das heißt, wir können die Microsoft Word-Dokument-Objekt-Modell, um änderungen an der E-Mail.

Set objMsg = Application.CreateItem(olMailItem)
objMsg.GetInspector.Display 'Displaying an empty email will populate the default signature
Set objSigDoc = objMsg.GetInspector.WordEditor
Set objSel = objSigDoc.Windows(1).Selection
With objSel
   .Collapse wdCollapseStart
   .MoveEnd WdUnits.wdStory, 1
   .Copy 'This will copy the signature
End With
objMsg.HTMLBody = "<p>OUR HTML STUFF HERE</p>"
With objSel
   .Move WdUnits.wdStory, 1 'Move to the end of our new message
   .PasteAndFormat wdFormatOriginalFormatting 'Paste the copied signature
End With 
'I am not a VB programmer, wrote this originally in another language so if it does not
'compile it is because this is my first VB method :P

Microsoft Outlook 2007 Programming (S. Mosher)> Kapitel 17 Arbeiten mit Element Körper: Arbeiten mit Outlook-Signaturen

InformationsquelleAutor Birdie

Ich mag Mozzi's Antwort fand aber, dass es nicht beibehalten haben die Standard-Schriftarten, die Benutzer-spezifisch sind. Der text erschien in einer system-schriftart als normaler text. Der code unten behält der Benutzer die Lieblings-Schriftarten, und machen es nur ein wenig länger. Es basiert auf Mozzi's Ansatz, verwendet einen regulären Ausdruck, um ersetzen Sie die Standard-text und stellen dem Benutzer ausgewählte text, wo es hingehört, durch die Verwendung von GetInspector.WordEditor. Ich fand, dass der Aufruf von GetInspector hat nicht füllen Sie den HTMLbody wie dimitry streblechenko sagt oben in diesem thread, zumindest nicht in Office 2010, damit Sie das Objekt immer noch angezeigt in meinem code. Im Vorbeigehen, beachten Sie bitte, dass es wichtig ist, dass das MailItem erstellt wird, als Objekt, nicht als eine einfache MailItem - siehe hier für mehr. (Oh, und sorry an alle von verschiedenen Geschmack, aber ich bevorzuge mehr beschreibende Variablen-Namen, so dass ich finden kann, Routinen!)

Public Function GetSignedMailItemAsObject(ByVal ToAddress As String, _
                      ByVal Subject As String, _
                      ByVal Body As String, _
                      SignatureName As String) As Object
'================================================================================================================='Creates a new MailItem in HTML format as an Object.
'Body, if provided, replaces all text in the default message.
'A Signature is appended at the end of the message.
'If SignatureName is invalid any existing default signature is left in place.
'=================================================================================================================
' REQUIRED REFERENCES
' VBScript regular expressions (5.5)
' Microsoft Scripting Runtime
'=================================================================================================================
Dim OlM As Object               'Do not define this as Outlook.MailItem.  If you do, some things will work and some won't (i.e. SendUsingAccount)
Dim Signature As String
Dim Doc As Word.Document
Dim Regex As New VBScript_RegExp_55.RegExp       '(can also use use Object if VBScript is not Referenced)

Set OlM = Application.CreateItem(olMailItem)
With OlM
    .To = ToAddress
    .Subject = Subject
    'SignatureName is the exactname that you gave your signature in the Message>Insert>Signature Dialog
    Signature = GetSignature(SignatureName)
    If Signature <> vbNullString Then
'        Should really strip the terminal </body tag out of signature by removing all characters from the start of the tag
'        but Outlook seems to handle this OK if you don't bother.
        .Display                                'Needed.  Without it, there is no existing HTMLbody available to work with.
        Set Doc = OlM.GetInspector.WordEditor   'Get any existing body with the WordEditor and delete all of it
        Doc.Range(Doc.Content.Start, Doc.Content.End) = vbNullString 'Delete all existing content - we don't want any default signature
        'Preserve all local email formatting by placing any new body text, followed by the Signature, into the empty HTMLbody.
        With Regex
            .IgnoreCase = True                  'Case insensitive
            .Global = False                     'Regex finds only the first match
            .MultiLine = True                   'In case there are stray EndOfLines (there shouldn't be in HTML but Word exports of HTML can be dire)
            .Pattern = "(<body.*)(?=<\/body)"   'Look for the whole HTMLbody but do NOT include the terminal </body tag in the value returned
            OlM.HTMLbody = .Replace(OlM.HTMLbody, "$1" & Signature)
        End With ' Regex
        Doc.Range(Doc.Content.Start, Doc.Content.Start) = Body 'Place the required Body before the signature (it will get the default style)
        .Close olSave                           'Close the Displayed MailItem (actually Object) and Save it.  If it is left open some later updates may fail.
    End If ' Signature <> vbNullString
End With ' OlM
Set GetSignedMailItemAsObject = OlM
End Function

Private Function GetSignature(sigName As String) As String
Dim oTextStream As Scripting.TextStream
Dim oSig As Object
Dim appDataDir, Signature, sigPath, fileName As String
Dim FileSys As Scripting.FileSystemObject        'Requires Microsoft Scripting Runtime to be available
    appDataDir = Environ("APPDATA") & "\Microsoft\Signatures"
    sigPath = appDataDir & "\" & sigName & ".htm"
    Set FileSys = CreateObject("Scripting.FileSystemObject")
    Set oTextStream = FileSys.OpenTextFile(sigPath)
    Signature = oTextStream.ReadAll
    ' fix relative references to images, etc. in Signature
    ' by making them absolute paths, OL will find the image
    fileName = Replace(sigName, ".htm", "") & "_files/"
    Signature = Replace(Signature, fileName, appDataDir & "\" & fileName)
    GetSignature = Signature
End Function

InformationsquelleAutor Neil Dunlop

0

Oft wird diese Frage im Kontext von Ron de Bruin - RangeToHTML - Funktion, die erstellt eine HTML - PublishObject aus einer Excel.Range Extrakte, die über FSO, und fügt den resultierenden stream HTML in der E-Mail HTMLBody. In doing so, das entfernt die Standard-Signatur (die RangeToHTML Funktion ist eine Hilfsfunktion, die GetBoiler versucht, legen Sie die Standard-Signatur).

Leider schlecht dokumentiert Application.CommandBars Methode ist nicht per Outlook:
```
wdDoc.Application.CommandBars.ExecuteMso "PasteExcelTableSourceFormatting"
```
Wird es werfen eine Laufzeit 6158:

Aber wir können immer noch nutzen Sie die Word.Document die zugänglich ist über das MailItem.GetInspector Methode, die wir tun können, so etwas zu kopieren & einfügen der Auswahl von Excel zu Outlook-E-Mail-Körper konservieren Sie Ihre Standard-Signatur (wenn es eine ist).
```
Dim rng as Range
Set rng = Range("A1:F10") 'Modify as needed

With OutMail
    .To = "[email protected]"
    .BCC = ""
    .Subject = "Subject"
    .Display
    Dim wdDoc As Object     '## Word.Document
    Dim wdRange As Object   '## Word.Range
    Set wdDoc = OutMail.GetInspector.WordEditor
    Set wdRange = wdDoc.Range(0, 0)
    wdRange.InsertAfter vbCrLf & vbCrLf
    'Copy the range in-place
    rng.Copy
    wdRange.Paste
End With
```
Beachten Sie, dass in einigen Fällen kann dies nicht perfekt zu bewahren, die Spaltenbreite oder in einigen Fällen die Zeilenhöhe, und während es auch kopieren, Formen und andere Objekte im Excel-Bereich, kann dies auch dazu führen, einige funky Ausrichtung Probleme, aber für einfache Tabellen und Excel-Bereiche, es ist sehr gut:

InformationsquelleAutor David Zemens

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.