Wie kann ich scrollen eine TScrollbar mit dem Mausrad?

Ich habe eine TScrollBar code in das OnScroll-event.

Ich will scrollen Sie mit dem Mausrad, aber drehen Sie das Mausrad nicht scrollen die scroll-Leiste und löst keine der OnScroll-event.

Irgendeine Idee?

Was nicht funktioniert?
Unter Berücksichtigung der rep, Sie sollten jetzt wissen, dass die meisten von uns können nicht viel tun, ohne Sie uns zu zeigen, Ihren code und sagen Sie uns, was Sie versucht haben und wie es nicht funktioniert (was hast du erwartet und was ist tatsächlich passiert).
Eine breitere Frage, die mir einfällt, die dies Lesen. Ich mache eine mod, die fängt die Maus-Rad-Nachricht zu bekommen, TListBox, etc 'richtig arbeiten'. Ich bin immer noch tun, diese in XE. Ist das richtig? Warum ist es noch nicht die "richtige" Verhalten aus der box mit XE? Ist das für legacy-Gründen?
-1 für "es funktioniert nicht."
Traurig. So viele Menschen eilten zu kritisieren, die Frage; keiner von denen rannte zu beantworten. Fazit: auf SO ist so einfach zu kritisieren, vor allem, wenn Sie don ' T haben eine Antwort.

InformationsquelleAutor XBasic3000 | 2011-08-15

procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var
  I: Integer;
begin
  Handled := PtInRect(ScrollBox1.ClientRect, ScrollBox1.ScreenToClient(MousePos));
  if Handled then
    for I := 1 to Mouse.WheelScrollLines do
    try
      if WheelDelta > 0 then
        ScrollBox1.Perform(WM_VSCROLL, SB_LINEUP, 0)
      else
        ScrollBox1.Perform(WM_VSCROLL, SB_LINEDOWN, 0);
    finally
      ScrollBox1.Perform(WM_VSCROLL, SB_ENDSCROLL, 0);
    end;
end;

-1 Es geht um eine Bildlaufleiste, nicht eine ScrollBox. Außerdem führen Sie arbeiten nur für/VCL-Interna.

InformationsquelleAutor Stefan

Die Standard-Komponente TScrollBar in der Tat scheint nicht in der OnMouseWheel* Veranstaltungen präsentieren. Aber Sie können einfach abtreten, wie folgt:

type
  TForm1 = class(TForm)
    ScrollBar1: TScrollBar;
    procedure FormCreate(Sender: TObject);
    procedure ScrollBar1Scroll(Sender: TObject; ScrollCode: TScrollCode;
      var ScrollPos: Integer);
  private
    procedure ScrollBarMouseWheel(Sender: TObject; Shift: TShiftState;
      WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
  end;

...

procedure TForm1.FormCreate(Sender: TObject);
begin
  ScrollBar1.OnMouseWheel := ScrollBarMouseWheel;
end;

procedure TForm1.ScrollBarMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var
  NewScrollPos: Integer;
begin
  NewScrollPos := ScrollBar1.Position - WheelDelta;
  //Trigger the OnScroll event:
  ScrollBar1.Scroll(scPosition, NewScrollPos);
  //Scroll the bar into the new position:
  ScrollBar1.Position := NewScrollPos;
  Handled := True;
end;

Sind Sie frei, zu implementieren und einige mehr kreative:

  if WheelDelta > 0 then
    NewScrollPos := ScrollBar1.Position - ScrollBar1.PageSize
  else
    NewScrollPos := ScrollBar1.Position + ScrollBar1.PageSize;

Und man konnte zwischenschalten der TScrollBar-Klasse zu vermeiden, weisen Sie das Ereignis zur Laufzeit:

type
  TScrollBar = class(StdCtrls.TScrollBar)
  protected
    function DoMouseWheel(Shift: TShiftState; WheelDelta: Integer;
      MousePos: TPoint): Boolean; override;
  end;

function TScrollBar.DoMouseWheel(Shift: TShiftState; WheelDelta: Integer;
  MousePos: TPoint): Boolean;
var
  NewScrollPos: Integer;
begin
  NewScrollPos := Position - WheelDelta;
  Scroll(scPosition, NewScrollPos);
  Position := NewScrollPos;
  Result := True;
end;

InformationsquelleAutor NGLN

es ist zu einfach, nur erhöhen Sie den Wert für die position .

procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
begin
self.VertScrollBar.Position :=  self.VertScrollBar.Position + WheelDelta;
end;

Dieser arbeitete für mich einfach verändern musste das + zu einem - sonst geht es rückwärts "invertierte scrollen" LOL

InformationsquelleAutor Safwat Safwat

procedure TForm1.FormMouseWheelDown(Sender: TObject; Shift: TShiftState;
  MousePos: TPoint; var Handled: Boolean);
begin
  ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position + 20;
end;

procedure TForm1.FormMouseWheelUp(Sender: TObject; Shift: TShiftState;
  MousePos: TPoint; var Handled: Boolean);
begin
  ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position - 20;
end;

Lesen Sie über die Formatierung von code und fixieren Sie Ihre Antwort. Es wäre viel leichter zu Lesen. stackoverflow.com/help/formatting
Die Frage ist, über eine ScrollBar, nicht eine ScrollBox.

InformationsquelleAutor Testman

Ich weiß nicht, ob dies wird Ihnen helfen viel, aber hier ist, wie tun Sie es mit einem TMemo. Die Scrollbalken werden müsste, um einen ähnlichen Prozess, es sei denn, es eine andere bessere Möglichkeit, die Delphi-Versionen später als mine benutzen.

procedure TForm1.Memo1WindowProc(var msg: TMessage);
  var
    ticks: ShortInt;
    ScrollMsg: TWMVScroll;
  begin
    if msg.Msg = WM_MOUSEWHEEL then
      begin
        ScrollMsg.Msg := WM_VSCROLL;
        ticks := HiWord(msg.wparam);
        if ticks > 0 then
          ScrollMsg.ScrollCode := sb_LineUp
        else
          ScrollMsg.ScrollCode := sb_LineDown;
        ScrollMsg.Pos:=0;
        Memo1.Dispatch(ScrollMsg) ;
      end
    else
      OldMemo1(msg);
    end;

procedure TForm1.FormCreate(Sender: TObject);
 // save old window proc, assign mine.
  begin
    OldMemo1 := Memo1.WindowProc;
    Memo1.WindowProc := Memo1WindowProc;
  end;

HTH einige.

InformationsquelleAutor Glenn1234

0

Alte post, aber ich fand die Lösung. Einfach
```
procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
begin
  inherited;

  ScrollBox1.ScrollBy(WheelDelta, 0);
end;
```
Funktioniert für mich.
- Die Frage ist, über eine ScrollBar, nicht eine ScrollBox.
- Neben der Tatsache, dass es über eine ScrollBar, mit ScrollBy scrollt die komplette Steuerung einschließlich der Bildlaufleiste selbst und scrollt horizontal. Viel bessere Ergebnisse werden erreicht durch die "ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position - WheelDelta;". Ebenfalls Behandelt werden soll, auf true festgelegt werden.
InformationsquelleAutor Lucas Magalhães

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.