Wie berechne MIPS von meinem Prozessor?

In Einklang mit dem, was Sie wollte, hier einige bootloader-code, der ausgeführt wird, um eine Art benchmark, der kann wahrscheinlich verwendet, um zu Messen die MIPS-in einer Art und Weise. Das Hauptziel hier war, wird low-level, und ich glaube, dies ist die niedrigste Ebene, auf der Sie können tatsächlich Programmieren mit dem PC, es sei denn, Sie bereit sind, ersetzen Sie Ihre BIOS oder so etwas.

Sowieso, das ist der code für ein floppy-image, das, wenn Sie gebootet ist, werden versuchen zu führen vier Befehle (zwei adds, einem sub, und ein bedingter Sprung) eine million mal. Wie oft die Anweisungen ausgeführt werden, gesteuert wird durch die ITERS makro. Durch anheben oder absenken können Sie angeben, wie viele Iterationen gemacht werden soll.

Zeit gemessen, indem die rdtsc Anweisung gibt die Anzahl der Prozessor-ticks seit Ihrer power-up, da eine 64-bit-Zahl im Register edx und eax. Durch die Berechnung der Differenz von diesem Wert vor der Ausführung der Schleife, und bevor, wir die Anzahl der ticks, die der Prozessor für die Ausführung gebraucht haben. Dieser Wert wird dann auf dem Bildschirm ausgegeben werden, mithilfe der BIOS-10h anrufen als hexadezimal-Wert. Die tatsächliche Zeit, die darauf verbracht wird, offensichtlich ist, abhängig von der Prozessor-clock Frequenz.

Hier ist die Quelle. Wenn Sie, kompilieren Sie es mit NASM mit -f bin erhalten Sie das floppy-image, das sollte dann geschrieben werden, um eine Diskette mit einigen raw-block-writing-Programm, zum Beispiel dd. Dann, beim Booten, wählen Sie das Diskettenlaufwerk als boot-medium. Alle, die arbeiten möglicherweise auch mit einem USB-Laufwerk, aber das ist viel mehr BIOS-abhängig. Wie bei allen Sachen, die so low-level, ich übernehme keine Verantwortung für die Ergebnisse tatsächlich ausführen dieser software auf Ihrem computer.

bits 16
org 0x7c00

ITERS equ 1000000

jmp 0x0000:start

start:
    cli
    xor ax, ax
    mov ds, ax
    mov ss, ax
    mov sp, stack_end

    rdtsc
    mov [old_rdtsc], eax
    mov [old_rdtsc+4], edx
    mov eax, ITERS

.loop:
    add ebx, ecx
    add ecx, edx

    sub eax, 1
    jnz .loop

    rdtsc

    sub eax, [old_rdtsc]
    sbb edx, [old_rdtsc+4]

    mov si, 15

.fillbuf_eax:
    mov edi, eax
    shr eax, 4
    and di, 0xf
    mov bl, [hex_chars+di]
    mov [str_buf+si], bl
    sub si, 1
    cmp si, 7
    ja .fillbuf_eax

.fillbuf_edx:
    mov edi, edx
    shr edx, 4
    and di, 0xf
    mov bl, [hex_chars+di]
    mov [str_buf+si], bl
    sub si, 1
    jns .fillbuf_edx

    mov ah, 0xe
    xor bx, bx
.bios_write:
    pusha
    mov al, [str_buf+bx]
    int 10h
    popa
    add bx, 1
    cmp bx, 16
    jb .bios_write

    sti

.halt:
    hlt
    jmp .halt

hex_chars db "0123456789ABCDEF"
old_rdtsc resq 1
str_buf resb 16

STACK_SIZE equ 200
stack resb STACK_SIZE
stack_end equ $

times 510-($-$$) db 0x90
db 0x55, 0xaa

Auf meinem ziemlich alten AMD Athlon XP 1700+, ich bekomme 0x1e8596 als Ergebnis der Ausführung dieses Codes, die gleich 2000278 CPU-Zeiteinheiten. Wie läuft die CPU auf 1466MHz, das ist mehr oder weniger gleich etwa 1,36 ms.

InformationsquelleAutor Daniel Kamil Kozar

Gibt es eine Liste von MIPS von processortype auf eine bestimmte GHZ finden Sie auf

http://en.wikipedia.org/wiki/Instructions_per_second

Ansonsten können Sie das Programm der benchmark und ausführen (in einer Konsole, ohne viel laufen) oder laden Sie die benchmark von irgendwo adn führen, dass.....

InformationsquelleAutor IvoTops