Wie effizient erstellen von lag-Variablen mit Stata

Ich habe panel Daten (Zeit: Datum, name: - ticker). Ich will 10 lags der Variablen x und y. Jetzt erstelle ich jede lag-variable nacheinander mit den folgenden code:

by ticker: gen lag1 = x[_n-1]

Allerdings, das sieht unordentlich aus.

Kann mir jemand sagen wie kann ich das erstellen von lag-Variablen effizienter zu gestalten, bitte?

Soll ich eine Schleife verwenden, oder hat Stata ein effizienter Umgang mit dieser Art von problem?

InformationsquelleAutor fly36 | 2015-07-05

  1. 5

    @Robert hat Euch gezeigt, dem stromlinienförmigen Weg, es zu tun. Zum Abschluss, hier ist die "traditionelle", langweilig Weg:

    clear
set more off

*----- example data -----

set obs 2

gen id = _n
expand 20

bysort id: gen time = _n
tsset id time

set seed 12345
gen x = runiform()
gen y = 10 * runiform()

list, sepby(id)

*----- what you want -----

//"traditional" loop
forvalues i = 1/10 {
     gen x_`i' = L`i'.x
     gen y_`i' = L`i'.y
}

list, sepby(id)

    Sowie eine Kombination:

    //a combination
foreach v in x y {
    tsrevar L(1/10).`v'
    rename (`r(varlist)') `v'_#, addnumber
}

    Wenn der Zweck ist, zu erstellen verzögerten Variablen, um Sie in einige Schätzung, wissen, können Sie Zeit-Serie-Betreiber in vielen Abschätzung Befehle direkt; das heißt, keine Notwendigkeit zu schaffen, die verzögerten Variablen in den ersten Platz. Sehen help tsvarlist.

    InformationsquelleAutor Roberto Ferrer

  2. 5

    Können Sie mit einer Schleife um dies zu tun, aber Sie können auch die Vorteile tsrevar zu erzeugen temporäre verzögerten Variablen. Wenn Sie brauchen, permanente Variablen, die Sie verwenden können rename group Sie umbenennen.

    clear
set obs 2
gen id = _n
expand 20
bysort id: gen time = _n
tsset id time
set seed 12345
gen x = runiform()
gen y = 10 * runiform()
tsrevar L(1/10).x
rename (`r(varlist)') x_#, addnumber
tsrevar L(1/10).y
rename (`r(varlist)') y_#, addnumber

    Beachten Sie, dass, wenn Sie tun, diese zu berechnen, eine Statistik, die auf einem rollenden Fenster, check-out tsegen (aus SSC)

    InformationsquelleAutor Robert Picard

Schreibe einen Kommentar