Wie kann ich das implementieren von Unix grep in Perl?

Wie kann ich das umsetzen grep von Unix in Perl? Ich habe versucht, das Perl built-in grep. Hier ist der code, der nicht funktioniert:

$pattern = @ARGV[0];
$file= @ARGV[1];

open($fp,$file);

@arr = <$fp>;

@lines = grep $pattern, @arr;

close($fp);
print @lines;

Und übrigens, ich versuche nur die grundlegenden grep Funktionalität nicht voll funktionsfähige und zweitens will ich nicht zu tun-string Parsen selbst. Ich will eingebaute grep oder eine Funktion von Perl.

Vielen Dank im Voraus 🙂

InformationsquelleAutor TCM | 2010-10-03
  1. 13

    In Perl finden Sie eine ganze Reihe wir verwenden @. Aber beziehen sich die einzelnen Elemente, die Skalare verwenden wir $.

    So, müssen Sie $ und nicht @ auf diese Zeilen:

    $pattern = @ARGV[0];
$file= @ARGV[1];

    Auch

    diese

    @lines = grep $pattern, @arr;

    sollte

    @lines = grep /$pattern/, @arr;

    den grep in Perl hat die Allgemeine syntax:

    grep EXPR,LIST

    Er wertet die EXPR für jedes element LIST und liefert den Wert, der aus denjenigen Elementen, für die der Ausdruck wahr ausgewertet.

    Den EXPR in Ihrem Fall ist die Suche nach dem Muster $pattern im array @arr. Zu suchen, müssen Sie die /PATTERN/ ohne die / den string $pattern werden ausgewertet true oder false.

    • - Dank Habe es.
    • du hast es toll den Fehler zu beheben in dem code, aber diese Frage und der Ansatz, den der Benutzer verwendet, wandelt es in ein quasi 'xy-problem', so ist dies eine jener Situationen, die Indoktrination wohl nicht off-topic. Ich hätte empfohlen, Sie nicht zu Lesen die gesamte Datei zur gleichen Zeit (er wollte simulieren, grep, der ist zeilenorientiert), ich würde haben empfohlen, ihn mit dem grep {} anstelle der grep() nur um eine gute Gewohnheit, und die drei Argumente offen. Und noch weiter, ihm den online-Zugang (oder alternativ die Zeile mit Weile) wäre ein plus.
    InformationsquelleAutor codaddict
  2. 14

    Als Sie bereits akzeptiert eine Antwort, ich Schreibe diese Antwort als Referenz für zukünftige Leser auf der Suche für ähnliche Probleme, aber nicht genau Ihre:

    Als Menschen haben Sie bereits beantwortet, die Art und Weise der Simulation von grep mit perl ist die Verwendung der online-Ansatz.
    Für die Verwendung von perl als 'besser' grep (suchen und Ausschneiden und...) empfehle ich das Buch minimal perl und Sie sind glücklich, weil das Kapitel für 'perl als "besser" grep' ist eine der Beispiel-Kapitel.

    Hier haben Sie mehr Beispiele inspiriert von dem Buch:

    perl -wnle '/foo/and print' null.txt  # normal grep
perl -wnle '/foo/and print "$ARGV: $_"' null.txt # grep -H
perl -wnle '/foo/and print $ARGV and close ARGV' null_1.txt null_2.txt # grep -l

    Im letzten Beispiel ARGV ist das aktuelle filehandle, und als mit -l Sie sind interessiert bei der Suche nach Dateien mit dem übereinstimmen, können Sie drucken den Namen der Datei, und gehen Sie für die nächste Datei, die nach dem ersten Spiel in eine Datei.

    Außerdem können Sie die Suche durch Absatz anstelle von line:

    $ perl -00 -wnl -e '/\bBRIBE\b/i and print;' SenQ.testimony
I knew I'd be in trouble if
I ACCEPTED THE BRIBE!
So I did not.

My minimum bribe is $100k, and she only offered me $50k,
so to preserve my pricing power, I refused it.

    Oder findet nur die erste übereinstimmung:

    $ perl -00 -wnl -e '/\bBRIBE\b/i and close ARGV;' SenQ.testimony
I knew I would be in trouble if
I ACCEPTED THE BRIBE!
So I did not.

    Und schließlich sollten Sie Fragen zu grep und perl, ich denke, thay, ich sollte erwähnen,ACK. Es implementiert in perl, grep-Funktionalität und erweitern. Dies ist ein wunderbares Werkzeug, und wie ein plus-Sie können es auch als ein CPAN-Paket. Ich habe immer als eine Befehlszeile, ich weiß nicht, ob können Sie auf dessen Methoden direkt aus Ihren perl-Programmen, aber das wäre sehr nett.

    • ja, aktualisiert wird die Antwort entsprechend
    InformationsquelleAutor Pablo Marin-Garcia
  3. 13

    Natürlich codaddict s Antwort ist richtig, aber ich möchte einige Bemerkungen anfügen :

    Sollten Sie immer beginnen Sie Ihre Skripte mit diesen beiden Zeilen :

    use strict;
use warnings;

    Drei args öffnen und testen auf Fehler:

    open my $fh, '<', $file or die "unable to open '$file' for reading : $!";

    Und weil der use strict müssen Sie deklarieren Sie alle Variablen. Also dein script wird so sein:

    #!/usr/bin/perl

use strict;
use warnings;

my $pattern = $ARGV[0];
my $file = $ARGV[1];

open $fh, '<', $file or die "unable to open file '$file' for reading : $!";
my @arr = <$fh>;
close $fh;  # close as soon as possible

my @lines = grep /$pattern/, @arr;

print @lines;

    Wenn Ihre Datei sehr groß ist, können Sie vermeiden, Lesen Sie vollständig im Arbeitsspeicher:

    #!/usr/bin/perl
use strict;
use warnings;

my $pattern = qr/$ARGV[0]/;
my $file= $ARGV[1];
print "pattern=$pattern\n";

my @lines;
open my $fh, '<', $file or die "unable to open file '$file' for reading : $!";
while(my $line=<$fh>) {
    push @lines, $line if ($line =~ $pattern);
}
close($fh);
print @lines;
    • Sie können ersetzen Sie die " push @Zeilen, $Zeile,' in der while-Schleife einfach mit 'print $line" und vermeiden Sie die Verwendung eines arrays. Wenn Ihre Datei "großen", dann jemanden oder etwas, wird zwangsläufig eines Tages auslösen grep liefert, dass fast alle Zeilen der Datei. (und gleich groß 🙂
    InformationsquelleAutor Toto
  4. 11

    Können Sie die Annäherung an eine primitive version grep direkt auf der Kommandozeile. Die -e option können Sie definieren ein Perl-script auf der Kommandozeile. Die -n option wickelt Ihr script etwa so: while (<>){ SCRIPT }.

    perl -ne 'print if /PATTERN/' FILE1 FILE2 ...

    Etwas bessere Annäherung der grep würde Präfix den Namen der Datei vor jedem gedruckten übereinstimmen. Beachten Sie, dass dieses Beispiel, wie die oben, nicht gehen durch den Aufwand der öffnung aller Dateien. Stattdessen verwenden wir das Perl <> Konstrukt zum Durchlaufen aller Dateien und der $ARGV variable enthält den name der aktuellen Datei.

    use strict;
use warnings;

my $pattern = shift;

while (my $line = <>){
    print $ARGV, ':', $line if $line =~ $pattern;
}
    • Die spezielle variable $. enthält die aktuelle Zeilennummer. Also, wenn Sie drucken möchten, dass Sie auch tun könnte perl -ne 'print "$ARGV,$.:$_" if /PATTERN/' file1 file2.
    InformationsquelleAutor FMc
  5. 4

    Die einfachen "grep" - Funktionalität ist bereits implementiert. (=~)

    $string =~ /pattern/;
    • Danke!!!
    InformationsquelleAutor ghostdog74
Schreibe einen Kommentar