Wie konvertieren von Text in Numerisch Mainframe

Brauche ich zum konvertieren von als Text gespeicherte Zahlen-Datentyp(Links ausgerichtet) in einem Bereich von 2 bis 4 Ziffern auf der Numerischen format(Rechtsbündig) in Mainframes.

For eg,

Field1(Text left aligned)         Field2(Numeric Right aligned)
---------------------------------------------------------------
1000                                       1000           
11                                           11     
200                                         200

Verwenden können, SORTIEREN EZTRIEVE COBOL.

InformationsquelleAutor Srinivasan | 2011-05-11
  1. 2

    Für ein COBOL-Lösung, versuchen Sie es mit UNSTRING und ein JUSTIFIED RIGHT empfangende Feld. Hier ist ein Beispiel-Programm (mit IBM Enterprise COBOL) zu illustrieren.

      IDENTIFICATION DIVISION.                       
    PROGRAM-ID. EXAMPLE1.                        
  DATA DIVISION.                                 
  WORKING-STORAGE SECTION.                       
  01  SOURCE-DATA       PIC X(4).                
  01  DEST-DATA         PIC X(4) JUSTIFIED RIGHT. 
  PROCEDURE DIVISION.                            
      MOVE '123' TO SOURCE-DATA                  
      UNSTRING SOURCE-DATA DELIMITED BY SPACE    
          INTO DEST-DATA                         
      DISPLAY 'SOURCE >' SOURCE-DATA '<'         
      DISPLAY 'DEST   >' DEST-DATA '<'           

      MOVE '1' TO SOURCE-DATA                    
      UNSTRING SOURCE-DATA DELIMITED BY SPACE 
          INTO DEST-DATA                         
      DISPLAY 'SOURCE >' SOURCE-DATA '<'         
      DISPLAY 'DEST   >' DEST-DATA '<'           
      GOBACK                                     
      .

    Die Ausgabe dieses Programms ist:

    SOURCE >123 <    
DEST   > 123<    
SOURCE >1   <    
DEST   >   1<
    InformationsquelleAutor NealB
  2. 1

    Diese funktioniert auch...

      IDENTIFICATION DIVISION.                       
    PROGRAM-ID. STR2NUM.                        
  DATA DIVISION.                                 
  WORKING-STORAGE SECTION.                       
  01  SOURCE-DATA       PIC X(4).                
  01  DEST-DATA         PIC BBB9. 
  PROCEDURE DIVISION.                            
      MOVE '123' TO SOURCE-DATA                  
      UNSTRING SOURCE-DATA DELIMITED BY SPACE    
          INTO DEST-DATA                         
      DISPLAY 'SOURCE >' SOURCE-DATA '<'         
      DISPLAY 'DEST   >' DEST-DATA '<'           

      MOVE '1' TO SOURCE-DATA                    
      UNSTRING SOURCE-DATA DELIMITED BY SPACE 
          INTO DEST-DATA                         
      DISPLAY 'SOURCE >' SOURCE-DATA '<'         
      DISPLAY 'DEST   >' DEST-DATA '<'           
      GOBACK                                     
      .
    • Funktioniert dies nicht. Erstens, mit der Enterprise Cobol, das Ziel einer UNSTRING kann nicht sein, ein Feld bearbeitet, so erhalten Sie einen Schweren Fehler "kompilieren IGYPA3107-S "UNSTRING IN" identifier "DEST-DATEN (NUMERIC-EDITED)" war ungültig, weil es eines der folgenden sein: eine bearbeitete Element, eine externe floating-point-Element, ein alphabetisches Element mit "B" in seiner "BILD" oder ein numerischer Eintrag mit "P" in seiner "BILD". Die Erklärung wurde verworfen.". Zweitens, wenn es funktioniert hat den BBB in der Abbildung sind für die drei eigentlichen Leerzeichen, so werden die Daten abgeschnitten, um eine Ziffer/Zeichen.
    InformationsquelleAutor Raja Reddy
  3. 0

    Werde ich bitte zu unterscheiden mit den beiden anderen Antworten als Sie, IMO, sind einfach re-repräsentieren Sie den Quelltext bearbeitet alphanumerische Ausgabe. Hier ist mein stab auf Sie:

      IDENTIFICATION DIVISION.                       
  PROGRAM-ID. STR2NUM.                        
  DATA DIVISION.                                 
  WORKING-STORAGE SECTION.            
  01  WS-VARIABLES.           
    05  SRCE-DATA         PIC  X(4). 
    05  SRCE-DATA-R       PIC  X(4) JUST RIGHT.      
    05  DEST-DATA-N       PIC  9(4).         
    05  DEST-DATA         PIC  ZZZ9. 
  PROCEDURE DIVISION. 
      INITIALIZE WS-VARIABLES                           
      MOVE '11' TO SRCE-DATA                  
      UNSTRING SRCE-DATA DELIMITED BY SPACE    
          INTO SRCE-DATA-R
      INSPECT SRCE-DATA-R
          REPLACING ALL SPACES BY ZEROES
      MOVE SRCE-DATA-R TO DEST-DATA-N, DEST-DATA                         
      DISPLAY 'SOURCE >' SRCE-DATA '<'         
      DISPLAY 'DEST   >' DEST-DATA '<'           
      GOBACK                                     
      .

    Den DEST-DATEN-N-Feld hat eine echte numerische version der source-Daten.

    • Da Sie nicht besorgt über Ihre "true numeric" wird numerisch ist, können Sie UNSTRING in DEST-DATEN-N, das ist Rechtsbündig mit führenden null aufgefüllt. Spart UNTERSUCHEN, und eine BEWEGUNG und Sie würden nicht brauchen, um einen alpha-numerischen, um einen numerischen.
    InformationsquelleAutor brianc
  4. 0

    Eine "ausführliche" Antwort, als NealB ist, weniger Belastung für die CPU.

       IDENTIFICATION DIVISION. 
   PROGRAM-ID. STR2NUM. 
   DATA DIVISION. 
   WORKING-STORAGE SECTION. 
   01  SOURCE-DATA                         PIC X(4). 
       88  SD-NO-DATA                      VALUE SPACE.
   01  FILLER REDEFINES SOURCE-DATA. 
       05  SOURCE-DATA-ALL                 PIC 9(4). 
   01  FILLER REDEFINES SOURCE-DATA. 
       05  SD-LEADING-1                    PIC 9. 
       05  SD-TRAILING-3                   PIC X(3). 
           88  SD-DATA-1-LEADING           VALUE SPACE.
   01  FILLER REDEFINES SOURCE-DATA. 
       05  SD-LEADING-2                    PIC 99. 
       05  SD-TRAILING-2                   PIC XX. 
           88  SD-DATA-2-LEADING           VALUE SPACE.
   01  FILLER REDEFINES SOURCE-DATA. 
       05  SD-LEADING-3                    PIC 9(3). 
       05  SD-TRAILING-1                   PIC X. 
           88  SD-DATA-3-LEADING           VALUE SPACE.
   01  DEST-DATA                           PIC 9(4). 
   PROCEDURE DIVISION. 
       MOVE '1234'                  TO SOURCE-DATA 
       PERFORM                      PROCESS-THE-DATA 
       MOVE '123'                   TO SOURCE-DATA 
       PERFORM                      PROCESS-THE-DATA 
       MOVE '12'                    TO SOURCE-DATA 
       PERFORM                      PROCESS-THE-DATA 
       MOVE '1'                     TO SOURCE-DATA 
       PERFORM                      PROCESS-THE-DATA 
       MOVE SPACE                   TO SOURCE-DATA 
       PERFORM                      PROCESS-THE-DATA 
       GOBACK 
       . 
   PROCESS-THE-DATA. 
       EVALUATE TRUE 
           WHEN SD-NO-DATA 
             MOVE ZERO              TO DEST-DATA
           WHEN SD-DATA-1-LEADING 
             MOVE SD-LEADING-1      TO DEST-DATA
           WHEN SD-DATA-2-LEADING 
             MOVE SD-LEADING-2      TO DEST-DATA
           WHEN SD-DATA-3-LEADING 
             MOVE SD-LEADING-3      TO DEST-DATA
           WHEN OTHER 
             MOVE SOURCE-DATA-ALL   TO DEST-DATA
       END-EVALUATE 

       DISPLAY 'SOURCE >' SOURCE-DATA '<' 
               'DEST   >' DEST-DATA '<' 
       .

    Gibt:

    SOURCE >1234<DEST   >1234<
SOURCE >123 <DEST   >0123<
SOURCE >12  <DEST   >0012<
SOURCE >1   <DEST   >0001<
SOURCE >    <DEST   >0000<
    InformationsquelleAutor Bill Woodger
Schreibe einen Kommentar