Wie vergleichen Sie die Struktur einer Tabelle in SAS

Ich bin ein tester und ich müssen für den Vergleich von zwei Datensätzen die Struktur (nicht die Daten zur Tabelle) in SAS.
Ich habe versucht, 'proc vergleichen", sondern vergleicht die Daten. Ich möchte vergleichen Datensatz/Struktur der Tabelle (Spaltenname, Datentyp, null-constraints etc).

Kann einer bitte helfen?

InformationsquelleAutor sachin | 2010-09-29
  1. 6

    Können Sie befragen die Ansichten in SASHELP (vtable, vcolumn etc), dies zu tun. Eine schnelle Möglichkeit wäre das erstellen einer temporären Tabelle aus sashelp.vcolumn für jede der beiden Tabellen, die Sie vergleichen wollen, dann verwenden Sie einen PROC SQL-join zu vergleichen. Dann vergleichen Sie die Strukturen, die in den Daten dargestellt, die aus vcolumn.

    Mit diesem Einstieg haben Sie einen Blick an, was Sie in SASHELP.vcolumn.

    Hier ist ein einfaches Beispiel für die Anwendung dieser Methode zum vergleichen von Variablen in 2 Datensätzen.

    * provide names of the two data sets here ;
%let ds1=TheFirstDataSet;
%let ds2=TheOtherDataSet;

* upcase the data set names ;
%let ds1=%sysfunc(upcase(&ds1));
%let ds2=%sysfunc(upcase(&ds2));

proc sql;
* retrieve info on these tables from sashelp.vcolumn;
  create table first as select * from sashelp.vcolumn where upcase(memname)="&ds1";
  create table second as select * from sashelp.vcolumn where upcase(memname)="&ds2";
* join these data sets and report on differences for var names;
  select coalescec(f.name,s.name) as varName
        ,case
          when f.name is null then "This var is in &ds2 only"
          when s.name is null then "This var is in &ds1 only"
          else 'This var is in both data sets'
          end as DiffDescription
  from 
    first as f
    full outer join 
      second as s 
      on f.name=s.name
  ;
quit;

    Können Sie verallgemeinern, dies für andere Attribute wie Datentyp, Länge, label etc., alle, die in vcolumn.

    • Beachten Sie, dass müssen Sie möglicherweise ändern Sie diesen code, um Platz für librefs, dass Ihre Datensätze haben können.
    InformationsquelleAutor sasfrog
  2. 3

    Schreiben Sie die Deskriptor-Teile von Datensätzen mit proc contents dann verwenden proc compare zu sehen, wie Ihre Strukturen unterscheiden. Die out2-option zu schreiben, Integritätsbedingungen, wenn Sie vorhanden sind. Wenn nicht, ist der Datensatz leer sein. Einige Spalten wie CRDATE (ERSTELLUNGSDATUM), oder LIBNAME oder MEMNAME, kann erwartet werden, unterscheiden sich und so können Sie ausschließen möchten, diejenigen, die aus dem Vergleich.

    /* create some fake data similar to an existing one */
proc sql;
create table myclass as 
  select *, "foo" as newcol from sashelp.class
;
/* modify it */
  insert into myclass
     values ("George", "M", 17, 72, 169,"foo");
/* add an index */
  create index names on
     work.myclass(name, age);
quit;

/* write out descriptor portions to data sets */
proc contents data=myclass out=ds1 out2=ds2;run;
/* sashelp.class doesn't have an index so ds2a will not exist */
proc contents data=sashelp.class out=ds1a out2=ds2a;run;

/* compare data set structures */
proc compare data=ds1 compare=ds1a;run;
    InformationsquelleAutor cmjohns
  3. 1

    1 - Benutzen Sie PROC CONTENTS, um Ihren Datensatz Beschreibung (dataset-Namen, Variablen-Namen, Variablen-label, Variablentyp....)

    2 - PROC SORT alle Inhalt Ausgabe

    3 - Verwenden Sie ein PROC VERGLEICHEN.

    ich.e

    ***********************************************;
proc content data=table1 out=cont1 noprint;
run;

proc content data=table2 out=cont2 noprint;
run;

proc sort data=cont1; 
  by memname name;
run;

proc sort data=cont2; 
  by memname name;
run;

proc compare listvar
  base=cont1
  compare=cont2;
  id memname name;
run;
******************* END ************;
    InformationsquelleAutor rbrt
Schreibe einen Kommentar