Wie kann ich Variablen verwenden, um Eigenschaften in VBA (Excel)

Nehmen Sie diesen code:

With ActiveSheet.Shapes.AddShape(msoShapeRectangle, x, y, w, h).TextFrame
  .Parent.Line.Visible = False
  .Parent.Fill.ForeColor.RGB = RGB(r, g, b)
End With

Gibt es eine VBA-Möglichkeit, um "execute" oder "bewerten" wie kann man in perl/python/..., so dass der text .Parent.Line.Visible gezogen werden können aus einer Variablen (oder den Wert der Zelle), eher als hart codiert?

ParentLine = ".Parent.Line.Visible"
ParentLineValue = "False"

With ActiveSheet.Shapes.AddShape(msoShapeRectangle, x, y, w, h).TextFrame
  **eval**(ParentLine & "=" & ParentLineValue)
  .Parent.Fill.ForeColor.RGB = RGB(r, g, b)
End With

EDIT: ich fand MSDN-Informationen für den Zugang erwähnt Eval, aber wenn, führe ich meinen code, er sagt "nicht definierte Sub oder Function", dem Hinweis auf Eval (Excel scheint nicht zu wissen, diese Funktion).

EDIT 2: Gefunden die endgültige (negative) Antwort auf SO.

EDIT 3: Scheint, wie es ist, eine Antwort nach, denn ich bin nicht nach einer Allgemeinen Lösung für die Ausführung von beliebigem code. Dank GSerg für die Hilfe mit der Verwendung von CallByName.

Ich bin gespannt, Wann würde jemals wollen, dies zu tun?
Ich möchte einfach zu parametrieren, ein makro und nicht dazu zwingen, Benutzer zu Lesen, VBA, spielen Sie einfach mit Ihrer Tabellenkalkulation. Ich bin mir bewusst, die Auswirkungen auf die Sicherheit, aber das ist für limited-use nur. Vielleicht möchten Sie unterschiedliche Eigenschaften, alternativ auf, dass man.
ScriptControl ActiveX kann Ihnen helfen, zu bewerten, string mit jeder Application's Mitglied, check die Antwort.

InformationsquelleAutor asoundmove | 2011-04-18

Lösung 1.

Verwenden CallByName.

Option Explicit

Private Type Callable
  o As Object
  p As String
End Type

Public Sub SetProperty(ByVal path As String, ByVal Value As Variant, Optional ByVal RootObject As Object = Nothing)
  With GetObjectFromPath(RootObject, path)
    If IsObject(Value) Then
      CallByName .o, .p, VbSet, Value
    Else
      CallByName .o, .p, VbLet, Value
    End If
  End With
End Sub

Public Function GetProperty(ByVal path As String, Optional ByVal RootObject As Object = Nothing) As Variant
  With GetObjectFromPath(RootObject, path)
    GetProperty = CallByName(.o, .p, VbGet)
  End With
End Function

Public Function GetPropertyAsObject(ByVal path As String, Optional ByVal RootObject As Object = Nothing) As Object
  With GetObjectFromPath(RootObject, path)
    Set GetPropertyAsObject = CallByName(.o, .p, VbGet)
  End With
End Function


Private Function GetObjectFromPath(ByVal RootObject As Object, ByVal path As String) As Callable
  'Returns the object that the last .property belongs to
  Dim s() As String
  Dim i As Long

  If RootObject Is Nothing Then Set RootObject = Application

  Set GetObjectFromPath.o = RootObject

  s = Split(path, ".")

  For i = LBound(s) To UBound(s) - 1
    If Len(s(i)) > 0 Then
      Set GetObjectFromPath.o = CallByName(GetObjectFromPath.o, s(i), VbGet)
    End If
  Next

  GetObjectFromPath.p = s(UBound(s))
End Function

Verwendung:

? getproperty("activecell.interior.color")
16777215 

SetProperty "activecell.interior.color", vbYellow
'Sets yellow background

? getproperty("names.count", application.ActiveWorkbook)
0 

? getproperty("names.count", GetPropertyAsObject("application.activeworkbook"))
0

Lösung 2.

Dynamisch code hinzuzufügen.

Tun Sie das nicht. Es ist falsch, und es erfordert, dass "Zugriff auf VB-Projekt" Häckchen setzen.

Fügen Sie einen Verweis auf Microsoft Visual Basic for Applications Extensibility X.X.

Erstellen Sie ein Modul namens ModuleForCrap.

Hinzufügen eines dynamisch konstruiert sub/Funktion:

ThisWorkbook.VBProject.VBComponents("ModuleForCrap").CodeModule.AddFromString _
"function foobar() as long" & vbNewLine & _
"foobar = 42" & vbNewLine & _
"end function"`

Nennen es:

msgbox application.run("ModuleForCrap.foobar")

Löschen:

With ThisWorkbook.VBProject.VBComponents("ModuleForCrap").CodeModule
  .DeleteLines .ProcStartLine("foobar", vbext_pk_Proc), .ProcCountLines("foobar", vbext_pk_Proc)
End With

toll. Es funktioniert mit SetProperty "interior.color", vbYellow, Data.Cells(1, 5), aber für einige Grund es nicht wie SetProperty "Data.Cells(1,5).interior.color", vbYellow - aber das tut mir gut.
Ja, nur Punkte unterstützt werden, in den Pfad-string. Wenn Sie waren zur Unterstützung der embedded-Parameter, würden Sie schreiben einen umfangreichen parser, an dem Punkt wäre es einfacher, den zweiten Ansatz.

InformationsquelleAutor GSerg

1

Du könntest versuchen Sie bei CallByName, aber ich glaube nicht, dass es geht, um zu tun, was Sie wollen (zumindest nicht leicht, wenn Sie gehen zu wollen, zu bewerten, multi-dot-Objekt/Objekt-Referenzen).
- große versuchen, aber ActiveSheet.Cells(x, y) nicht unterstützen CallByName.
- jetzt verstehe ich es, CallByName ist nur eine Ebene. GSerg die Lösung ist erforderlich für multi-level.
InformationsquelleAutor Tim Williams
0

False ausgewertet zu Null. Können Sie konstruieren eine integer-variable gleich null, es entpuppen die gleiche Weise als Falsch.
- gut, aber mein problem ist viel grundlegender als das. Ich bearbeitet meine Frage, zu verfeinern, meine Fragen. Ich begreife, dass dies eher eine support-Frage, aber ich kann nicht finden, die relevanten Informationen überall.
InformationsquelleAutor Harry

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.