Wie öffne ich eine URL mit dem Standard-Browser mit plattformübergreifenden FireMonkey-Anwendungen?

In der Regel verwende ich: ShellExecute(0, 'OPEN', PChar(edtURL.Text), '', '', SW_SHOWNORMAL);

Wie kann ich das gleiche Verhalten (das öffnen eines Links im Standard-browser) auf allen Plattformen (Windows und OSX)?

InformationsquelleAutor der Frage Whiler | 2011-09-16

  1. 12

    In der FireMonkey-Diskussions-forum fand ich diesen code, um eine Frage zu NSWorkspace.URLForApplicationToOpenURL:

    uses
  Posix.Stdlib;
....
  _system(PAnsiChar('open ' + ACommand));

    (nicht getestet von mir)

    Update: Posix ist unter Windows nicht verfügbar, so ist es nicht möglich zu schreiben, eine Lösung, die über die gleichen Betriebssystem-Aufrufe, die auf allen Plattformen. Ich schlage vor, zu bewegen, diesen code in eine zentrale 'XPlatform' Einheit, die einige IFDEF POSIX etc.

    InformationsquelleAutor der Antwort mjn

  2. 17

    Bezug auf die Antwort von mjnich habe das folgende geschrieben-Einheit. Ich habe erfolgreich getestet auf Windows, aber ich habe kein OSX, um es zu testen auf dieser Plattform. Wenn jemand bestätigen kann das es funktioniert, würde ich schätzen.

    unit fOpen;

interface

uses
{$IFDEF MSWINDOWS}
  Winapi.ShellAPI, Winapi.Windows;
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  Posix.Stdlib;
{$ENDIF POSIX}

type
  TMisc = class
    class procedure Open(sCommand: string);
  end;

implementation

class procedure TMisc.Open(sCommand: string);
begin
{$IFDEF MSWINDOWS}
  ShellExecute(0, 'OPEN', PChar(sCommand), '', '', SW_SHOWNORMAL);
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  _system(PAnsiChar('open ' + AnsiString(sCommand)));
{$ENDIF POSIX}
end;

end.

    und ich rufe es wie folgt: 

    TMisc.Open('https://stackoverflow.com/questions/7443264/how-to-open-an-url-with-the-default-browser-with-firemonkey-cross-platform-applic');

    InformationsquelleAutor der Antwort Whiler

  3. 3

    XE2 C++ - code, der erfolgreich getestet (Windows 7 64 und OSX Lion), kleinere Verbesserungen. Danke Whiler, der Schmerz ist vorbei 🙂

    #include <fmx.h>
//---------------------------------------------------------------------------
#ifdef _WIN32
#include <shellapi.h>
#endif//Windows
#ifdef TARGET_OS_MAC
#include <Posix.Stdlib.hpp>
#endif //Mac

void OpenCommand(String _sCommand) {
    #ifdef _Windows
    String open = "open";
    ShellExecute(0, open.w_str(), _sCommand.c_str(), NULL, NULL, SW_SHOWNORMAL);
    #endif //Windows

    #ifdef TARGET_OS_MAC
    system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif //Mac
}

    InformationsquelleAutor der Antwort Tuomas Kayhko

  4. 2

    Für alle Plattformen (Windows, macOs, iOS und Android) Sie können die Einheit verwenden, schrieb ich für mein blog

    unit u_urlOpen;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes,
  System.Variants,
{$IF Defined(IOS)}
  macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS;
{$ELSEIF Defined(ANDROID)}
Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Net,
   Androidapi.JNI.App,
  Androidapi.helpers;
{$ELSEIF Defined(MACOS)}
Posix.Stdlib;
{$ELSEIF Defined(MSWINDOWS)}
Winapi.ShellAPI, Winapi.Windows;
{$ENDIF}

type
  tUrlOpen = class
    class procedure Open(URL: string);
  end;

implementation

class procedure tUrlOpen.Open(URL: string);
{$IF Defined(ANDROID)}
var
  Intent: JIntent;
{$ENDIF}
begin
{$IF Defined(ANDROID)}
  Intent := TJIntent.Create;
  Intent.setAction(TJIntent.JavaClass.ACTION_VIEW);
  Intent.setData(StrToJURI(URL));
  tandroidhelper.Activity.startActivity(Intent);
  // SharedActivity.startActivity(Intent);
{$ELSEIF Defined(MSWINDOWS)}
  ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL);
{$ELSEIF Defined(IOS)}
  SharedApplication.OpenURL(StrToNSUrl(URL));
{$ELSEIF Defined(MACOS)}
  _system(PAnsiChar('open ' + AnsiString(URL)));
{$ENDIF}
end;

end.

    InformationsquelleAutor der Antwort Patrick PREMARTIN

  5. 1

    Als @NicoBlu erwähnt, die akzeptierte Lösung scheint kürzen Sie die URL nach dem ersten vorkommen von '&'. Hier ist, was funktioniert für mich ohne Trunkierung:

    uses Macapi.AppKit, Macapi.Foundation, Macapi.Helpers;

// ...

procedure OpenLinkInDefaultBrowser(const Link: string);
  var URL : NSURL;
      Workspace : NSWorkspace;
begin
  URL := TNSURL.Wrap(TNSURL.OCClass.URLWithString(StrToNSStr(Link)));
  Workspace := TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace);
  Workspace.openURL(URL);
end;

    InformationsquelleAutor der Antwort DNR

  6. 1

    Und nun eine C++ - version (OSx-code ungetestet, auch nicht sicher über die _POSIX #def):

    #ifdef _Windows
#include <Winapi.Windows.hpp>
#endif //_Windows
#ifdef _POSIX
#include <Posix.Stdlib.h>
#endif //_POSIX

void OpenCommand(String _sCommand)
{
    #ifdef _Windows
    ShellExecute(0, _T("open"), _sCommand.c_str(), _T(""), _T(""), SW_SHOWNORMAL);
    #endif //_Windows
    #ifdef _POSIX
    _system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif //_POSIX
}

    InformationsquelleAutor der Antwort Rhys Drummond

  7. 0
    _system(PAnsiChar('open ' + AnsiString(sCommand)));

    nicht funktioniert, wenn Sie die URL-Zeichenfolge (sCommand) enthält ein kaufmännisches und-Zeichen (&), die nötig sind, um anzugeben, viele Argumente im querystring.

    URL sended zu def. browser in OSX (Safari) wird abgeschnitten, beim ersten auftreten von &.

    InformationsquelleAutor der Antwort NicoBlu

  8. 0
    LEncodedString : String;

begin
    LEncodedString := TIdURI.URLEncode('http://www.malcolmgroves.com');
    sharedApplication.openURL(StringToNSURL(LEncodedString));
end;

    InformationsquelleAutor der Antwort Maxime Bonin

Schreibe einen Kommentar