Wie füge ich Linien oben und unten eine Datei in Perl?

Vom perlfaq5's Antwort auf Wie kann ich das ändern, löschen oder einfügen einer Zeile in eine Datei oder Anhängen an den Anfang einer Datei?

Wie kann ich das ändern, löschen oder einfügen einer Zeile in eine Datei oder Anhängen an den Anfang einer Datei?

(beigetragen von brian d foy)

Die grundlegende Idee, einfügen, ändern oder löschen einer Zeile aus einer text-Datei beinhaltet das Lesen und drucken der Datei zu der Stelle, die Sie wollen, um die änderung, der änderung, dann Lesen und ausdrucken der rest der Datei. Perl nicht zufällig Zugang zu den Linien (vor allem, da der Datensatz input-separator, $/, ist stummschaltbar), obwohl die Module wie Tie::File können fake it.

Einem Perl-Programm zu tun, diese Aufgaben nimmt die Grundform des öffnens einer Datei -, Druck-Linien, dann die Datei schließen:

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

while( <$in> )
    {
    print $out $_;
    }

close $out;

Innerhalb dieses basic-form, fügen Sie die Teile, die Sie benötigen einfügen, ändern oder löschen von Zeilen.

Voranstellen Zeilen an den Anfang, drucken Sie die Zeilen, bevor Sie die Schleife druckt den bestehenden Linien.

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC

while( <$in> )
    {
    print $out $_;
    }

close $out;

Ändern bestehender Linien, fügen Sie den code zum ändern der Zeilen innerhalb der while-Schleife. In diesem Fall, den code findet alle kleingeschrieben Versionen von "perl" und uppercases. Das geschieht für jede Zeile, so werden Sie sicher, dass Sie tun sollen, dass auf jeder Linie!

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n";

while( <$in> )
    {
    s/\b(perl)\b/Perl/g;
    print $out $_;
    }

close $out;

Ändern, nur eine bestimmte Zeile der Eingabe Zeilennummer, $., ist nützlich. Erst Lesen und drucken die Zeilen bis zu der, die Sie ändern möchten. Als Nächstes Las die einzige Zeile, die Sie ändern möchten, ändern Sie es und drucken Sie es. Danach Lesen Sie den rest der Zeilen und drucken diese:

while( <$in> )   # print the lines before the change
    {
    print $out $_;
    last if $. == 4; # line number before change
    }

my $line = <$in>;
$line =~ s/\b(perl)\b/Perl/g;
print $out $line;

while( <$in> )   # print the rest of the lines
    {
    print $out $_;
    }

Überspringen Linien, verwenden Sie die Schleife steuert. Die next in diesem Beispiel überspringt Kommentarzeilen, und der Letzte Stoppt die Verarbeitung, sobald es auf entweder ENDE oder DATEN.

while( <$in> )
    {
    next if /^\s+#/;             # skip comment lines
    last if /^__(END|DATA)__$/;  # stop at end of code marker
    print $out $_;
    }

Tun die gleiche Art von Sache, die Sie zum löschen einer bestimmten Zeile, indem Sie mit weiter überspringen die Zeilen, die Sie nicht wollen, zu zeigen, bis in den Ausgang. In diesem Beispiel springt jede fünfte Zeile:

while( <$in> )
    {
    next unless $. % 5;
    print $out $_;
    }

Wenn, aus irgendeinem seltsamen Grund, Sie wirklich wollen, um zu sehen, die gesamte Datei auf einmal eher als die Verarbeitung jeder Zeile können Sie schlürfen (so lange wie Sie können passen die ganze Sache in Erinnerung!):

open my $in,  '<',  $file      or die "Can't read old file: $!"
open my $out, '>', "$file.new" or die "Can't write new file: $!";

my @lines = do { local $/; <$in> }; # slurp!

    # do your magic here

print $out @lines;

Module wie File::Slurp und Tie::File können helfen mit, dass zu. Wenn Sie können, vermeiden Sie es jedoch, liest die gesamte Datei auf einmal. Perl will nicht, dass der Speicher wieder an das Betriebssystem, bis der Prozess abgeschlossen ist.

Können Sie auch Perl one-liners, eine Datei zu ändern. Die folgenden änderungen werden alle 'Fred' , 'Barney' in inFile.txt, überschreiben Sie die Datei mit dem neuen Inhalt. Mit der -p-Schalter, Perl schließt eine while-Schleife um den code, den Sie angeben, mit -e und-i stellt auf der in-place-Bearbeitung. Die aktuelle Zeile wird in $. Mit -p -, Perl-druckt automatisch den Wert von $ am Ende der Schleife. Man Vergleiche perlrun für mehr details.

perl -pi -e 's/Fred/Barney/' inFile.txt

Ein backup zu machen inFile.txt geben -i-eine Datei mit der Endung hinzufügen:

perl -pi.bak -e 's/Fred/Barney/' inFile.txt

Nur die fünfte Zeile, können Sie eine test-Prüfung $., die Eingabe Zeilennummer, dann nur die operation durchzuführen, wenn der test erfolgreich verläuft:

perl -pi -e 's/Fred/Barney/if $. == 5' inFile.txt

Hinzufügen von Zeilen vor einer bestimmten Zeile können Sie fügen Sie eine Zeile (oder Zeilen!) vor Perl gibt $_:

perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt

Können Sie sogar fügen Sie eine Zeile am Anfang der Datei, da die aktuelle Zeile druckt am Ende der Schleife:

perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt

Einfügen einer Zeile nach einer bereits in der Datei, verwenden Sie den-n-Schalter. Es ist genauso wie-p außer, dass es nicht print $_ am Ende der Schleife, so müssen Sie selbst erledigen. In diesem Fall print $_ erste, und drucken Sie dann die Zeile, die Sie hinzufügen möchten.

perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt

Löschen von Zeilen, die nur drucken, die Sie möchten.

perl -ni -e 'print unless /d/' inFile.txt

    ... or ...

perl -pi -e 'next unless /d/' inFile.txt

InformationsquelleAutor brian d foy

Verwenden Tie::File, die Zugriff auf die Zeilen einer Datei über ein Perl-array. Es kommt mit standard-distribution.

Beispiel aus der Dokumentation:

use Tie::File;

tie @array, 'Tie::File', filename or die ...;
$array[13] = 'blah';     # line 13 of the file is now 'blah'
print $array[42];        # display line 42 of the file

$n_recs = @array;        # how many records are in the file?
$#array -= 2;            # chop two records off the end

for (@array) {
    s/PERL/Perl/g;         # Replace PERL with Perl everywhere in the file
}

# These are just like regular push, pop, unshift, shift, and splice
# Except that they modify the file in the way you would expect
push @array, new recs...;
my $r1 = pop @array;
unshift @array, new recs...;
my $r2 = shift @array;
@old_recs = splice @array, 3, 7, new recs...;

untie @array;            # all finished

InformationsquelleAutor zakovyrya

Es gibt viele Möglichkeiten, Sie können es tun, zum Beispiel mit einem einfachen shell-Skript die Art und Weise @Pax erwähnt. Sie können auch ersetzen Sie Ihre array und eine Schleife mit einem join():

open(DATA, "</usr/old") || die "cant open old\n"; #file to which line has to be added
my $body=join("", <DATA>);
open (FILE, ">/usr/new") || die "cant open new\n"; #file after stuff has been added
print FILE "9   431\n";
print(FILE $body);
print FILE "(3,((((1,4),(7,6)),(2,8)),5),9)";
close(FILE);

InformationsquelleAutor sunny256

können Sie dies tun,

open(FILE,">", $file) or die "cannot open $file: $!";
print FILE "add line to top\n";
while (<FILE>) { print $_ ."\n";}
close(FILE);
print FILE "add line to bottom\n";

auf der Kommandozeile

perl myscript.pl > newfile

InformationsquelleAutor ghostdog74

Als Pax sagt, es gibt keine integrierte Möglichkeit, dies zu tun. Aber wenn Sie wollen, es zu tun mit einer einzigen Zeile perl-Befehl aus der shell, die Sie verwenden können:

perl -ple 'print "Top line" if $. == 1; if (eof) { print "$_\nBottom line";  exit; }' yourfile.txt > newfile.txt

InformationsquelleAutor Nikhil