Windows-batch-Datei umleiten Ausgabe in logfile mit Datum/Uhrzeit

Ich versuche ausführen einer batch-Datei die ausgeführt wird, eine ausführbare Datei und leitet die Ausgabe in eine log-Datei. Die log-Datei muss das Datum und die Uhrzeit als der name der Datei. Dies ist der Befehl den ich verwende:

"%PROGRAMFILES%\PostgreSQL\9.4\bin\vacuumdb.exe" --username postgres --verbose --analyze --all > E:\Logs\VacuumDB\%date:~10,4%_%date:~4,2%_%date:~7,2%_%time:~0,2%_%time:~3,2%_%time:~6,2%.log 2>&1

Dieser Befehl funktioniert beim einfügen direkt in cmd. Die log-Datei erstellt, wie erwartet '2015_06_25__11_20_46.log'. Jedoch, es funktioniert nicht, wenn eingefügt in eine batch-Datei, und führen Sie dann im cmd. Cmd interpretiert den Befehl wie folgt:

"C:\Program Files\PostgreSQL\9.4\bin\vacuumdb.exe" --username postgres --verbose --analyze --all  8_21_42.log  1>E:\Logs\VacuumDB\2015_06_26_ 2>&1

Beachten Sie, wie der Dateiname wird abgeschnitten, und jetzt ist die Zeit an den Befehl angefügt Argumente, anstatt in den Dateinamen. So offensichtlich schlägt der Befehl fehl.

Dies ist sicherlich etwas sehr einfach, aber ich habe nicht gefunden, einen Weg, um dieses Problem zu beheben. Jede Hilfe wird sehr geschätzt.

Danke!

versuchen Sie, mit > "E:\Logs\VacuumDB\%date:~10,4%_%date:~4,2%_%date:~7,2%_%time:~0,2%_%time:~3,2%_%time:~6,2%.log" 2>&1

InformationsquelleAutor sixtstorm1 | 2015-06-26

2

Dein problem ist, dass die timestring darf keine Leerzeichen enthalten (vor 10 Uhr)
Sie können ersetzen Sie es mit einer null, aber ich empfehle einen Lösung unabhängig von der locale-Einstellungen:
```
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /format:list') do set datetime=%%I
```
Wird es geben, Sie (unabhängig von den locale-Einstellungen!):
```
  20130802203023.304000+120 
( YYYYMMDDhhmmss.<fraction>+/-<timedifference to UTC>  )
```
von hier aus ist es einfach zu formatieren und Ihren Bedürfnissen. Zum Beispiel:
```
set datetime=%datetime:~0,8%-%datetime:~8,6%
20130802-203023
```
Danke, das ist es, was ich gesucht habe!

InformationsquelleAutor Stephan
1

Vielleicht die einfachste Lösung für Sie sein diese eine:
```
set "dat=%date: =0%"
set "tim=%time: =0%"
"%PROGRAMFILES%\PostgreSQL\9.4\bin\vacuumdb.exe" --username postgres --verbose --analyze --all > E:\Logs\VacuumDB\%dat:~10,4%_%dat:~4,2%_%dat:~7,2%_%tim:~0,2%_%tim:~3,2%_%tim:~6,2%.log 2>&1
```
Danke es funktioniert, aber da das Datum/Zeit-format ist nicht dasselbe über alle lokalen Einstellungen, die Mitte der string-Funktion nicht immer extrahieren Sie die richtigen Zeichen. Stephan ' s Lösung löst dieses problem.
Gut, Sie hat nicht angegeben, dass Sie hatten die lokalen Probleme. Nach deinem Beispiel-code, Sie sagte: "Die log-Datei erstellt, wie erwartet '2015_06_25__11_20_46.log'"... :/
Ja, ich weiß, aber ich habe versucht, Ihr Beispiel und es gibt das falsche format auf mein Ende (weil mein Gebietsschema fr-CA), und dass zeigt die locale-problem. Da kann ich nur wählen Sie eine anwser ich wählte die eine, die behoben die locale-problem... Sorry, aber ich habe Sie sowieso...
Ich denke, es ist ein Durcheinander hier. Ich kopieren-einfügen den code und fügte gerade die Ersetzung von Leerzeichen durch Nullen, so dass alle substring-Positionen sind genau das gleiche, die Sie geschrieben, bevor "Die log-Datei erstellt, wie erwartet". Aber in deinem vorherigen Kommentar sagte Sie, dass die gleiche Teilstrings "Ausgänge das falsche format auf mein Ende (weil mein Gebietsschema fr-CA)"??? I don ' T care rep-Punkte, aber klar, dieses detail ist wichtig für mich, weil Englisch nicht meine primäre Sprache. Ich möchte, dass Sie beachten, wenn ich missverstanden einem gewissen Punkt, bitte; sonst kann ich nur erwarten, dass Sie sagen: "Mein Fehler, entschuldigen Sie mich..." :/
Ich klebte Ihre Lösung auf einem anderen computer, der ein anderes Gebietsschema als die, die ich verwendet, um zu erhöhen meine ursprüngliche problem, das ist, was passiert ist und warum es die Ausgabe eines falschen format. Das andere Mitglied tatsächlich vorausgesehen hat ein problem, das ich eigentlich gar nicht erhöhen, und dachte über etwas, das könnte irgendwann entpuppen zu sein ein problem (und ich fand mich, es ist). Also ja, deine Lösung hat das problem lösen, das ich ursprünglich gebucht, es besteht kein Zweifel, dass. Niemand kann die Schuld auf dieses. Danke für deine Antwort und die Zeit nehmen, um zu versuchen und helfen Sie mir...

InformationsquelleAutor Aacini

Versuchen, wie dieser Weg :

@echo off
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
echo hour=%hour%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
echo min=%min%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
echo secs=%secs%

set year=%date:~-4%
echo year=%year%
set month=%date:~3,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
echo month=%month%
set day=%date:~0,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
echo day=%day%
Set MaDate=%day%/%month%/%year%
Set MyTime=%hour%:%min%:%secs%
echo %MaDate%
echo %MyTime%
set DateTimeFile=%year%_%month%_%day%_%hour%_%min%_%secs%.log
echo DateTimeFile=%DateTimeFile%
pause

Oder ich habe eine andere Lösung von foxidrive :

::From foxidrive
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set datestamp=%dt:~0,8%
set timestamp=%dt:~8,6%
set YYYY=%dt:~0,4%
set MM=%dt:~4,2%
set DD=%dt:~6,2%
set HH=%dt:~8,2%
set Min=%dt:~10,2%
set Sec=%dt:~12,2%
set stamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%
echo stamp: "%stamp%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
pause

InformationsquelleAutor Hackoo

1

Hier ist ein Inline-version ohne Verwendung von SET-Befehl
```
C:\test.bat > C:\log\test_%date:~10%%date:~4,2%%date:~7,2%-%time:~0,2%%time:~3,2%%time:~6,2%.log 2>&1
```
Diesem Beispiel wird die Ausgabe von C:\test.bat und schreiben ein Protokoll namens test_YYYYMMDD-HHMMSS.melden Sie der C:\log Verzeichnis

Ausgabedatei Beispiel: c:\log\test_20181008-1121.log

InformationsquelleAutor Stevie G

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.