wie Sie sich bei der Drupal-Benutzer (oder bekomme derzeit-angemeldete Benutzer) von Flex/Flash?

Ich habe eine Flash-Anwendung gehostet wird, die innerhalb einer Drupal Seite. Einige Teile der Flash-Anwendung sollte für alle Benutzer verfügbar sein, aber einige sollten nur für einen angemeldeten Benutzer. (Die spezifische Rolle, keine Rolle, nur, dass Sie von jedem autorisierten Benutzer der Website).

Innerhalb von Flash, kann ich erkennen, ob der Benutzer angemeldet ist, die durch screen-scraping "?q=user" - Seite, aber diese ist sehr spröde. Was ist die "richtige" Art und Weise, dies zu tun? Ich kann die Installation zusätzlicher Module, wenn nötig, aber Sie brauchen, um kompatibel mit Drupal 6, nicht 5.

Ähnlich, wenn derzeit kein Benutzer angemeldet, wie kann ich einen Benutzernamen und ein Passwort, dass Sie an mich und protokollieren Sie (oder bestimmen Sie, dass das Passwort schlecht ist)?

InformationsquelleAutor Eric | 2008-11-11

4

Die "richtige" Lösung

werden Sie wahrscheinlich wollen, um uns etwas anzuschauen, wie die services-Modul. im Grunde wollen Sie aussetzen, Nutzer von Dienstleistungen, um Ihre flash-app, so senden Sie Anfragen (per XML-RPC, oder was auch immer die Umsetzung, die Sie wählen), um Informationen wie "was ist der Zugang muss der aktuelle Benutzer eingeloggt" oder "login mit diesem Benutzer mit username x und Kennwort y" usw...

Die do it yourself-schnell-Lösung

wenn Sie vertraut sind mit der Modul-Entwicklung, erstellen Sie Ihre eigenen module schnell zu bekommen, die Funktionalität, die Sie benötigen, ohne zu gehen durch eine "echte" web-services-Schicht. hier ein kurzes Beispiel, erstellen Sie ein Modul namens "myservices":
```
<?php
//myservices.info
   name = My Services
   description = Expose basic services
   core = 6.x

<?php
//myservices.module

   function myservices_menu() {
       $items['myservices/user'] = array(
         'title' => 'Get auth',
         'page callback' => 'myservices_get_user',
         'access arguments' => array('access content'),
       );
       return $items;
   }

   function myservices_get_user() {
       global $user;
       if (in_array('authenticated user', $user->roles) ) {
           print 'yes';
       } else {
           print 'no';
       }
   }
```
diese beiden Dateien in ein Verzeichnis "myservices" in Ihrem Modul-Verzeichnis, aktivieren Sie es, und gehen Sie dann zu http://yourdomain.com/myservices/user

wenn Sie authentifiziert sind, werde es einfach zurück yes, und wenn nicht no usw..., die Sie abholen können in Ihrem flash-app.

InformationsquelleAutor Owen

War ich in der Lage, dies zu tun mit Drupal "system" und "Benutzer" Dienstleistungen:

installieren Sie die Services-Modul
aktivieren Sie die "system" und "Benutzer" Dienstleistungen
für den folgenden code, deaktivieren Sie die API-Keys. (Oder lassen Sie diese aktiviert und liefern zusätzliche Argumente)
Berechtigung authentifizierte und anonyme Benutzer auf die Dienste zugreifen

Als dies geschrieben wurde, die AMFPHP-service ist noch nicht portiert nach Drupal 6, so habe ich XMLRPC. Für XMLRPC verwenden von ActionScript habe ich die helper-Bibliothek auf as3-rpclib. Diese Bibliothek wurde geschrieben für ActionScript2, so es mit mit Flex3 mir erforderlich, um den patch, wie beschrieben, auf auf dieser Seite (scrollen Sie die Seite und suchen für einen Kommentar am Mai 10, 2008, von "jameshyu").

Sobald alle diese Voraussetzungen werden berücksichtigt, können Sie den aktuell angemeldeten Benutzer (wenn vorhanden) und/oder loggen Sie sich ein Benutzer mit code wie dem folgenden.

Hier ist das Modul tatsächlich implementiert die Anmeldung:

package
{
    import com.ak33m.rpc.xmlrpc.XMLRPCObject;

    import flash.events.*;
    import flash.net.*;

    import mx.collections.ItemResponder;
    import mx.rpc.AsyncToken;
    import mx.rpc.events.FaultEvent;
    import mx.rpc.events.ResultEvent;


    public class DrupalLogin
    {
        private var _api:XMLRPCObject;

        public function DrupalLogin( url:String )
        {
            _api = new XMLRPCObject();
            _api.endpoint = url;
            _api.destination = "";
        }

        public function set LoginResult( fn:Function ):void {_handleLoginResult = fn; }
        public function set CheckResult( fn:Function ):void {_handleCheckResult = fn; }
        public function set LogoutResult( fn:Function ):void {_handleLogoutResult = fn; }
        public function get User():String { return _user; }
        public function set TraceResult( fn:Function ):void {_handleTrace = fn; }

        private var _handleLoginResult:Function;
        private var _handleCheckResult:Function;
        private var _handleLogoutResult:Function;
        private var _handleTrace:Function;

        private function onTrace( st:String ):void
        {
            _handleTrace(st);
        }

        private var _firstCheckDone:Boolean = false;
        private var _loggedIn:Boolean = false;


        //The logged-in user's ID (if any)
        private var _user:String = "";



        //*****************************************
        //doLogin
        //*****************************************

        //Function doLogin kicks off the process.
        public function doLogin( user:String, pwd:String ):void
        {
            onTrace( "******************* doLogin ********************" );

            if( !_firstCheckDone )
            {
                _handleLoginResult( false, "ALWAYS CALL doCheck() FIRST TO SEE IF YOU NEED TO LOG IN OR NOT" );
                return;
            }
            if( _loggedIn )
            {
                _handleLoginResult( true, "YOU ARE ALREADY LOGGED IN" );
                return;
            }

            var token:AsyncToken = _api.call( "user.login", _sid, user, pwd );
            var tresponder:ItemResponder = new ItemResponder(this.onLoginInfo,this.onLoginFault);
            token.addResponder(tresponder);
        }


        private function onLoginInfo (event:ResultEvent,token:Object = null):void
        {
            onTrace( "... got onLoginInfo" );

            _user = event.result.user.name;
            _loggedIn = true;
            _handleLoginResult( true, "logged in ok" );         
        }

        private function onLoginFault (event:FaultEvent, token:Object=null):void
        {
            onTrace( "   got onLoginFault" );

            _loggedIn = false;
            _handleLoginResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
        }


        //*****************************************
        //doLogout
        //*****************************************

        public function doLogout():void
        {
            onTrace( "******************* doLogout ********************" );

            if( !_firstCheckDone )
            {
                _handleLogoutResult( false, "ALWAYS CALL doCheck() FIRST TO SEE IF YOU ARE ABLE TO LOG OUT OR NOT" );
                return;
            }
            if( !_loggedIn )
            {
                _handleLogoutResult( true, "YOU ARE ALREADY LOGGED OUT" );
                return;
            }

            var token:AsyncToken = _api.call( "user.logout", _sid );
            var tresponder:ItemResponder = new ItemResponder(this.onLogoutInfo,this.onLogoutFault);
            token.addResponder(tresponder);
        }

        private function onLogoutInfo (event:ResultEvent,token:Object = null):void
        {
            onTrace( "got onLogoutInfo" );

            _loggedIn = false;
            _handleLogoutResult( true, "logged out ok" );           
        }

        private function onLogoutFault (event:FaultEvent, token:Object=null):void
        {
            onTrace( "got onLogoutFault" );

            _loggedIn = false;
            _handleLogoutResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
        }


        //*****************************************
        //doCheckLogin
        //*****************************************

        private var _sid:String;

        public function doCheckLogin():void
        {
            onTrace( "******************* doCheckLogin ********************" );

            var token:AsyncToken = _api.call( "system.connect" );
            var tresponder:ItemResponder = new ItemResponder(this.onCheckInfo,this.onCheckFault);
            token.addResponder(tresponder);

        }

        private function onCheckInfo (event:ResultEvent,token:Object = null):void
        {
            onTrace( "got onCheckInfo" );

            _user = event.result.user.name;
            _sid = event.result.user.sid;
            var roles:Object = event.result.user.roles;
            _loggedIn = false;
            for( var i:int=0; i<10; i++ )
            {
                var tmp:String = roles[i.toString()];
                if( tmp == "authenticated user" )
                    _loggedIn = true;
            }

            trace( "user = " + _user + ", sid=" + _sid + ", loggedIn=" + _loggedIn );
            _firstCheckDone = true;

            _handleCheckResult( _loggedIn, _loggedIn?("Currently logged in as " + _user):"Not logged in yet" );
        }

        private function onCheckFault (event:FaultEvent, token:Object=null):void
        {
            onTrace( "got onCheckFault" );

            _handleCheckResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
        }

    }
}

und hier ist ein Beispiel der Verwendung:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Script source="LoginExample.as" />
    <mx:Button id="btnGoodLogin" click="btnGoodLogin_onClick()"  label="Good Login" enabled="true" y="28"/>
    <mx:Button id="btnBadLogin" click="btnBadLogin_onClick()"  label="Bad Login" enabled="true" y="28" x="112"/>
    <mx:Button id="btnLogout" click="btnLogout_onClick()"  label="Logout" enabled="true" y="28" x="219"/>
    <mx:Button id="btnCheck" click="btnCheck_onClick()"  label="Check" enabled="true" y="28" x="325"/>
    <mx:Text id="txtResult"  y="58" width="263"/>
</mx:Application>





import flash.events.*;
import flash.net.*;

private var _login:DrupalLogin;

private function setup():void
{
    if( _login==null )
    {
        var url:String = "http://myserver/mydrupal?q=services/xmlrpc";

        _login = new DrupalLogin(url);
        _login.CheckResult = handleCheckResult;
        _login.LoginResult = handleLoginResult;
        _login.LogoutResult = handleLogoutResult;
        _login.TraceResult = handleTraceResult;
    }
}

private function btnGoodLogin_onClick():void
{
    setup();
    _login.doLogin( "goodname", "goodpwd" );
}

private function btnBadLogin_onClick():void
{
    setup();
    _login.doLogin( "badname", "badpwd" );
}

private function btnLogout_onClick():void
{
    setup();
    _login.doLogout();
}

private function btnCheck_onClick():void
{
    setup();
    _login.doCheckLogin();
}



private function showResult( result:String):void
{
    trace( "showResult: " + result );
    txtResult.text = result;    
}

private function handleTraceResult( text:String ):void
{
    trace( text );
}



private function handleCheckResult( loggedIn:Boolean, txt:String="" ):void
{
    if( txt != "" )
        txt = " (" + txt + ")";

    if( loggedIn )
        showResult( "ALREADY LOGGED IN AS " + _login.User + txt);
    else
        showResult( "NOT LOGGED IN YET" + txt );
}

private function handleLoginResult( loggedIn:Boolean, txt:String="" ):void
{
    if( txt != "" )
        txt = " (" + txt + ")";

    if( loggedIn )
        showResult( "LOGIN ATTEMPT SUCCEEDED" + txt);
    else
        showResult( "LOGIN ATTEMPT FAILED" + txt );
}

private function handleLogoutResult( loggedOut:Boolean, txt:String="" ):void
{
    if( txt != "" )
        txt = " (" + txt + ")";

    if( loggedOut )
        showResult( "LOGOUT ATTEMPT SUCCEEDED" + txt );
    else
        showResult( "LOGOUT ATTEMPT FAILED" + txt);
}

InformationsquelleAutor Eric

0

Ich weiß, das ist ein langer Weg aus, wenn dieser post wurde ursprünglich gemacht, aber wenn Sie noch interessiert sind diese und nahm nie die Zeit, um es zu erforschen viel, ich habe herausgefunden, wie man erfolgreich Prozess einen login über ein flash-Dokument. (Eingebettet oder extern, für diese Angelegenheit.) Es Bedarf nicht einmal AMFPHP installiert werden auf dem system. (Das ist gut, denn zuletzt habe ich geprüft das Modul services, die AMFPHP, hängt von der noch nicht über eine status empfohlen.)

Ich eine demo-Seite hier: AS3-Login Demo-Seite

Können Sie sich anmelden und Abmelden, und es wird erkannt, wenn Sie bereits angemeldet sind. Es ist immer noch ein work in progress, aber die meisten der Sachen, die Sie brauchen, ist für Sie festgelegt.

Wenn Sie möchten, um zu sehen, die Dokumentation und die wollen eine Kopie der Quelle, all das finden Sie hier: http://www.andrewnprice.com

Ich hoffe, das hilft. Ich sein sollte, ein update für die demo irgendwann in der nächsten Woche, so überprüfen Sie zurück, wenn Sie wollen, einige der anderen Funktionen, die ich erwähnen das hinzufügen in der post.

InformationsquelleAutor

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.

Die "richtige" Lösung

Die do it yourself-schnell-Lösung