Wie kann ich Dateien überschreiben ohne Aufforderung in Access 2007?

Ich versuche die Ausgabe mehrerer Tabellen in excel-Dateien. Jedes mal, wenn ich das makro ausführen, es fordert mich auf die alte Datei überschreiben. Ich bin auf der Suche nach einer Methode, die nicht die send-keys, da es sperrt die Tastatur und Maus so lange, bis das makro abgeschlossen ist.

Was wäre die beste Lösung sein?

InformationsquelleAutor | 2009-07-28
  1. 4

    Sind Sie mit DoCmd.OutputTo?

     DoCmd.OutputTo acOutputTable, "Table1", acFormatXLS, "c:\temp\test.xls"

    Diese scheint keine Aufforderung zum überschreiben der vorhandenen Dateien.

    • Ich mag diese Antwort, außer ich Wünsche mir, dass OutputTo würde, können Sie die Excel-version wurde der Export zu.
    InformationsquelleAutor pjp
  2. 3

    Können Sie so etwas tun, aber es ist cludgy und nicht sehr robust.

    DoCmd.SetWarnings False
'do stuff
DoCmd.SetWarnings true

    Was Sie auch tun könnte, ist zunächst, ob die Datei vorhanden ist, und dann, wenn es ist, löschen Sie es (natürlich zerstört jede spezielle Datei-Berechtigungen, die Sie gesetzt hatte, auf es).

    If Dir(strPath) <> "" Then
    Kill (strPath) 'Delete (strPath)
End If
DoCmd.TransferSpreadsheet acExport, _
                            acSpreadsheetTypeExcel8, _
                            "MyTableQueryName", _
                            strPath, _
                            True
    • +1 für den zweiten Satz von code
    • Einstellung Setwarnings deaktiviert, ist immer eine ziemlich schlechte Idee. Es ist im Grunde eine Art und Weise zu ignorieren, Fehler-reports aus Access, und Sie nicht wissen, für sicher, was bestimmte Probleme, die Sie am Ende zu ignorieren.
    • DWF, vereinbart. Wie gesagt, es ist cludgy
    • Ich bin damit einverstanden, nicht die erste option verwenden. Aber der zweite ist gut. Sie sollten wahrscheinlich haben aufgeteilt in zwei Antworten 🙂
    InformationsquelleAutor BIBD
  3. 1

    Haben ein anderes makro, das zuerst ausgeführt wird und löscht die Datei, wenn Sie bereits vorhanden ist.

    • Gibt es nicht eine option zum löschen einer externen Datei.
    • Kill [PathToFile] wird, löschen Sie die externen Dateien, aber Sie müssen, um den Fehler zu behandeln, die erzeugt wird, wenn die Datei nicht da ist.
    InformationsquelleAutor Neil Barnwell
  4. 1

    Ich schlage vor, Sie Weg von der Verwendung von Makros so bald wie möglich. Sie sind nicht robust (keine Fehlerbehandlung) und nicht handhabbar (wie wollen Sie herausfinden, wo ein makro soll verwendet werden?).

    DoCmd.OutputTo oder einer der DoCmd.TransferXXX Befehle viel eaiser, um mit viel im langen Lauf.

    InformationsquelleAutor David-W-Fenton
  5. 0

    Nicht sicher über den Zugang, aber die meisten anderen Office-Anwendungen haben eine DisplayAlerts Eigenschaft oder etwas ähnliches, so dass Sie tun können Application.DisplayAlerts = False bevor Sie Vorgänge, führen normalerweise zu einem dialog angezeigt.

    • Das habe ich versucht. Nur unterdrückt die internen Anweisungen. Es funktioniert nicht beim exportieren.
    InformationsquelleAutor Gary McGill
  6. 0

    Vermeiden Sie doppelte Dateien, die ich in der Regel fügen Sie das Datum und die Uhrzeit an den Dateinamen an. Dies hat auch den Vorteil, dass der Anwender mehrere Versionen desselben Berichts.

    Public Sub ExportToExcel(objectToExport As Variant, _
                         outPutType As AcOutputObjectType, _
                         filename As String, _
                         Optional outputFormat = acFormatXLS)
    ' Construct the filename using the date and time '
    Dim fnamebase As String
    Dim ext As String
    ext = Mid$(filename, InStrRev(filename, "."))
    fnamebase = Left$(filename, Len(filename) - Len(ext)) _
                & Format(Now, "-yyyymmdd-hh\hmm")

    ' check if there is another file with the same name '
    ' append (1), (2) until we find a free slot '
    Dim fname As String
    Dim count As Integer
    fname = fnamebase & ext
    Do While Len(Dir(fname)) > 0
        count = count + 1
        fname = fnamebase & "(" & count & ")" & ext
    Loop

    ' Now we're fairly sure no identical filename exists '
    DoCmd.OutputTo objectType:=outPutType, _
                    ObjectName:=objectToExport, _
                    outputFormat:=outputFormat, _
                    OutputFile:=fname, _
                    Encoding:=vbUnicode

End Sub

    Können Sie nun exportieren, Abfragen und Tabellen:

    • Abfrage in Excel 2007/2010-format (XLXS-format nur in Access2007/2010):

      ExportToExcel "qrySupplierList", acOutputQuery, "D:\suppliers.xlsx", acFormatXLSX

    • Einer Tabelle in eine Text-Datei:

      ExportToExcel "Suppliers", acOutputTable, "D:\suppliers.txt", acFormatTXT

    Nun TransferSpreadSheet ist besser auf die übertragung von Tabellen in Excel, so können Sie es vorziehen zu verwenden, stattdessen:

    Public Sub ExportTableToExcel(tableName As String, _
                              filename As String, _
                              Optional spreadSheetType = acSpreadsheetTypeExcel8)
    ' Construct the filename using the date and time '
    Dim fnamebase As String
    Dim ext As String
    ext = Mid$(filename, InStrRev(filename, "."))
    fnamebase = Left$(filename, Len(filename) - Len(ext)) _
                & Format(Now, "-yyyymmdd-hh\hmm")

    ' check if there is another file with the same name '
    ' append (1), (2) until we find a free slot '
    Dim fname As String
    Dim count As Integer
    fname = fnamebase & ext
    Do While Len(Dir(fname)) > 0
        count = count + 1
        fname = fnamebase & "(" & count & ")" & ext
    Loop

    ' Now we're fairly sure no identical filename exists '
    DoCmd.TransferSpreadsheet TransferType:=acExport, _
                              spreadSheetType:=spreadSheetType, _
                              tableName:=tableName, _
                              filename:=fname, _
                              HasFieldNames:=True
End Sub

    Eine Sie es wie diese:

    • Zu exportieren einer Tabelle in eine Excel97-format:

      ExportTableToExcel "Supplier", "D:\Suppliers.xlx"

    • Zu exportieren, um XLSX-format (ab Access 2007/2010 nur):
      ExportTableToExcel "Supplier", "D:\Suppliers.xlsx", acSpreadsheetTypeExcel12Xml

    InformationsquelleAutor Renaud Bompuis
Schreibe einen Kommentar