Wie das abfangen und manipulieren von Internet Explorer popup mit VBA

Hier ist etwas code, den ich verwenden, um ein IE-Fenster aus dem Titel. Es ist aufgeteilt in zwei Funktionen, da einer meiner Benutzer hatte ein extrem seltsames problem, wo ein Fehler war, nicht erwischt zu werden, richtig. Möglicherweise (wahrscheinlich) in der Lage sein, den Körper zu bewegen, von der eigenen Funktion in der öffentlichen Funktion.

Darüber hinaus müssen Sie einen Verweis auf Microsoft Internet Controls (dies ist entweder shdocvw.dll oder ieframe.dll je nach Ihrer version von Windows) und ich würde empfehlen die Einstellung einen Verweis auf die Microsoft HTML Object Library, die es leichter machen, die zum Durchlaufen des DOM-nachdem Sie Ihre IE-Objekt.

Function oGetIEWindowFromTitle(sTitle As String, _
                               Optional bCaseSensitive As Boolean = False, _
                               Optional bExact As Boolean = False) As SHDocVw.InternetExplorer

    Dim objShellWindows As New SHDocVw.ShellWindows
    Dim found As Boolean
    Dim startTime As Single

    found = False
    'Loop through shell windows
    For Each oGetIEWindowFromTitle In objShellWindows
        found = oGetIEWindowFromTitleHandler(oGetIEWindowFromTitle, sTitle, bCaseSensitive, bExact)
        If found Then Exit For
    Next

    'Check whether a window was found
    If Not found Then
        Set oGetIEWindowFromTitle = Nothing
    Else
        pauseUntilIEReady oGetIEWindowFromTitle
    End If

End Function

Private Function oGetIEWindowFromTitleHandler(win As SHDocVw.InternetExplorer, _
                                      sTitle As String, _
                                      bCaseSensitive As Boolean, _
                                      bExact As Boolean) As Boolean

    oGetIEWindowFromTitleHandler = False

    On Error GoTo handler
    'If the document is of type HTMLDocument, it is an IE window
    If TypeName(win.Document) = "HTMLDocument" Then
        'Check whether the title contains the passed title
        If bExact Then
            If (win.Document.title = sTitle) Or ((Not bCaseSensitive) And (LCase(sTitle) = LCase(win.Document.title))) Then oGetIEWindowFromTitleHandler = True
        Else
            If InStr(1, win.Document.title, sTitle) Or ((Not bCaseSensitive) And (InStr(1, LCase(win.Document.title), LCase(sTitle), vbTextCompare) <> 0)) Then oGetIEWindowFromTitleHandler = True
        End If
    End If
handler:
    'We assume here that if an error is raised it's because
    'the window is not of the correct type. Therefore we
    'simply ignore it and carry on.

End Function

Verwenden Sie den obigen code wie folgt:

Sub test()

    Dim ie As SHDocVw.InternetExplorer
    Dim doc As HTMLDocument 'If you have a reference to the HTML Object Library
    'Dim doc as Object 'If you do not have a reference to the HTML Object Library

    ' Change the title here as required
    Set ie = oGetIEWindowFromTitle("My popup window")
    Set doc = ie.Document

    Debug.Print doc.getElementsByTagName("body").Item(0).innerText

End Sub

Finden Sie ein Fenster aus, nahezu jede Eigenschaft des Fensters, oder es ist Dokument Inhalt. Wenn Sie kämpfen mit diesem, bitte kommentieren :).