Wie kann ich einem nur Teil eines hash in Perl?

Gibt es eine Möglichkeit, um eine sub-hash? Brauche ich einen hash-slice?

Beispiel:

%hash = ( a => 1, b => 2, c => 3 );

Ich will nur

%hash = ( a => 1, b => 2 );
  • Da ist nichts logisch zu "slice" ich vermute, etwas zu tun mit "Karte". In einem array, das Sie es tun würde, basiert auf einem index, sondern in einem hash gibt es keine zuverlässig interne Darstellung der Daten. Man bräuchte irgendeine Art von qualifier (regex?) zu definieren, was sollte in der subhash und was nicht.
  • BTW, Sie die hash-syntax ist falsch: verwenden Sie Runde Klammern "()" für eine einfache hash, "{}" für die anonyme hash-Referenzen.
InformationsquelleAutor Timmy | 2009-06-11
  1. 53

    Hash-slices Rückkehr der Werte verbunden mit einer Liste von Schlüsseln. Um einen hash-slice, den Sie ändern Sie die Siegel an @ und eine Liste der Schlüssel (in diesem Fall "a" und "b"):

    my @items = @hash{"a", "b"};

    Oft Sie können verwenden Sie ein Zitat Wort-operator zum erzeugen der Liste:

    my @items = @hash{qw/a b/};

    Können Sie auch zuweisen, um einen hash-slice, wenn Sie so wollen, einen neuen hash enthält eine Teilmenge der anderen hash kann man sagen

    my %new_hash;
@new_hash{qw/a b/} = @hash{qw/a b/};

    Viele Menschen nutzen eine anzeigen statt hash-slices:

    my %new_hash = map { $_ => $hash{$_} } qw/a b/;

    Beginnend mit Perl 5.20.0, erhalten Sie die Schlüssel und die Werte in einem Schritt, wenn Sie die % Siegel anstelle des @ - Siegel:

    my %new_hash = %hash{qw/a b/};
    • dies macht, warum die "Karte" funktioniert w/ hashes ein wenig klarer für mich. Dank
    • Larry Wall, brian d foy, und...Chas. Owens...vielen Dank für diese sehr ausführliche Erklärung!
    • Sie sollten wahrscheinlich machen es klar, dass ein hash-slice, nur die Werte, keine Schlüssel/Wert-Paaren.
    • Sind Sie jetzt glücklicher?
    InformationsquelleAutor Chas. Owens
  2. 9

    Würden Sie wahrscheinlich wollen einfach eine Liste von Schlüssel Sie möchten:

    my @keys = qw(a b);

    Und dann eine Schleife verwenden, um die hash:

    my %hash_slice;
for(@keys) {
  $hash_slice{$_} = %hash{$_};
}

    Oder:

    my %hash_slice = map { $_ => $hash{$_} } @keys;

    (Meine Vorliebe ist die zweite, aber je nachdem, was Ihnen gefällt, ist es am besten.)

    InformationsquelleAutor Chris Lutz
  3. 6

    Noch einen anderen Weg:

    my @keys = qw(a b);
my %hash = (a => 1, b => 2, c => 3);
my %hash_copy;
@hash_copy{@keys} = @hash{@keys};
    InformationsquelleAutor Hynek -Pichi- Vychodil
  4. 3

    Zuviel funktionale Programmierung führt mich zu denken zip ersten.

    Mit List::MoreUtils installiert,

    use List::MoreUtils qw(zip);

%hash = qw(a 1 b 2 c 3);
@keys = qw(a b);
@values = @hash{@keys};
%hash = zip @keys, @values;

    Leider der Prototyp List::MoreUtils ist zip hemmt

    zip @keys, @hash{@keys};

    Wenn Sie wirklich wollen, um zu vermeiden, die temporäre variable, Sie könnten

    zip @keys, @{[@hash{@keys}]};

    Oder schreiben Sie einfach Ihre eigenen zip ohne das problematische Vorbild. (Dies muss nicht List::MoreUtils überhaupt.)

    sub zip {
    my $max = -1;
    $max < $#$_and $max = $#$_ for @_;
    map { my $ix = $_; map $_->[$ix], @_; } 0..$max;
}

%hash = zip \@keys, [@hash{@keys}];

    Wenn du gehst zu sein, mutiert in-place,

    %hash = qw(a 1 b 2 c 3);
%keep = map +($_ => 1), qw(a b);
$keep{$a} or delete $hash{$a} while ($a, $b) = each %hash;

    vermeidet das zusätzliche kopieren, dass der map und zip Lösungen entstehen. (Ja, mutiert der hash, während Sie Durchlaufen, ist es sicher... solange die mutation ist nur das löschen der zuletzt iteriert paar.)

    • Erklären Sie diese, bitte -- %keep = map +($_ => 1), qw(a b); ?
    InformationsquelleAutor ephemient
  5. 3

    FWIW, verwende ich Moose::Autobox hier:

    my $hash = { a => 1, b => 2, c => 3, d => 4 };
$hash->hslice([qw/a b/]) # { a => 1, b => 2 };

    Im realen Leben, ich verwende extrahieren "Benutzername" und "Passwort" aus einer Formular-Vorlage, und geben, dass die Catalyst $c->authenticate (die erwartet wird, in meinem Fall, eine hashref mit dem Benutzernamen und Passwort, aber sonst nichts).

    • Wie ist $hash->hslice(qw/a b/) besser als @{$hash}{qw/a b/}? Oder ist das einer der Fälle, wo, wenn ich Fragen haben ich bin zu weit Weg, zu verstehen?
    • Sollten Sie eine Antwort haben, die Schablone so, dass "ich benutze Elch::" am Anfang jeder Antwort. 🙂
    • Chas. Owens: das ist nicht das, was hslice tut. @{$hash}{...} gibt eine Liste der Werte; hslice gibt ein neues hash-Referenz mit beiden Schlüsseln und Werten.
    InformationsquelleAutor jrockway
  6. 2

    Neu in perl 5.20 ist die hash-slices Rückkehr Schlüssel als auch als Werte mit%, wie in der letzten Zeile hier:

    my %population = ('Norway',5000000,'Sweden',9600000,'Denmark',5500000);
my @slice_values = @population{'Norway','Sweden'}; # all perls can do this
my %slice_hash   = %population{'Norway','Sweden'}; # perl >= 5.20 can do this!
    InformationsquelleAutor Kjetil S.
  7. -3

    Ein hash ist eine ungeordnete container, aber der Begriff slice macht wirklich nur Sinn in Bezug auf einen bestellten container. Vielleicht schauen Sie in einem array. Sonst, Sie können nur entfernen Sie alle Elemente, die Sie nicht wollen, zu produzieren, Ihre "sub-hash'.

    InformationsquelleAutor B Johnson
Schreibe einen Kommentar