Wie kann ich die Darstellung ganzer zahlen in hexadezimal -, batch-Datei?

echo The error level is: %ERRORLEVEL%

Produziert

>The error level is: 15

Was ich möchte:

>The error level is: F

muss ich tun, umtauschen oder gibt es eine Möglichkeit zum anzeigen von zahlen anders?

Jede Hilfe in die richtige Richtung, wird sehr geschätzt, danke.

InformationsquelleAutor T.T.T. | 2011-04-20
  1. 3

    Nur schreiben Sie es in vbscript anstelle von batch -

    setzen Sie die vbscript-Anweisung ist unten in einer Datei.

    WScript.Echo Hex( WScript.Arguments(0) )

    dann, um es auszuführen, geben Sie einfach diesen Befehl an der Befehlszeile ( in einem batch-Skript, verwenden Sie eine for-Schleife, um den Wert, wenn erforderlich )

    C:\workspace> cscript //nologo hex.vbs 15
F

    Gibt es keine Notwendigkeit, etwas zu installieren. vbscript kommt standardmäßig in den meisten windows-Systemen.

    • keine option aber danke.
    • warum nicht? Sie haben Grenzen, aber du bist keine Angabe. Ich hatte nicht erwartet, Sie zu nehmen, meine Lösung, aber das verwendet nur Komponenten, die mit Windows kommen.
    • das ist wahr, ich werde das prüfen, danke.
    InformationsquelleAutor bash-o-logist
  2. 9

    Es war vor langer Zeit, war ich sehr gelangweilt.

    cmdcalc.cmd 

    @echo off
    if not defined trace set trace=rem
    %trace% on
SetLocal
    if "%1"=="/?" (
       call :help %0
       goto :eof
    )
    Set MinInBase=
    if /i "%2" EQU "Bin" call :DoBin %1
    if /i "%2" EQU "Hex" call :DoHex %1
    If not defined BinStr call :DoDec %1
EndLocal & set RET=%RET%
goto :eof


:DoBin
    Set MinInBase=2
    Set ShiftBy=1
    Set StartSyn=0b
    call :DoCalc %1
goto :eof

:DoHex
    Set MinInBase=16
    Set ShiftBy=4
    Set StartSyn=0x
    call :DoCalc %1
goto :eof


:DoDec
    if {%1} EQU {} goto :eof
    set  /a BinStr=%1
    set RET=%BinStr%
    echo %RET%
goto :eof


:DoCalc 
    Set BinStr= 
    SET /A A=%1
    %Trace% %A%
:StartSplit
    SET /A B="A>>%ShiftBy%"
    %Trace% %B%
    SET /A C="B<<%ShiftBy%"
    %Trace% %C%
    SET /A C=A-C
    %Trace% %C%
    call :StringIt %C%
    If %B% LSS %MinInBase% goto :EndSplit 
    set A=%B%
goto :StartSplit    
:EndSplit
    call :StringIt %B%
    set RET=%StartSyn%%BinStr%
    Echo %RET%
EndLocal & set RET=%RET%
goto :eof


:StringIt
    set Bin=0123456789ABCDEF
    FOR /F "tokens=*" %%A in ('echo "%%BIN:~%1,1%%"') do set RET=%%A
    set ret=%ret:"=%
    Set BinStr=%Ret%%BinStr%
goto :eof

:help
    echo %1 syntax:
    echo.
    echo %1 Calculation [Hex^|Bin]
    echo.
    echo eg %1 12*2 Hex
    echo.
    echo gives 0x18.
goto :eof
    • +1, Ein bisschen overkill für die Frage, aber eine Lösung
    • Morris: danke
    InformationsquelleAutor Andy Morris
  3. 7

    Entsprechend der externen Ressource Windows-Umgebungsvariablen, es ist eine nicht dokumentierte eingebauten nur-lese-variable =ExitCode gibt die aktuellen exit-code im hexadezimalen format. Zur Gewährleistung der ErrorLevel Wert gleich dem exit-code, verwenden Sie cmd /C exit %ErrorLevel%.

    Wenn Sie also mit dieser Zeile code...:

    cmd /C exit %ErrorLevel%
echo The error level is: %=ExitCode%

    ...erhalten Sie diese (angenommen, dass die ErrorLevel ist 15):

    The error level is: 0000000F

    Um loszuwerden, das führende Nullen, verwenden Sie diese...:

    cmd /C exit %ErrorLevel%
for /F "tokens=* delims=0" %%Z in ("%=ExitCode%") do set "HEXCODE=%%Z"
if not defined HEXCODE set "HEXCODE=0"
echo The error level is: %HEXCODE%

    ...um dies zu erhalten:

    The error level is: F
    • exitcode neq errorlevel
    • Ja, @Stephan, du hast Recht! Nach dieser Seite, cmd /C exit %ErrorLevel% sollten sicherstellen, dass der exit-code gleich ErrorLevel -- siehe mein Bearbeiten...
    InformationsquelleAutor aschipfl
  4. -1
    perl -e"printf qq{The errorlevel is: %X\n}, $ENV{ERRORLEVEL}"

    Erfordert Perl installiert werden, natürlich, aber das ist einfach zu tun.

    • keine option aber danke.
    • Es ist nur einfach zu tun, wenn du bist admin auf der eigenen Maschine. Da draußen in der realen Welt alle möglichen Dinge, die sind in der Art von »nur die Installation etwas«.
    • Ich habe mindestens 5 die Installation von Perl auf meine beiden Maschinen. Ich brauchte keine admin-Rechte auf dem nicht-Windows-Computer. Ich kann mich nicht erinnern, für den Windows-Rechner, aber ich sehe nicht ein, warum würden Sie brauchen keine besonderen Privilegien. Es kann installiert werden, um ein beliebiges Verzeichnis, und es muss nicht die registry.
    InformationsquelleAutor ikegami
Schreibe einen Kommentar