Wie kann ich auto-erhöhen meine batch-Datei, so dass Sie Anfragen von UAC Administratorrechte, falls erforderlich?

Gibt es eine einfache Möglichkeit, ohne die Notwendigkeit, ein externes tool - es läuft wunderbar mit Windows 7, 8, 8.1 und 10 und ist rückwärts-kompatibel zu (Windows XP hat keine Benutzerkontensteuerung, also die Höhe ist nicht erforderlich - in diesem Fall das Skript nur Erlös).

Überprüfen Sie heraus diesen code (ich war inspiriert durch den code durch NIronwolf gepostet in dem thread Batch-Datei "Zugriff Verweigert" Auf Windows 7?), aber ich habe es verbessert - in meiner version gibt es kein Verzeichnis erstellt und entfernt, um zu überprüfen, für die Administratorrechte):

::::::::::::::::::::::::::::::::::::::::::::
:: Elevate.cmd - Version 4
:: Automatically check & get admin rights
:: see "https://stackoverflow.com/a/12264592/1016343" for description
::::::::::::::::::::::::::::::::::::::::::::
 @echo off
 CLS
 ECHO.
 ECHO =============================
 ECHO Running Admin shell
 ECHO =============================

:init
 setlocal DisableDelayedExpansion
 set cmdInvoke=1
 set winSysFolder=System32
 set "batchPath=%~0"
 for %%k in (%0) do set batchName=%%~nk
 set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
 setlocal EnableDelayedExpansion

:checkPrivileges
  NET FILE 1>NUL 2>NUL
  if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges
  if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
  ECHO.
  ECHO **************************************
  ECHO Invoking UAC for Privilege Escalation
  ECHO **************************************

  ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
  ECHO args = "ELEV " >> "%vbsGetPrivileges%"
  ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
  ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
  ECHO Next >> "%vbsGetPrivileges%"

  if '%cmdInvoke%'=='1' goto InvokeCmd 

  ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
  goto ExecElevation

:InvokeCmd
  ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
  ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"

:ExecElevation
 "%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
 exit /B

:gotPrivileges
 setlocal & cd /d %~dp0
 if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

 ::::::::::::::::::::::::::::
 ::START
 ::::::::::::::::::::::::::::
 REM Run shell as admin (example) - put here code as you like
 ECHO %batchName% Arguments: P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 P6=%6 P7=%7 P8=%8 P9=%9
 cmd /k

Das Skript nutzt die Tatsache, dass NET FILE erfordert Administratorrechte und zurück errorlevel 1 wenn Sie es nicht haben. Die Höhe wird erreicht, indem Sie ein Skript erstellen, die re-startet die batch-Datei, um Berechtigungen zu erhalten. Dies bewirkt, dass Windows zu präsentieren, die das UAC-Dialogfeld und fragt Sie für das administrator-Konto und Passwort.

Ich habe es getestet mit Windows 7, 8, 8.1, 10 und mit Windows XP - es läuft gut für alle.
Der Vorteil ist, nach dem start-Punkt Sie können alles, was benötigt system-administrator-Privilegien, zum Beispiel, wenn Sie beabsichtigen, Sie zu re-installieren und re-führen Sie ein Windows-Dienst für debugging-Zwecke (davon ausgegangen, dass MeinPaket.msi ist service-installer-Paket):

msiexec /passive /x mypackage.msi
msiexec /passive /i mypackage.msi
net start myservice

Ohne dieses Privileg Erhöhung Skript, UAC würde Sie bitten, drei mal für Ihre administrator-Benutzer-und-Passwort - jetzt bist du gefragt, nur einmal am Anfang, und nur, wenn erforderlich.

Wenn Ihr Skript nur braucht, um zu zeigen Sie eine Fehlermeldung und beenden, wenn es gibt keine administrator-Rechte statt auto-erhöhen, das ist sogar noch einfacher: Sie können dies erreichen, indem Sie den folgenden am Anfang des Skripts:

@ECHO OFF & CLS & ECHO.
NET FILE 1>NUL 2>NUL & IF ERRORLEVEL 1 (ECHO You must right-click and select &
  ECHO "RUN AS ADMINISTRATOR"  to run this batch. Exiting... & ECHO. &
  PAUSE & EXIT /D)
REM ... proceed here with admin rights ...

Diese Weise, der Benutzer hat mit der rechten Maustaste klicken, und wählen Sie "als administrator Ausführen". Das Skript wird fortgesetzt, nachdem die REM Aussage, wenn es erkennt, administrator-Rechte, sonst wird mit einem Fehler beenden. Wenn Sie nicht erforderlich PAUSE, entfernen Sie es einfach.
Wichtig: NET FILE [...] EXIT /D) muss auf der gleichen Linie. Es ist angezeigt, die hier in mehreren Zeilen zur besseren Lesbarkeit!

Auf einigen Maschinen, ich habe festgestellt, Probleme, die gelöst in der neuen version oben bereits. Man war aufgrund der unterschiedlichen Anführungszeichen Handhabung, und das andere Problem war, aufgrund der Tatsache, dass die UAC war deaktiviert (eingestellt auf niedrigster Stufe) auf einer Windows 7-Rechner, damit das script ruft sich selbst wieder und wieder.

Ich behoben haben dies jetzt durch Strippen die Anführungszeichen in dem Pfad, und re-adding Sie später, und ich habe einen zusätzlichen parameter, die Hinzugefügt wird, wenn das Skript neu startet mit erhöhten rechten.

Doppelte Anführungszeichen werden entfernt, indem die folgenden (details sind hier):

setlocal DisableDelayedExpansion
set "batchPath=%~0"
setlocal EnableDelayedExpansion

Kann dann auf den Pfad mit !batchPath!. Es enthält keine doppelten Anführungszeichen, so ist es sicher zu sagen "!batchPath!" später im Skript.

Die Linie

if '%1'=='ELEV' (shift & goto gotPrivileges)

überprüft, ob das Skript bereits genannt worden, die von der VBScript Skript zum erhöhen der Rechte, damit zur Vermeidung von endlosen rekursionen. Es entfernt die parameter shift.

Update:

• Um zu vermeiden, dass Sie zum registrieren der .vbs Erweiterung in Windows 10, ich habe ersetzt die Linie
  
  "%temp%\OEgetPrivileges.vbs"
  
  durch
  
  "%SystemRoot%\System32\WScript.exe" "%temp%\OEgetPrivileges.vbs"
  
  in dem oben beschriebenen Skript; auch Hinzugefügt cd /d %~dp0 wie vorgeschlagen von Stephen (separat beantworten) und Tomáš Zato (Kommentar), um Skript-Verzeichnis als default.

• Nun das Skript Ehrungen Kommandozeilen-Parameter übergeben werden. Dank jxmallet, TanisDLJ und Peter Mortensen für Beobachtungen und Inspirationen.

• Laut Artjom B. s Hinweis, ich habe es analysiert und ersetzt haben SHIFT durch SHIFT /1, was bewahrt die Dateinamen für die %0 parameter

• Hinzugefügt del "%temp%\OEgetPrivileges_%batchName%.vbs" zu den :gotPrivileges Abschnitt zu bereinigen (wie mlt vorgeschlagen). Hinzugefügt %batchName% zu vermeiden Auswirkungen, wenn man verschiedene Chargen parallel. Beachten Sie, dass Sie brauchen, um zu verwenden for zu können, nutzen Sie die erweiterte string-Funktionen, wie %%~nk, die extrahiert nur den Dateinamen.

• Optimierte Skript-Struktur, Verbesserungen (zusätzliche variable vbsGetPrivileges die nun verwiesen wird überall erlauben, ändern Sie den Pfad oder den Namen der Datei einfach nur löschen .vbs batch-Datei, wenn nötig, erhöht werden)

• In einigen Fällen, eine andere Aufruf-syntax erforderlich war, für die elevation. Wenn das Skript nicht funktioniert, überprüfen Sie die folgenden Parameter:
  
  set cmdInvoke=0

set winSysFolder=System32
  
  Entweder ändern Sie den 1. parameter set cmdInvoke=1 und überprüfen Sie, ob das schon das Problem behebt. Es wird cmd.exe um das Skript ausführen der Höhe.
  
  Oder versuchen, ändern Sie den 2. parameter zu winSysFolder=Sysnative, das könnte helfen (ist aber in den meisten Fällen nicht erforderlich) auf 64-bit-Systeme. (ADBailey hat dies berichteten). "Sysnative" ist nur erforderlich für den Start der 64-bit-Anwendungen von einer 32-bit-Scripting-host (z.B. ein Visual-Studio-build-Prozess oder Skript-Aufruf von einem anderen 32-bit-Anwendung).

• Zu machen, mehr klar, wie der Parameter interpretiert werden, bin ich die Anzeige jetzt wie P1=value1 P2=value2 ... P9=value9. Dies ist besonders nützlich, wenn Sie zum einschließen von Parametern wie Pfade in doppelten Anführungszeichen, z.B. "C:\Program Files".

Nützliche links:

• Bedeutung der Sonderzeichen in batch-Datei:
  Anführungszeichen (""), Bang (!), Caret-Zeichen (^), Kaufmännisches und-Zeichen (&), Andere Sonderzeichen

InformationsquelleAutor Matt

Ich bin mit Matt ' s ausgezeichnete Antwort, aber ich sehe einen Unterschied zwischen meinem Windows 7 und Windows 8-Systemen bei der Ausführung erhöhte scripts.

Einmal das Skript erhöht auf Windows 8, wird das aktuelle Verzeichnis festgelegt ist C:\Windows\system32. Glücklicherweise gibt es eine einfache Abhilfe durch ändern Sie das aktuelle Verzeichnis in den Pfad des aktuellen Skripts:

cd /d %~dp0

Hinweis: Verwenden Sie cd /d um sicherzustellen Laufwerksbuchstaben auch geändert.

Um dies zu testen, können Sie kopieren Sie den folgenden, um ein Skript. Normalerweise laufen beide Versionen zu sehen, das gleiche Ergebnis. Als Admin ausführen und sehen den Unterschied in Windows 8:

@echo off
echo Current path is %cd%
echo Changing directory to the path of the current script
cd %~dp0
echo Current path is %cd%
pause

InformationsquelleAutor Stephen Klancher

Matt hat eine tolle Antwort, aber es entfernt keine Argumente an das Skript übergeben. Hier ist meine Modifikation, hält Argumente. Ich habe auch integriert Stephen ' s fix für das Arbeitsverzeichnis ein problem in Windows 8.

@ECHO OFF
setlocal EnableDelayedExpansion

NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto START ) else ( goto getPrivileges ) 

:getPrivileges
if '%1'=='ELEV' ( goto START )

set "batchPath=%~f0"
set "batchArgs=ELEV"

::Add quotes to the batch path, if needed
set "script=%0"
set script=%script:"=%
IF '%0'=='!script!' ( GOTO PathQuotesDone )
    set "batchPath=""%batchPath%"""
:PathQuotesDone

::Add quotes to the arguments, if needed.
:ArgLoop
IF '%1'=='' ( GOTO EndArgLoop ) else ( GOTO AddArg )
    :AddArg
    set "arg=%1"
    set arg=%arg:"=%
    IF '%1'=='!arg!' ( GOTO NoQuotes )
        set "batchArgs=%batchArgs% "%1""
        GOTO QuotesDone
        :NoQuotes
        set "batchArgs=%batchArgs% %1"
    :QuotesDone
    shift
    GOTO ArgLoop
:EndArgLoop

::Create and run the vb script to elevate the batch file
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
ECHO UAC.ShellExecute "cmd", "/c ""!batchPath! !batchArgs!""", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
"%temp%\OEgetPrivileges.vbs" 
exit /B

:START
::Remove the elevation tag and set the correct working directory
IF '%1'=='ELEV' ( shift /1 )
cd /d %~dp0

::Do your adminy thing here...

InformationsquelleAutor jxmallett

Für einige Programme, die die Einstellung der super-geheime __COMPAT_LAYER Umgebungsvariable RunAsInvoker funktioniert.Überprüfen Sie dies :

set "__COMPAT_LAYER=RunAsInvoker"
start regedit.exe

Aber wie diese wird es keine UAC-Aufforderungen für den Benutzer weiterhin ohne admin-Berechtigungen.

InformationsquelleAutor npocmaka

Folgende Lösung ist sauber und funktioniert einwandfrei.

1. Download Elevate zip-Datei aus https://www.winability.com/download/Elevate.zip

2. Innerhalb von zip -, sollten Sie zwei Dateien finden: Elevate.exe und Elevate64.exe. (Letzteres ist eine native 64-bit-Zusammenstellung, wenn Sie verlangen, dass, obwohl die reguläre 32-bit-version, Elevate.exe sollte funktionieren mit der 32 - und 64-bit-Versionen von Windows)

3. Kopieren Sie die Datei Elevate.exe in einen Ordner, in dem Windows kann es immer wieder (wie C:/Windows). Oder Sie besser können Sie die Kopie im selben Ordner, in dem Sie planen, um Ihre bat-Datei.

4. Zur Verwendung in einer batch-Datei, Schreibe einfach den Befehl, den Sie ausführen möchten, als administrator mit dem elevate-Befehl, wie hier:

 elevate net start service ...

InformationsquelleAutor Vaibhav Jain