Wie kann ich ein Element aus einem Array in VB.NET löschen?

Wie Heinzi sagte, ein array hat eine Feste Größe. Um 'entfernen Sie ein Element' oder 'resize', müssen Sie erstellen ein neues array mit der gewünschten Größe, und kopieren Sie die Elemente, die Sie benötigen, angebracht.

Hier der code zum entfernen eines Elements aus einem array:

<System.Runtime.CompilerServices.Extension()> _
Function RemoveAt(Of T)(ByVal arr As T(), ByVal index As Integer) As T()
    Dim uBound = arr.GetUpperBound(0)
    Dim lBound = arr.GetLowerBound(0)
    Dim arrLen = uBound - lBound

    If index < lBound OrElse index > uBound Then
        Throw New ArgumentOutOfRangeException( _
        String.Format("Index must be from {0} to {1}.", lBound, uBound))

    Else
        'create an array 1 element less than the input array
        Dim outArr(arrLen - 1) As T
        'copy the first part of the input array
        Array.Copy(arr, 0, outArr, 0, index)
        'then copy the second part of the input array
        Array.Copy(arr, index + 1, outArr, index, uBound - index)

        Return outArr
    End If
End Function

Können Sie es verwenden, wie folgt:

Module Module1

    Sub Main()
        Dim arr = New String() {"abc", "mno", "xyz"}
        arr.RemoveAt(1)
    End Sub
End Module

Den obigen code entfernt das zweite element ("mno") [die hat einen index von 1] aus dem array.

Müssen Sie zu werden Entwicklung in .NET 3.5 oder höher, um die extension-Methode.
Wenn Sie verwenden .NET 2.0 oder 3.0 haben, können Sie rufen Sie die Methode als solche

arr = RemoveAt(arr, 1)

Ich hoffe das ist das, was Sie brauchen.

Update

Nach der Ausführung von tests, basierend auf ToolMakerSteve Kommentar es erscheint der erste code nicht ändern das array, das Sie aktualisieren möchten, weil der ByVal verwendet in der Funktion der Erklärung. Allerdings ist das schreiben von code wie arr = arr.RemoveAt(1) oder arr = RemoveAt(arr, 1) hat, ändert das array, da es ordnet die modifizierte array an das original.

Nachfolgend finden Sie die aktualisierte Methode (Unterprogramm) zum entfernen eines Elements aus einem array.

<System.Runtime.CompilerServices.Extension()> _
Public Sub RemoveAt(Of T)(ByRef arr As T(), ByVal index As Integer)
    Dim uBound = arr.GetUpperBound(0)
    Dim lBound = arr.GetLowerBound(0)
    Dim arrLen = uBound - lBound

    If index < lBound OrElse index > uBound Then
        Throw New ArgumentOutOfRangeException( _
        String.Format("Index must be from {0} to {1}.", lBound, uBound))

    Else
        'create an array 1 element less than the input array
        Dim outArr(arrLen - 1) As T
        'copy the first part of the input array
        Array.Copy(arr, 0, outArr, 0, index)
        'then copy the second part of the input array
        Array.Copy(arr, index + 1, outArr, index, uBound - index)

        arr = outArr
    End If
End Sub

Verwendung der Methode ist ähnlich wie das original, außer es gibt keine return-Wert dieses mal so versucht, weisen Sie ein array vom Rückgabewert wird nicht funktionieren, weil nichts zurückgegeben.

Dim arr = New String() {"abc", "mno", "xyz"}
arr.RemoveAt(1)  ' Output: {"abc", "mno"} (works on .NET 3.5 and higher)
RemoveAt(arr, 1) ' Output: {"abc", "mno"} (works on all versions of .NET fx)
arr = arr.RemoveAt(1)  'will not work; no return value
arr = RemoveAt(arr, 1) 'will not work; no return value

Hinweis:

1. Ich ein temporäres array für den Prozess, da macht es meine Absichten sind klar, und das ist genau das, was VB.NET hinter den kulissen tut, wenn Sie Redim Preserve. Wenn Sie möchten, ändern Sie das array in-place-mithilfe Redim Preserve finden Sie ToolmakerSteve Antwort.

2. Den RemoveAt Methoden hier geschrieben wird, sind Erweiterung-Methoden. In Reihenfolge für Sie zu arbeiten, müssen Sie fügen Sie Sie in eine Module. Erweiterung Methoden funktionieren nicht in VB.NET wenn Sie Sie in eine Class.

3. Wichtig Wenn Sie ändern Ihre array mit viel 'entfernt', ist es dringend empfohlen, verwenden Sie eine andere Datenstruktur wie List(Of T) wie vorgeschlagen, die von anderen Beantworter dieser Frage.

InformationsquelleAutor der Antwort Alex Essilfie

Hängt davon ab, was du damit meinst löschen. Ein array hat eine Feste Größe, so dass das löschen nicht wirklich sinnvoll.

Wenn Sie möchten, entfernen Sie das Filterelement ieine Möglichkeit wäre, alle Elemente verschieben. j > i eine position nach Links (a[j - 1] = a[j] für alle j oder mit Array.Copy) und dann die Größe des Arrays mit ReDim Preserve.

So, es sei denn, Sie sind gezwungen, um ein array zu verwenden, die durch einige externe Einschränkung, überlegen Sie sich eine Datenstruktur, die mehr geeignet für das hinzufügen und entfernen von Elementen. List<T>zum Beispiel, verwendet ebenfalls ein array intern, sondern kümmert sich um alle die Größenänderung Fragen sich: Für das entfernen von Elementen, es verwendet den Algorithmus oben erwähnt (ohne die ReDim -), das ist der Grund, warum List<T>.RemoveAt ist eine O(n) operation.

Gibt es eine ganze Reihe von verschiedenen collection-Klassen in der System.Sammlungen.Generic namespace, optimiert für verschiedene Anwendungsfälle. Wenn das entfernen von Elementen, Häufig ist eine Voraussetzung, es gibt viele bessere Optionen als ein array (oder auch List<T>).

InformationsquelleAutor der Antwort Heinzi

Einer Linie mit LINQ:

Dim arr() As String = {"uno", "dos", "tres", "cuatro", "cinco"}
Dim indx As Integer = 2
arr = arr.Where(Function(item, index) index <> indx).ToArray 'arr = {"uno", "dos", "cuatro", "cinco"}

Entferne erstes element:

arr = arr.Skip(1).ToArray

Entfernen Letzte element:

arr = arr.Take(arr.length - 1).ToArray

InformationsquelleAutor der Antwort Ivan Ferrer Villa

Die variable i ist der index des Elements, das Sie löschen möchten:

System.Array.Clear(ArrayName, i, 1)

InformationsquelleAutor der Antwort Vinayak D.Gaikwad

Public Sub ArrayDelAt(ByRef x As Array, ByVal stack As Integer)
    For i = 0 To x.Length - 2
        If i >= stack Then
            x(i) = x(i + 1)
            x(x.Length-1) = Nothing
        End If
    Next
End Sub

versuchen, diese

InformationsquelleAutor der Antwort Lulu Lovely