Windows Batch prüfen ob variable beginnt mit, endet mit, enthält eine bestimmte Zeichenfolge

Ich versuche zu überprüfen, ob eine variable in einer batch-Datei beginnt mit " enthält BETA irgendwo und endet mit ").

Ist es möglich?
Und wenn ja, kann mir jemand helfen mit, dass?

InformationsquelleAutor BrainStone | 2013-03-29

4
```
@ECHO OFF
SETLOCAL
SET var=abc&CALL :check
SET var="abc"&CALL :llcheck
SET var="")&CALL :check
SET var=")"&CALL :llcheck
SET var=abc")"&CALL :llcheck
SET var=xyzbetazyx&CALL :check
SET var="xyzbetazyx"&CALL :llcheck
SET var=xyzbetazyx")"&CALL :llcheck
SET var=xyzbetazyx")"&CALL :check
SET var="xyzbetazyx")&CALL :check
GOTO :eof
:: Lop last, then check
:llcheck
SET var=%var:~0,-1%
:check
SET result=N
SET var2=%var%
SET varvar=%var%

>test1.txt ECHO %var:~0,1%%var:~-2%
>test2.txt ECHO "")
FC test1.txt test2.txt >nul
IF ERRORLEVEL 1 GOTO done
SET var|FINDSTR /b "var="|FINDSTR /i "beta" >nul
IF ERRORLEVEL 1 GOTO done
SET result=Y
:done
ECHO %var% starts " has BETA and ends ") : %result% 
GOTO :eof
```
Wo ein Wille ist...

Setzen von Variablen mit unsymmetrischen " kann schwierig sein. Ich habe gerade es, ausgewogene und lopped off des letzten Zeichens (:llcheck Eintrag : lop letzten und überprüfen.

Essentiall, ich habe kopiert die variable in var2 und varvar oder demo, was passiert, sollten diese variablenames eingestellt werden.

Zwei Dateien erzeugt. TEST1.TXT enthält, die ersten und letzten 2 Zeichen von var und TEST2.TXT einfach "")

Vergleichen Sie die zwei - wenn Sie nicht identisch, dann wird die variable NICHT starten " und Ende ") Sonst gut - könnte einfach geschrieben var aus einer Datei und verwendet findstr zu finden beta, aber ich beschloss, senden Sie die Ausgabe SET var was sollte der Inhalt ALL des var* Variablen in der form
```
var=abc
var2=abc
varvar=abc
```
in findstr, finden startet (/b) var= und herauszufinden, ob , DASS enthält den string beta Die /i wählt der groß-und Kleinschreibung. Wenn Sie möchten, speziell BETA im OBEREN FALL, ändern Sie einfach beta zu BETA und entfernen Sie die /i.

result eingestellt ist Y oder N
- Das funktionierte perfekt in Ordnung!
- Dies funktioniert sicherlich, aber es gibt eine viel einfachere Lösung, mit einem einzigen FINDSTR regex-Suche. Siehe meine Antwort
InformationsquelleAutor Magoo
11

Angenommen die variable enthält keine Zeilenvorschübe oder Wagenrückläufe, dann ist alles, was benötigt wird ist ein einzelner Befehl "FINDSTR". Es hat begrenzte Unterstützung für reguläre Ausdrücke, das ist mehr als genug für dieses problem.
```
@echo off
setlocal
set test1=abc
set test2="abc"
set test3="")
set test4=")"
set test5=abc")"
set test6=xyzBETAzyx
set test7="xyz BETA zyx"
set test8=xyzBETAzyx")"
set test9=xyzBETAzyx")"
set test10="xyzbetazyx")
set test11="xyzBETAzyx")

for /l %%N in (1 1 11) do call :test test%%N
exit /b

:test  variableName
setlocal enableDelayedExpansion
echo !%1!|>nul findstr /rx \".*BETA.*\") && set "result=PASS" || set "result=FAIL"
echo %1 = !result!: !%1!
exit /b
```
Nur TEST11 geht.

Den /R option erzwingt, dass der search-string, der als ein regulärer Ausdruck behandelt.

Den /X option bedeutet, es muss eine genaue übereinstimmung sein - muss die gesamte Zeichenfolge in der Suchzeichenfolge entsprechen.

.* ist die regex wildcard Ausdruck entsprechen, wird eine beliebige Zeichenfolge.

Ich umleiten FINDSTR Ausgabe nach NUL, weil wir nicht brauchen, um die Linie zu sehen. Wir wollen einfach nur den return-code

FINDSTR erfordert Literale in doppelten Anführungszeichen maskiert werden als \"

Verwendung verzögert die expansion, so dass Sie können sicher echo einen beliebigen Wert innerhalb der variable.

Benutze ich && bedingt Maßnahmen ergreifen, wenn FINDSTR erfolgreich war, und || bedingt Maßnahmen ergreifen, wenn FINDSTR gescheitert.

Meine :TEST routine trägt den Namen der Variablen als einziges argument.

Beachten Sie, dass in einigen Situationen die batch-parser erfordert, dass Sie auch die Flucht der doppelten Anführungszeichen als ^", also ein völlig entgangen Zitat Aussehen wird \^". Aber, dass die Komplikationsrate ist nicht notwendig in Ihrem Fall. Der FINDSTR-escape-Regeln sind eigentlich ein bisschen wackelig. Sehen Was sind die undokumentierten Funktionen und die Einschränkungen der Windows-Befehl "FINDSTR"? für mehr info.

Mein test-code wird zwischen groß-und Kleinschreibung suchen. So beta nicht mit BETA. Wenn Sie möchten, eine groß-und Kleinschreibung suchen, dann fügen Sie einfach die /I option.

EDIT: 2015-07-22

Weitere option, wenn, und nur wenn Sie wollen, um groß - /Kleinschreibung ignorieren, ist die Verwendung einer Kombination der Variablen expansion suchen/ersetzen-und ausbau substring-Operationen. Beide test10 und test11 pass unten.
```
@echo off
setlocal
set test1=abc
set test2="abc"
set test3="")
set test4=")"
set test5=abc")"
set test6=xyzBETAzyx
set test7="xyz BETA zyx"
set test8=xyzBETAzyx")"
set test9=xyzBETAzyx")"
set test10="xyzbetazyx")
set test11="xyzBETAzyx")

for /l %%N in (1 1 11) do call :test test%%N
exit /b

:test  variableName
setlocal enableDelayedExpansion
set "result=FAIL"
if "!%1:beta=!" neq "!%1!" if "!%1:~0,1!" equ ^""" if "!%1:~-2!" equ ^"")" set "result=PASS"
echo %1 = !result!: !%1!
exit /b
```
Die erste IF prüft beta überall (groß-und Kleinschreibung). Die zweite IF-Prüfungen für " am Anfang, und das Letzte, WENN Prüfungen für ") am Ende. Die einzige heikle Sache ist, herauszufinden, wie zu entkommen, der Vergleichs-string, wenn es eine ungerade Anzahl von Anführungszeichen.
- Entschuldigen Sie, Dave. Ist nicht ein Fehler, die richtigen Klammern zu findstr /rx \".*BETA.*\") ? Ja, es ist eine alte Antwort, aber ich sehe nur einen link zu diesem Thema jetzt...
- Ich sehe nicht ein, warum Sie vermuten, es könnte ein Fehler vorliegt. Die Zeichenfolge erscheint nie in einen code-block, also die nicht börsennotierte, ohne Umschreibung die Rechte Klammer nie ein problem verursacht. Ich habe auch getestet, den code, und es funktioniert.
- Ok. Vielleicht ist es nicht zu einem - Fehler, aber ich sehe keinen Grund, um ein Recht Klammer an diesem Ort, ausgenommen ein Tippfehler...
- Es definitiv ist kein Tippfehler - die richtige Klammer ist da, weil der OP will nach einer Zeichenfolge suchen, endet mit einer rechten Klammer. Die Anführungszeichen sind "escaped" (von " FINDSTR point of view), also Sie sind Bestandteil der zu Suchenden Zeichenkette.
- Ja, du hast Recht! Ich war verwirrt durch das escaped quotes! mein Fehler... 🙁
InformationsquelleAutor dbenham
2
```
@echo off
setlocal EnableDelayedExpansion
set quote="
set variable="This must be true: BETA")
echo Variable=!variable!
if "!variable:~0,1!" equ "!quote!" (
   rem Start with "
   if "!variable:BETA=!" neq "!variable!" (
      rem Contains BETA
      if "!variable:~-2!" equ "!quote!^)" (
         echo TRUE: it start with " contains BETA and ends with "^)
      ) else (
         echo FALSE, it does not ends with "^)
      )
   ) else (
      echo FALSE, it does not contain BETA
   )
) else (
   echo FALSE, it does not start with "
)
```
Ausgabe:
```
Variable="This must be true: BETA")
TRUE: it start with " contains BETA and ends with ")
```
- Den Umgang mit unausgeglichenen zitiert (und mit anderen, speziellen Batch-Zeichen, in der Tat), ist die Verwendung Verzögerte Erweiterung: auf diese Weise die Anführungszeichen und Sonderzeichen, die nicht in der Befehlszeile analysiert wird.
- Denken Sie daran, zu entkommen, mit ^ alle Rechte Klammern, der nicht schließenden Klammern der Befehl blockiert.
- Einen einfachen Weg, um zu überprüfen, ob eine variable enthalten, die eine gegebene Zeichenkette zu beseitigen versuchen den string von variable-Wert: wenn das Ergebnis anders ist, als der ursprüngliche Wert, dann die variable, die die Zeichenfolge enthalten.
Antonio
- Thabks für deine Antwort. Es ist auch Super!
InformationsquelleAutor Aacini

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.