Wie Sie per drag-and-drop Zeile in der gleichen datagridview

In eine Windows-Anwendung (Visual Studio) - (VB -) wie Sie mit drag und drop eine einzelne Zeile an eine andere postition zu ermöglichen für den Benutzer, um die Reihenfolge der Zeile? Ich habe nicht gefunden eine würdige Beispiele für diese noch.

InformationsquelleAutor Troy Mitchel | 2012-07-19

Hier ist ein vb-version aus C# Antwort: Wie konnte ich per Drag und Drop DataGridView Zeilen unter einander?

Die form-Klasse von Variablen:

Private fromIndex As Integer
Private dragIndex As Integer
Private dragRect As Rectangle

Drag-Ereignis:

Private Sub DataGridView1_DragDrop(ByVal sender As Object, _
                                   ByVal e As DragEventArgs) _
                                   Handles DataGridView1.DragDrop
  Dim p As Point = DataGridView1.PointToClient(New Point(e.X, e.Y))
  dragIndex = DataGridView1.HitTest(p.X, p.Y).RowIndex
  If (e.Effect = DragDropEffects.Move) Then
    Dim dragRow As DataGridViewRow = e.Data.GetData(GetType(DataGridViewRow))
    DataGridView1.Rows.RemoveAt(fromIndex)
    DataGridView1.Rows.Insert(dragIndex, dragRow)
  End If
End Sub

Private Sub DataGridView1_DragOver(ByVal sender As Object, _
                                   ByVal e As DragEventArgs) _
                                   Handles DataGridView1.DragOver
  e.Effect = DragDropEffects.Move
End Sub

Die Maus-Ereignisse:

Private Sub DataGridView1_MouseDown(ByVal sender As Object, _
                                    ByVal e As MouseEventArgs) _
                                    Handles DataGridView1.MouseDown
  fromIndex = DataGridView1.HitTest(e.X, e.Y).RowIndex
  If fromIndex > -1 Then
    Dim dragSize As Size = SystemInformation.DragSize
    dragRect = New Rectangle(New Point(e.X - (dragSize.Width / 2), _
                                       e.Y - (dragSize.Height / 2)), _
                             dragSize)
  Else
    dragRect = Rectangle.Empty
  End If
End Sub

Private Sub DataGridView1_MouseMove(ByVal sender As Object, _
                                    ByVal e As MouseEventArgs) _
                                    Handles DataGridView1.MouseMove
  If (e.Button And MouseButtons.Left) = MouseButtons.Left Then
    If (dragRect <> Rectangle.Empty _
    AndAlso Not dragRect.Contains(e.X, e.Y)) Then
      DataGridView1.DoDragDrop(DataGridView1.Rows(fromIndex), _
                               DragDropEffects.Move)
    End If
  End If
End Sub

Stellen Sie sicher, dass die Gitter AllowDrop - Eigenschaft auf true festgelegt.

Kann mir jemand beantworten, warum bekomme ich diesen Fehler, wenn Sie eine Zeile irgendwo in der Datagridview? Rows cannot be programmatically added to the DataGridView's rows collection when the control is data-bound.
Wie der Fehler sagt, Ihre raster-Daten gebunden (Sie haben eine Datenquelle in es), was bedeutet, dass Sie können nicht ändern die Gitter direkt. In Ihrem Fall müssen Sie zum Bearbeiten der Datenquelle statt. Wenn Sie Probleme haben, stellen Sie eine neue Frage, und dokumentieren Sie entsprechend.
wie kann ich die Daten Bearbeiten, die Quelle statt? das ist mein code zum Befüllen des datagridview:

con = New SqlConnection             con.ConnectionString = "Data Source=mssql;Initial Catalog=DATABASE;User ID=sa;Password="             con.Open()              adap = New SqlDataAdapter("SELECT * FROM tablename", con)             ds = New System.Data.DataSet()             adap.Fill(ds, "TableNew")             Datagridview1.DataSource = ds.Tables(0)             con.Close()

Ihre Daten Tisch: ds.Tables(0). Wenn Sie eine Zeile hinzufügen, die Daten-Tabelle, in Ihrem raster wird automatisch angezeigt.

InformationsquelleAutor LarsTech

UPDATE:

Statt

 If dragIndex < 0 Then dragIndex = DataGridView1.RowCount - 1

änderung

 If dragIndex > -1 Then 
      'action if not selected in the row header and blank space
 else
      'return error if selected in the column header and blank space
 end if

dann ein Fehler Auftritt, wenn Sie ziehen Sie eine Zeile, um die "leere zone", wenn Sie mir nicht glauben, müssen Sie es versuchen.

Finale code (Nur der Teil "Die drag-Ereignisse") ist dieser:

  Private Sub DataGridView1_DragDrop(ByVal sender As Object, ByVal e As DragEventArgs) Handles DataGridView1.DragDrop
        Dim p As Point = DataGridView1.PointToClient(New Point(e.X, e.Y))
        dragIndex = DataGridView1.HitTest(p.X, p.Y).RowIndex
    'Determine if dragindex is valid row index       
    If dragIndex > -1 Then
        If (e.Effect = DragDropEffects.Move) Then
            Dim dragRow As DataGridViewRow = CType(e.Data.GetData(GetType(DataGridViewRow)), DataGridViewRow)
            DataGridView1.Rows.RemoveAt(fromIndex)
            DataGridView1.Rows.Insert(dragIndex, dragRow)
            'Add this line of code if you want to put selected rows to the rows that change
            DataGridView1.Rows(dragIndex).Selected = True
        End If 
       Else 'Do any message here if selected in column header and blank space. 
       End If
    End Sub

InformationsquelleAutor Adrian LG

Hier ist eine Kontrolle ohne die genannten Fehler.

Set AllowUserToOrderRows und AllowDrop zu True im Windows Forms-Designer ein und ziehen Sie die Zeilen-Header, nicht den Inhalt.

Imports System.ComponentModel

Public Class BetterDataGridView
    Inherits DataGridView

    <Category("Behavior"), DefaultValue(False)>
    Public Property AllowUserToOrderRows As Boolean = False

    Protected Overrides Sub OnMouseDown(e As MouseEventArgs)
        MyBase.OnMouseDown(e)

        Dim hitInfo As HitTestInfo = HitTest(e.X, e.Y)
        If AllowUserToOrderRows AndAlso
                e.Button = MouseButtons.Left AndAlso
                hitInfo.ColumnIndex = -1 AndAlso
                ValidRow(hitInfo.RowIndex) Then
            DoDragDrop(Rows(hitInfo.RowIndex), DragDropEffects.Move)
        End If
    End Sub

    Protected Overrides Sub OnDragOver(e As DragEventArgs)
        MyBase.OnDragOver(e)

        Dim dragRow As DataGridViewRow = e.Data.GetData(GetType(DataGridViewRow))
        Dim targetIndex As Integer = GetRowIndex(e)
        e.Effect = If(ValidRowDragDrop(dragRow, targetIndex),
                      DragDropEffects.Move,
                      DragDropEffects.None)
    End Sub

    Protected Overrides Sub OnDragDrop(e As DragEventArgs)
        MyBase.OnDragDrop(e)

        Dim dragRow As DataGridViewRow = e.Data.GetData(GetType(DataGridViewRow))
        Dim targetIndex As Integer = GetRowIndex(e)

        If e.Effect = DragDropEffects.Move AndAlso ValidRowDragDrop(dragRow, targetIndex) Then
            EndEdit()

            Rows.Remove(dragRow)
            Rows.Insert(targetIndex, dragRow)

            ClearSelection()
            dragRow.Selected = True
        End If
    End Sub

    Protected Function ValidRow(rowIndex As Integer) As Boolean
        Return rowIndex >= 0 AndAlso
            rowIndex < Rows.Count - If(AllowUserToAddRows, 1, 0)
    End Function

    Protected Function GetRowIndex(e As DragEventArgs) As Integer
        Dim clientPos As Point = PointToClient(New Point(e.X, e.Y))
        Return HitTest(clientPos.X, clientPos.Y).RowIndex
    End Function

    Protected Function ValidRowDragDrop(dragRow As DataGridViewRow, targetIndex As Integer) As Boolean
        Return dragRow IsNot Nothing AndAlso
            ValidRow(targetIndex) AndAlso
            targetIndex <> dragRow.Index AndAlso
            Rows.Contains(dragRow)
    End Function
End Class

Hinweis: das Steuerelement wird nur angezeigt in der toolbox, nachdem Sie erfolgreich das Projekt.
Ich habe auch festgestellt, dass ich, wenn ich verlängern einige WinForms-Steuerelemente dann der neue code muss kompiliert werden, wie 32-bit, um zu arbeiten (und können daher nur gesehen werden in der toolbox einmal zusammengestellt, wie 32-bit). Siehe stackoverflow.com/a/26539992/1624894 für details.

InformationsquelleAutor John

Danke für alles, code arbeiten. Ich war immer nur ein Fehler. Ich löste es.

wenn das datagridview "Bearbeitung Aktivieren" gesetzt ist, erhalten Sie eine Fehlermeldung, wenn Sie werfen Zeilenabstand. Sie können versuchen,. Ich löste es wie folgt:

    Private Sub DataGridView1(ByVal sender As Object, ByVal e As DragEventArgs) Handles DataGridView1.DragDrop

    Dim p As Point = DataGridView1.PointToClient(New Point(e.X, e.Y))
                    dragIndex = DataGridView1.HitTest(p.X, p.Y).RowIndex
                    If (e.Effect = DragDropEffects.Move) Then
                        Dim dragRow As DataGridViewRow = CType(e.Data.GetData(GetType(DataGridViewRow)), DataGridViewRow)

                        If dragIndex = DataGridView1.RowCount - 1 Then '**ADD THIS AREA**
                            DataGridView1.Rows.RemoveAt(fromIndex)
                            DataGridView1.Rows.Insert(DataGridView1.RowCount - 1, dragRow)
                        Else
                            If dragIndex < 0 Then dragIndex = DataGridView1.RowCount - 2 '**this is important**
                            DataGridView1.Rows.RemoveAt(fromIndex)
                            DataGridView1.Rows.Insert(dragIndex, dragRow)
                        End If
                    End If
End Sub

Vielen Dank für alle weiteren Informationen

InformationsquelleAutor Yucel Solmaz

1.5 Verbesserungen für die Veranstaltung GridView.DragDrop:

Den ersten 50% Verbesserung Zu vermeiden, die descriped Fehler können Sie auch verwenden,

Private Sub DgvSearchFieldCurrent_DragDrop( _
   ByVal sender As  Object, ByVal e As DragEventArgs) _
   Handles DgvSearchFieldCurrent.DragDrop

Dim LclDgv As DataGridView = CType(sender, DataGridView)

If dragIndex > -1 AndAlso dragIndex < LclDgv.RowCount -1 Then

Zweite ist, setzen Sie den Fokus auf die aktuelle Zeile und die erste Zelle:

LclDgv.Rows.Insert(dragIndex, dragRow)

LclDgv.Rows(fromIndex).Selected = False
LclDgv.Rows(dragIndex).Selected = True

For Each C As DataGridViewColumn In LclDgv.Columns
  LclDgv(C.Index, fromIndex).Selected = False
Next

LclDgv(0, dragIndex).Selected = True

InformationsquelleAutor Tzwenni

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.