Wie zufällig neu anordnen, Zeilen in eine text-Datei mit einer batch-Datei

Können Sie versuchen, diese batch-Datei zu helfen, Sie zu mischen Ihre maclist.txt. Die Verwendung der batch-code ist

C:\> type list.txt | shuffle.bat > maclist_temp.txt

Nach Erteilung dieses Befehls maclist_temp.txt enthält eine randomisierte Liste der MAC-Adresse.

Hoffe, das hilft.

Diese scheint zu funktionieren. Füttern Sie einen Kommandozeilen-parameter der Datei zu randomisieren.

    @echo off
    setlocal EnableDelayedExpansion

    rem read the number of lines in the file
    rem the find prepends the line number so we catch blank lines
    for /f "delims=" %%n in ('find /c /v "" %1') do set "len=%%n"
    set len=!len:*: =!
    rem echo %1 has %len% lines

    rem Relocate as many lines as there are lines in the file
    for /l %%j in (1 1 !len!) do (
      rem echo starting round %%j

      rem geta random number between 1 and the number of lines in the file
      set /a var=!random! %% !len! + 1
      rem echo relocating line !var!

      rem make sure there is no temp file
      if exist %1.temp del %1.temp

      rem read each line of the file, write any that don't match and then write the one that does
      <%1 (
        for /l %%i in (1 1 !len!) do (

          rem if it is the target line then save it
          if %%i == !var! (
            set /p found=
            rem echo saving !found!
          )

          rem if it is the target line then write it
          if not %%i == !var! (
            set /p other=
            rem echo writing !other!
            echo !other!>> %1.temp
          )
        )
        rem now write the target line at the end
        rem echo appending !found!
        echo !found!>> %1.temp
      )

      rem replace the original with the temp version
      move %1.temp %1>nul
    )

    rem print the result
    type %1

Ich mag foxidrive's Ansatz. Ich möchte dennoch eine Lösung zu bieten, mit den aufgeführten Einschränkungen beseitigt (obwohl cmd-bezogene Einschränkungen, wie Datei-Größen < 2 GB und line-Längen < ~ 8 KiB bleiben).

Den Schlüssel verzögerte Erweiterung, welchen Bedarf ein-und ausgeschaltet werden, um nicht zu verlieren explamation markiert. Das löst alle möglichen Probleme mit Sonderzeichen wie ^, &, %, !, (, ), <, >, | und ".

Den Zähler index wurde implementiert, um nicht zu verlieren, eine einzelne Zeile der original-text, - Datei, was passieren könnte, ohne, weil random zurückgeben kann doppelte Werte; mit index angehängt, die resultierende Variablen-Namen $$!random!.!index! sind einzigartig.

Den findstr /N /R "^" - Befehl vor jeder Zeile der ursprünglichen Datei mit einer Zeilennummer gefolgt von einem Doppelpunkt. Also keine Zeile leer zu sein scheint, um die for /F Schleife, die würde ignorieren Sie solche. Die Nummer der Zeile, auch implizit löst das Problem mit führenden Semikolons, die Standard - eol Charakter for /F.

Schließlich alles bis zu und einschließlich dem ersten Doppelpunkt (denken Sie daran der sagte Präfix Hinzugefügt von findstr) entfernt wird, aus jeder Zeile, bevor Sie ausgegeben wird, also nicht mehr der führende gleich-Zeichen haben, werden entlassen.

So, hier ist der code:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

set /A "index=0"
for /f "delims=" %%a in ('findstr /N /R "^" "%~dpn0.lst"') do (
    setlocal EnableDelayedExpansion
    for /F %%b in ("$$!random!.!index!") do (
        endlocal
        set "%%b=%%a"
    )
    set /A "index+=1"
)
> "%~dpn0.new" (
    for /f "delims=" %%a in ('set $$') do (
        set "item=%%a"
        setlocal EnableDelayedExpansion
        echo(!item:*:=!
        endlocal
    )
)

endlocal
exit /B