Wie kann ich das schreiben von binären Daten auf der Festplatte in VBScript?

Habe ich eine binäre Zeichenfolge, die ich brauche um eine Datei zu schreiben. Ich habe das Gefühl, dass dies sollte ein einfaches Verfahren, aber dann wieder, VBScript. Die FileSystemObject ist keine Hilfe, da es munges der Daten. Die Stream Objekt sieht vielversprechend aus, mit adBinaryMode und seine Write Methode, aber die Write Methode erfordert ein byte-array und wird nicht scheinen zu akzeptieren, die ein variant-array statt. Da VBScript arrays sind alle Variante arrays, erscheint dies problematisch.

So, wie ich Schreibe einfach die Daten in die Datei?

EDIT: ich sollte hinzufügen, dass die ganze Sache VBScript. Keine zusätzlichen Komponenten. Sorry, ich weiß nicht wie es entweder.

InformationsquelleAutor Thom Smith | 2011-04-07
  1. 5

    Es ist auch möglich mit der normalen FileSystemObject, hier ist der code, den ich verwende in benutzerdefinierten upload-Skript, das schrieb ich schon vor langer Zeit mit code, den ich online gefunden, konvertiert Binär-string in ASCII:

    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("file path here")
objFile.Write(RSBinaryToString(strBinaryContents))
objFile.Close
Set objFile=Nothing
Set objFSO=Nothing

Private Function RSBinaryToString(xBinary)
    'Antonin Foller, http://www.motobit.com
    'RSBinaryToString converts binary data (VT_UI1 | VT_ARRAY Or MultiByte string)
    'to a string (BSTR) using ADO recordset

    Dim Binary
    'MultiByte data must be converted To VT_UI1 | VT_ARRAY first.
    If vartype(xBinary)=8 Then Binary = MultiByteToBinary(xBinary) Else Binary = xBinary

    Dim RS, LBinary
    Const adLongVarChar = 201
    Set RS = CreateObject("ADODB.Recordset")
    LBinary = LenB(Binary)

    If LBinary>0 Then
        RS.Fields.Append "mBinary", adLongVarChar, LBinary
        RS.Open
        RS.AddNew
        RS("mBinary").AppendChunk Binary 
        RS.Update
        RSBinaryToString = RS("mBinary")
    Else  
        RSBinaryToString = ""
    End If
End Function

Function MultiByteToBinary(MultiByte)
    '© 2000 Antonin Foller, http://www.motobit.com
    ' MultiByteToBinary converts multibyte string To real binary data (VT_UI1 | VT_ARRAY)
    ' Using recordset
    Dim RS, LMultiByte, Binary
    Const adLongVarBinary = 205
    Set RS = CreateObject("ADODB.Recordset")
    LMultiByte = LenB(MultiByte)
    If LMultiByte>0 Then
        RS.Fields.Append "mBinary", adLongVarBinary, LMultiByte
        RS.Open
        RS.AddNew
        RS("mBinary").AppendChunk MultiByte & ChrB(0)
        RS.Update
        Binary = RS("mBinary").GetChunk(LMultiByte)
    End If
    MultiByteToBinary = Binary
End Function
    • Ich habe butting meinen Kopf gegen die Wand über das ganze ASP-Datei-upload-Problem, das ist schließlich etwas, das einfach nur funktioniert :-). Ich kann nicht glauben, dass etwas so wichtiges Bedürfnis, dass eine solche Menge fremder hantieren :-/. Danke seeeeehr viel!!!!
    • lol, sei froh, dass es dieses oooold code war so eine große Hilfe! 🙂
    • Genial, jetzt habe ich zu kämpfen mit diesem alten Zeug auch-und dies scheint die einzige Lösung, die funktioniert einfach nach endlosen Stunden des basteln / testen / suchen.
    InformationsquelleAutor Shadow
  2. 2

    Hier sind mehrere Optionen. Die interessanteste Variante beschrieben, wandelt die Binärdaten in eine Zeichenfolge mit Hilfe einer benutzerdefinierten Funktion BinaryToString.

    InformationsquelleAutor Helge Klein
  3. 1

    Schreiben eine binäre Datei in VBScript ist einfach, aber erfordert, dass Sie schreiben, die ein byte zu einem Zeitpunkt. Als eine demonstration, hier ist ein einfaches Skript, das schafft eine single-pixel-GIF-Datei. Die resultierende Datei hat genau den binären Inhalt geschrieben, nichts mehr, und eine gültige GIF-Datei.

    Dim GifFile : Set GifFile = CreateObject("Scripting.FileSystemObject").CreateTextFile("SinglePixel.gif")

With GifFile
    .write chr(&h47) 'GIF87a
    .write chr(&h49)
    .write chr(&h46)
    .write chr(&h38)
    .write chr(&h37)
    .write chr(&h61)
    .write chr(&h01) 'Width
    .write chr(&h00)
    .write chr(&h01) 'Height
    .write chr(&h00)
    .write chr(&h80) 'Use global color map
    .write chr(&h00) 'Background
    .write chr(&h00) 'End of header
    .write chr(&h00) 'Color map color #1 in RGB
    .write chr(&h00)
    .write chr(&h00)
    .write chr(&hFF) 'Color map color #2 in RGB
    .write chr(&hFF)
    .write chr(&hFF)
    .write chr(&h2C) 'Image descriptor
    .write chr(&h00) 'Left
    .write chr(&h00)
    .write chr(&h00) 'Top
    .write chr(&h00)
    .write chr(&h01) 'Width
    .write chr(&h00)
    .write chr(&h01) 'Height
    .write chr(&h00)
    .write chr(&h40) 'Use global color map /seq order /1 bit per pixel
    .write chr(&h02) 'Code size
    .write chr(&h02) 'Blok byte count
    .write chr(&h44) 'LZW data
    .write chr(&h01)
    .write chr(&h00) 'Terminate data stream
    .write chr(&h3B) 'Gif terminator
End With

GifFile.Close
    InformationsquelleAutor Regis Desrosiers
Schreibe einen Kommentar