Wiederholen zufällige Variablen in VBA

Aus der Microsoft-eigenen Mund:

Wiederholen Sequenzen von Zufallszahlen, rufen Sie Rnd mit einem negativen argument unmittelbar vor der Verwendung von Randomize mit einem numerischen argument.

Sehen hier für details.

Den gesamten Abschnitt:

Bemerkungen

Den Rnd - Funktion gibt einen Wert kleiner als 1, aber größer als oder gleich null ist.

Den Wert von Zahl bestimmt, wie Rnd generiert eine zufällige Nummer:

Für jede gegebene ersten Samen, die gleiche Zahlenfolge generiert wird, da jedem nachfolgenden Aufruf der Rnd Funktion die Vorherige Zahl als Startwert für die nächste Zahl in der Sequenz.

Bevor Sie Rnd verwenden Sie die Randomize - Anweisung ohne argument initialisiert den Zufallszahlen-generator mit der ein Ausgangswert basierend auf der system-timer.

Produzieren zufällige Ganzzahlen in einem bestimmten Bereich, verwenden Sie diese Formel:

Int((upperbound - lowerbound + 1) * Rnd + lowerbound)

Hier, upperbound ist die höchste Zahl in der Reihe, und die Untergrenze ist die niedrigste Zahl in der Reihe.

^Hinweis wiederholen Sie die Sequenzen von Zufallszahlen, rufen Sie Rnd mit einem negativen argument unmittelbar vor der Verwendung Randomize mit einem numerischen argument. Verwenden von Randomize mit demselben Wert für Zahl nicht wiederholen Sie den vorherigen Sequenz.

Beispiel, wenn Sie fügen Sie diesen code in Excel, erzeugt es eine unterschiedliche Anzahl jedes mal, wenn Sie es ausführen:

Sub xx()
    ' x = Rnd(-1) '
    Randomize 10
    MsgBox (Rnd)
End Sub

Jedoch, wenn Sie die Auskommentierung der x = Rnd(-1) Zeile generiert die gleichen Zahl bei jedem Lauf.

Beachten Sie, dass Sie zu tun haben zwei Dinge. Rufen Sie Rnd mit einem negativen argument und nennen Randomize mit einem bestimmten argument. Ändern Sie entweder diese Dinge geben Ihnen einen anderen Samen (und daher ist die Reihenfolge).

Edit:

Re Ihr Kommentar:

Durch Wiederholung, ich meine, wenn Sie laufen einer Schleife 10 Zufallszahlen, jedes zufällige Zahl in der Liste eindeutig sein. Darüber hinaus, wenn Sie zu laufen waren diese Sequenz wieder, Sie bekommt die gleichen 10 zufällige zahlen als zuvor. Tut, was ich beschrieben habe, Sinn machen?

Müssen Sie jetzt ein weiteres Stück von Informationen. Was Sie fordern, ist keine zufällige zahlen, sondern eine shuffling-Algorithmus. Ich Verweise Sie auf eine frühere Antwort, die ich gab, wie dies zu tun hier. Alles, was Sie tun müssen, ist, kombinieren Sie die schlurfenden Algorithmus mit der Saatgut-Einstellung oben detailliert beschrieben, und Sie werden Ihr wiederholbare, einzigartige Sequenz.

Und hier ist ein code, der zeigt es in Aktion. Jede Ausführung dieser subroutine wird die Sequenz 4 1 5 6 2 3 7 10 9 8 also ich denke, das ist, was Sie wurden, nachdem ein repetable, "random", einzigartige Sequenz. Wenn du wollte erzeugen zu können, verschiedene Sequenzen (aber immer noch in einer wiederholbaren Art und Weise), müssen Sie nur ändern Sie den Wert für die Randomize.

Option Explicit
Option Base 1

Sub xx()
    Dim x(10) As Integer
    Dim xc As Integer
    Dim xp As Integer
    Dim i As Integer
    Dim s As String

    For i = 1 To 10
        x(i) = i
    Next
    xc = 10

    i = Rnd(-1)
    Randomize 1

    s = "Values:"
    For i = 1 To 10
        xp = Int(Rnd * xc) + 1
        s = s & " " & CStr(x(xp))
        x(xp) = x(xc)
        xc = xc - 1
    Next i

    MsgBox (s)
End Sub

InformationsquelleAutor paxdiablo