Wie lese ich die 64-bit-Registry-Werte von VBScript ausgeführt als eine msi-task nach der installation?

Muss ich Lesen, den Speicherort des Temporären ASP.NET Dateien Ordner von VBScript als Teil einer post-installation tasks in einen installer erstellt mit Visual Studio 2008 deployment-Projekt.

Ich dachte, ich würde etwas wie das hier tun:

Set oShell = CreateObject("Wscript.Shell")
strPath = oShell.RegRead("HKLM\SOFTWARE\Microsoft\ASP.NET\2.0.50727.0\Path")

und dann verketten strPath mit "\Temporary ASP.NET Dateien" und mit ihm getan werden.

Auf ein x64-system, jedoch bekomme ich den Wert aus dem WOW6432Node - (HKLM\SOFTWARE\Wow6432Node\Microsoft\ASP.NET\2.0.50727.0), die gibt mir die 32-bit-framework-Pfad (C:\Windows\Microsoft.NET\Framework\v2.0.50727), aber auf einem x64 system, eigentlich will ich die 64-bit-Pfad, d.h. C:\Windows\Microsoft.NET\Framework64\v2.0.50727.

Ich verstehe, dass dies geschieht, weil die .vbs-Datei ausgeführt wird, mithilfe der 32-bit-Scripting-host durch den übergeordneten Prozess (der installer), die 32-bit selbst.

Wie kann ich das Skript mit der 64-bit-Scripting-host - oder - wie kann ich Lesen Sie die 64-bit-Werte, selbst wenn das Skript ausgeführt wird, mithilfe der 32-bit-Scripting-host?

InformationsquelleAutor Joergen Bech | 2009-08-04
  1. 9

    Nicht sicher über die Einführung der 64-bit-Scripting-host-version, aber Sie sollten in der Lage sein, um Zugriff auf die 64-bit-Registrierung-von der 32-bit-Scripting-host mithilfe der WMI - StdRegProv Klasse, wie folgt:

    Const HKEY_LOCAL_MACHINE = &H80000002
sPath = ReadRegStr (HKEY_LOCAL_MACHINE, "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", "Path", 64)
WScript.Echo sPath

' Reads a REG_SZ value from the local computer's registry using WMI.
' Parameters:
'   RootKey - The registry hive (see http://msdn.microsoft.com/en-us/library/aa390788(VS.85).aspx for a list of possible values).
'   Key - The key that contains the desired value.
'   Value - The value that you want to get.
'   RegType - The registry bitness: 32 or 64.
'
Function ReadRegStr (RootKey, Key, Value, RegType)
    Dim oCtx, oLocator, oReg, oInParams, oOutParams

    Set oCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
    oCtx.Add "__ProviderArchitecture", RegType

    Set oLocator = CreateObject("Wbemscripting.SWbemLocator")
    Set oReg = oLocator.ConnectServer("", "root\default", "", "", , , , oCtx).Get("StdRegProv")

    Set oInParams = oReg.Methods_("GetStringValue").InParameters
    oInParams.hDefKey = RootKey
    oInParams.sSubKeyName = Key
    oInParams.sValueName = Value

    Set oOutParams = oReg.ExecMethod_("GetStringValue", oInParams, , oCtx)

    ReadRegStr = oOutParams.sValue
End Function

    NB: ich bin unter einem 32-bit OS jetzt ist, kann so nicht überprüfen, dass dieses Beispiel funktioniert. Achtung, bugs!: -)

    Siehe auch die Anfordern von WMI-Daten, die auf einem 64-bit-Plattform MSDN-Artikel für mehr info über das Thema.

    • Wie machst du das, aber stellen Sie sicher nur einen Schlüssel, keinen Wert?? (Ex: siehe, wenn "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0" vorhanden ist, nicht aber der Wert "Path"
    • Müssen Sie rufen Sie EnumKey statt GetStringValue (mit entsprechenden Parametern) und prüfen, ob oOutParams.ReturnValue 0 ist. Auch finden Sie Antworten in dieser Frage: Überprüfen Sie, ob registry-Schlüssel vorhanden ist.
    • Alternativ können Sie die Abfrage der standard-Wert oReg.GetStringValue , "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", , stdv und überprüfen Sie dann IsNull(stdv). Technik inspiriert von Die Scripting Guys
    InformationsquelleAutor Helen
  2. 0

    Ich denke, so etwas wie dieses, aber ich habe nicht aussortiert wie die Verarbeitung der output-Werte.

    strComputer = "."
Const HKLM = &h80000002
Set objCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
objCtx.Add "__ProviderArchitecture", 64
objCtx.Add "__RequiredArchitecture", TRUE
Set objLocator = CreateObject("Wbemscripting.SWbemLocator")
Set objServices = objLocator.ConnectServer("","root\default","","",,,,objCtx)
Set objStdRegProv = objServices.Get("StdRegProv") 

' Use ExecMethod to call the GetStringValue method
Set Inparams = objStdRegProv.Methods_("EnumValues").Inparameters
Inparams.Hdefkey = HKLM
Inparams.Ssubkeyname = "SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names\SQL\"
'Inparams.Svaluename = "Logging"
set Outparams = objStdRegProv.ExecMethod_("EnumValues", Inparams,,objCtx)

'Show output parameters object and the registry value HKLM\SOFTWARE\
WScript.Echo Outparams.GetObjectText_
WScript.Echo "WMI Logging is set to  " & Outparams.SValue
    InformationsquelleAutor Eathen Rentz
  3. 0

    Microsoft dokumentiert approache, Helen ' s Antwort ist absolut korrekt.

    Aber nach meinen eigenen tests es stellt sich heraus, dass es ist genug, um geben Sie die __ProviderArchitecture Kontext fahne, nur an der Zeit den Anschluss an die StdRegProv-Anbieter etabliert ist.

    Dies macht die Dinge viel einfacher als nur das einrichten der Anbieter muss sein, gekapselt in einer separaten Funktion, ansonsten kann man mit dem regulären API.

    set reg64 = MakeRegLocator(64)
reg64.GetStringValue , "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", "Path", path

WScript.Echo path

' Establish a connection to the local 32 or 64 bit registry hive as requested.
' Parameters:
'   RegType - The registry bitness: 32 or 64.
function MakeRegLocator(bitness)
    set ctx = CreateObject("WbemScripting.SWbemNamedValueSet")
    ctx.Add "__ProviderArchitecture", bitness

    set locator = CreateObject("Wbemscripting.SWbemLocator")
    set services = locator.ConnectServer("", "root\default", "", "", , , , ctx)
    set reg = services.Get("StdRegProv")

    set MakeRegLocator = reg
end function
    InformationsquelleAutor klaus triendl
  4. -1

    Bitte Prüfen:

    Set oShell = CreateObject("Wscript.Shell")
    strPath = oShell.RegRead("HKLM64\SOFTWARE\Microsoft\ASP.NET\2.0.50727.0\Pfad")

    https://www.autoitscript.com/autoit3/docs/functions/RegRead.htm

    • AutoIt-Skript ist kein VBScript, die Funktionen sind nicht die gleichen
    InformationsquelleAutor Pawan Kumar
Schreibe einen Kommentar