Wie Sie programmgesteuert markieren Sie ein Datum in Delphi TDateTimePicker Kalender?

Ja, Sie können dies tun. Zuerst müssen Sie zum initialisieren der Steuerung:

const
  DTM_GETMCSTYLE = DTM_FIRST + 12;
  DTM_SETMCSTYLE = DTM_FIRST + 11;
...
SendMessage(DateTimePicker1.Handle,
  DTM_SETMCSTYLE,
  0,
  SendMessage(DateTimePicker1.Handle, DTM_GETMCSTYLE, 0, 0) or MCS_DAYSTATE);

(uses CommCtrl).

Dann klicken Sie einfach auf die Sie reagieren müssen, um die MCN_GETDAYSTATE Benachrichtigung. Sie können entweder erstellen Sie Ihre eigenen TDateTimePicker Nachkomme, oder Sie können ein 'Abfangjäger'.

type
  TDateTimePicker = class(ComCtrls.TDateTimePicker)    
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

  ...

procedure TDateTimePicker.WndProc(var Message: TMessage);
var
  i: integer;
begin
  inherited;
  case Message.Msg of
    WM_NOTIFY:
      with PNMDayState(Message.LParam)^ do
        if nmhdr.code = MCN_GETDAYSTATE then
        begin
          // The first visible day is SystemTimeToDateTime(stStart);
          // cDayState is probably three, because most often three months are
          // visible at the same time. Of course, the second of these is the
          // 'currently displayed month'.
          // Each month is represented by a DWORD (32-bit unsigned integer)
          // bitfield, where 0 means not bold, and 1 means bold.
          // For instance, the following code will select all days:
          for i := 0 to cDayState - 1 do
            PMonthDayState(Cardinal(prgDayState) + i*sizeof(TMonthDayState))^ := $FFFFFFFF;
        end;
  end;
end;

Weiteres Beispiel: nehmen Sie an, dass die aktuelle Anzeige besteht aus drei Monaten, und dass Sie nur wollen, wählen Sie die Tage in der "aktuell angezeigten Monats", das heißt, in der Mitte Monat. Angenommen, Sie möchten jeden Dritten Tag ausgewählt werden, beginnend mit einem ausgewählten Tag.

Dann werden Sie wollen, verwenden Sie die bitfields

Month  Bitfield
0      00000000000000000000000000000000
1      01001001001001001001001001001001
2      00000000000000000000000000000000

die

Month  Bitfield
0      $00000000
1      $49249249
2      $00000000

in hexadezimal. So müssen Sie

for i := 0 to cDayState - 1 do
  if i = 1 then
    PMonthDayState(cardinal(prgDayState) + i*sizeof(TMonthDayState))^ := $49249249
  else
    PMonthDayState(cardinal(prgDayState) + i*sizeof(TMonthDayState))^ := $00000000;