Wie erstellen Preloader in AS3

Update:

Option 1. IDE Flash eine swf-Datei

Haben ein eingebettetes preloader beim kompilieren mit Flash-IDE, sollten Sie Ihre Document Class code auf den 2. frame der FLA-Datei (ohne Paket und die Klasse Konstruktor, natürlich), und entfernen Sie Document Class .als Datei von der Projekt-Eigenschaften. In den ersten frame legen Sie bitte diesen code:

stop(); //stops the timeline at preloader frame
this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
function onProgress(e:ProgressEvent):void {
    var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
    //additional code to update preloader graphics
    //..
    if (percent == 100) onLoaded();
}
function onLoaded() {
   this.loaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
   nextFrame();
}

Sobald die swf-Datei geladen wird, rückt er auf das nächste Bild und der original-Anwendung code für die Initialisierung ausgeführt werden soll.
Dies funktioniert gut, wenn Sie organisiert Ihr Projekt in einer Weise, dass die meisten assets (Bilder, etc) sind in der Flash-IDE-Bibliothek und werden nicht geladen, auf dem ersten Bild (Sie können überprüfen, dass in jedem library-Eintrag der Eigenschaften).

Option 2. Flash-IDE, zwei swf-Dateien

Andere Möglichkeit, wie schon empfohlen, von einem anderen Kommentator, ist zu halten Sie Ihre Anwendung, swf, wie es ist, und erstellen Sie einen anderen LDAP-swf-Datei geladen, die erste.
Den code des Preloaders.swf im ersten frame:

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
loader.load(new URLRequest("path/to/application.swf"));

function onProgress(e:ProgressEvent):void
{
   var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
   //additional code to update preloader graphics
   //..
   if (percent == 100) onLoaded();
}
function onLoaded():void
{
   loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
   var application:DisplayObject = loader.content;
   addChild(application);
}

Manchmal gibt es zusätzliche Probleme mit diesem Ansatz, wenn Sie versuchen, Zugriff stage von Ihrem Document Class constructor etc, aber für die meisten Fälle sollte die Arbeit machen.

Option 3. Verschiedene IDE, meine Empfehlung: FlashDevelop

Wenn Sie versucht zu kompilieren mein Zitat-code mit FlashDevelop, Flash Builder oder anderen IDE, sollte es funktionieren.

Original post:

Hier ist ein einfaches setup für eine embedded-preloader. Ihre Document Class sollte wie folgt Aussehen:

package {

  import flash.display.Sprite;

  [Frame(factoryClass='Preloader')] //class name of your preloader

  public class Main extends Sprite {

     public function Main() {
        //init
     }
  }
}

Preloader-Klasse:

package {

   import flash.display.DisplayObject;
   import flash.display.MovieClip;
   import flash.events.ProgressEvent;
   import flash.utils.getDefinitionByName;

  public class Preloader extends MovieClip {

     public function Preloader()
     {
        //add preloader graphics 

        //check loading progress
        this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
     }
     private function onProgress(e:ProgressEvent):void 
     {
        var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
        if (percent == 100)
        {
          this.loaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
          onLoaded();
        }
     }
     private function onLoaded():void
     {
       nextFrame(); //go to next frame
       var App:Class = getDefinitionByName("Main") as Class; //class of your app
       addChild(new App() as DisplayObject);
     }
  }
}

InformationsquelleAutor package

Hier ist der Artikel how to create eingebettet as3 preloader
http://www.kirupa.com/forum/showthread.php?351689-actionscript-preloader-in-flash-develop

InformationsquelleAutor zaynyatyi

[Frame(factoryClass='Preloader')] funktioniert nicht mehr in das neue ASC-2.0-compiler. Statt, der preloader wird Ihr Dokument der Klasse, und Sie brauchen, um eine Zusätzliche Compiler-Argument zu sagen, flash, um Ihre main-Klasse auf dem zweiten Rahmen (nicht Referenz es im preloader):

-frame=NameDoesntMatter,Main

Hat ASC 2.0 erkennen [Frame] - Metadaten-tags (ex: für Preloader factoryClass)?

ASC2.0 und Frame-metatag

InformationsquelleAutor Sarah Northway