Wie kann ich überprüfen ob ein array enthält einen bestimmten Wert?

wie kann ich richtig schreiben diesem ?:

If number is different from Array[1] to Array[x-1] the begin......

Nummer ist ein integer und array ist ein array von ganzen zahlen von 1 bis x

  • Ich bin sicher, ich habe Ihnen geraten, Sie nicht zu verwenden, 1-basierten array-indices. Lassen Sie mich wiederholen der Beratung.
  • Auch Array ist kein Gültiger Variablenname in Delphi.
  • Ich habe bereits gesagt, dass Filip mindestens einmal, bevor Sie auch: stackoverflow.com/questions/29594762/...
  • Ich bin mir sicher, dass Filip feststellen, dass, wenn er versucht zu kompilieren seinem code...
  • Es war nur ein stehen im Beispiel ich bin nicht mit entweder-Array als name einer array-oder 1-basiertes array
  • ich habe nur gehofft, es gibt sowas wie....wenn die Zahl <> myarray[0] myarray[x-1] dann beginnen
  • Eine Funktion, die prüft, ob ein Element enthalten ist, in ein array. Zum Beispiel in meinem code-Basis würde ich schreiben: if not TArray.Contains(arr, value) then ...

InformationsquelleAutor Filip Sulik | 2015-04-17
  1. 10

    Ich glaube, Sie wollen etwas tun, wenn number ist nicht im array gefunden MyArray. Dann kannst du es so machen:

    NoMatch := true;
for i := Low(MyArray) to High(MyArray) do
  if MyArray[i] = number then
  begin
    NoMatch := false;
    break;
   end;

if NoMatch then
  DoYourThing;

    Könnte man eine Funktion erstellen, die überprüft, ob eine Zahl in einem array. Dann können Sie mit dieser Funktion jedes mal, wenn Sie brauchen, um eine solche Prüfung. Und jedes mal, der code wird besser lesbar. Zum Beispiel könnte man es so machen:

    function IsNumberInArray(const ANumber: integer; 
  const AArray: array of integer): boolean;
var
  i: integer;
begin
  for i := Low(AArray) to High(AArray) do
    if ANumber = AArray[i] then
      Exit(true);
  result := false;
end;

...

if not IsNumberInArray(number, MyArray) then
  DoYourThing;

    Wenn Sie verwenden eine alte version von Delphi, die Sie ersetzen Exit(true) durch begin result := true; break; end. In neueren Versionen von Delphi, ich nehme an, Sie könnten auch spielen mit Sachen wie Generika.

    • Great minds think alike 😀
    • Außer dein code ist sehr Verschieden von Andreas'
    InformationsquelleAutor Andreas Rejbrand
  2. 1

    Könnte man auch schreiben eine Generische version, jedoch können Sie keine Generika mit stand-alone-Verfahren, Sie müssen gebunden werden, um eine Klasse oder aufnehmen können. So etwas wie die folgenden

    unit Generics.ArrayUtils;

interface

uses
  System.Generics.Defaults;

type
  TArrayUtils<T> = class
  public
    class function Contains(const x : T; const anArray : array of T) : boolean;
  end;

implementation

{ TArrayUtils<T> }

class function TArrayUtils<T>.Contains(const x: T; const anArray: array of T): boolean;
var
  y : T;
  lComparer: IEqualityComparer<T>;
begin
  lComparer := TEqualityComparer<T>.Default;
  for y in anArray do
  begin
    if lComparer.Equals(x, y) then
      Exit(True);
  end;
  Exit(False);
end;

end.

    Verwendung wäre

    procedure TForm6.Button1Click(Sender: TObject);
begin
  if TArrayUtils<integer>.Contains(3, [1,2,3]) then
    ShowMessage('Yes')
  else
    ShowMessage('No');
end;

    Sollten mit einem Parameter wie TArray<integer> oder array of integer sowie Konstanten-arrays (siehe Abbildung) - und man könnte hinzufügen, vielen anderen Methoden der Klasse, wie IndexOf oder Insert...

    • Brauchte etwas für TArray<TGUID> und das funktioniert perfekt. Danke!!!
    InformationsquelleAutor Alister
Schreibe einen Kommentar