XSLT-Entfernen von Duplikaten

Ich habe eine xml-Datenquelle, die wie folgt aussieht:

<dsQueryResponse>
  <Department>
    <Rows>
      <Row dept="HR" state="NY" region="East"/>
      <Row dept="HR" state="NJ" region="East"/>
      <Row dept="SD" state="NY" region="East"/>
      <Row dept="MM" state="NY" region="East"/>
      <Row dept="SD" state="NJ" region="East"/>
      <Row dept="SD" state="CO" region="West"/>
      <Row dept="MM" state="CO" region="West"/>
    </Rows>
  </Department>
</dsQueryResponse>

Mein XSLT sieht wie folgt aus:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output method="html" indent="no"/>
  <xsl:decimal-format NaN=""/>
  <xsl:param name="DeptQS">East</xsl:param>
  <xsl:variable name="deptRows" select="/dsQueryResponse/Department/Rows/Row[@region = $DeptQS]"/>

  <xsl:template match="/">
    <xsl:if test="count($deptRows) &gt; 0">
      <xsl:call-template name="deptList"/>
    </xsl:if>
  </xsl:template>

  <xsl:template name="deptList">
    <xsl:for-each select="$deptRows">
      <!-- process unique depts--> 
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

Ich will alle Abteilungen in der region geschrieben. Den code habe ich nun Schreibe doppelten Abteilungen. Aber wie kann ich das schreiben aus der Abteilung für die region nur einmal?

Dank!

Bitte geben Sie das tatsächliche und das erwartete Ergebnis. Ansonsten ist es schwer zu verstehen, was Sie genau brauchen.

InformationsquelleAutor user686924 | 2011-04-01

xml xslt

2

Für XSLT 1.0, können Sie die "Muenchian Methode".

Erstellen Sie eine Taste, um den index der Row Elemente durch eine Kombination von @region und @dept Werte.

Ist, dann hätte man das erste auftreten der region/department Kombination (das hat die gesuchte region ($DeptQS)) und output der Abteilung (dept).

Hier ist ein Beispiel-stylesheet der Ausgabe <test> Elemente zu zeigen, die Kontext:
```
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" method="xml" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="kDept" match="Department/Rows/Row" use="concat(@region,'|',@dept)"/>
  <xsl:param name="DeptQS">East</xsl:param>

  <xsl:template match="/*">
    <xsl:for-each select="Department/Rows/Row[count(.|key('kDept',
      concat($DeptQS,'|',@dept))[1])=1]">
      <test>Current dept: <xsl:value-of select="@dept"/></test>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>
```
Hier ist die Ausgabe mit Ihrer XML-Eingabe:
```
<test>Current dept: HR</test>
<test>Current dept: SD</test>
<test>Current dept: MM</test>
```
- Variable/parameter-Referenzen sind nicht gültig in XSLT 1.0-Muster wie xsl:key/@match
- Sie können nicht verwenden var/param-Verweis in der XSLT-1.0-Muster, aber Sie können in XSLT 2.0. Das ändert das ganze problem, da in XSLT 1.0 müssen Sie die push-Stil. Ihre Antwort verwenden Sie pull-Stil und param Referenz-mustern. Dies ist nicht ein XSLT 1.0-Lösung, wie Sie Ihre erste Satz scheint zu behaupten.
InformationsquelleAutor Daniel Haley
4

Ihnen angezeigt, noch nicht das gewünschte Ergebnis. Aber in XSLT 2.0 konnten Sie so etwas tun:
```
<xsl:template match="Rows">
  <xsl:for-each-group select="Row" group-by="@region">
    <region name="{current-grouping-key()}">
      <xsl:for-each-group select="current-group()" group-by="@dept">
        <dept name="{current-grouping-key()}">
          <xsl:for-each select="current-group()">
            <state name="{@state}"/>
          </xsl:for-each>
        </dept>
      </xsl:for-each-group>
    </region>
  </xsl:for-each>
</xsl:template>
```
- Die zweite Hälfte der code scheint syntaktisch illegal?
- Vielen Dank für die Bearbeitung, Simon. Ich benutze </ zu Ende-tags in einem XML-editor mit auto-Vervollständigung, so Neige ich dazu, verwenden Sie es als Abkürzung beim schreiben von "sketchy" XML in notes wie diese; es ist ein signal an die Leser, die Sie anwenden sollten einige Gehirn-Zyklen, anstatt einfach kopieren Sie den code und erwarten, dass es funktioniert out of the box.
InformationsquelleAutor Michael Kay

wie kann ich schreiben Sie die Abteilung für
die region erst einmal?

Diesem stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="pRegion" select="'East'"/>
    <xsl:key name="kRowByDept-Region" match="Row"
             use="concat(@dept,'++',@region)"/>
    <xsl:template match="Rows">
        <xsl:apply-templates select="Row[generate-id()
                                          = generate-id(
                                               key('kRowByDept-Region',
                                                   concat(@dept,'++',$pRegion)
                                               )[1]
                                            )
                                     ]"/>
    </xsl:template>
    <xsl:template match="Row">
        <xsl:value-of select="concat(@dept,'&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>

Ausgabe:

HR
SD
MM

InformationsquelleAutor

Das folgende stylesheet zeigt einen Allgemeinen Ansatz für die Gruppierung auf mehreren Ebenen:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="byRegion" match="Row" use="@region" />
    <xsl:key name="byRegionState" 
             match="Row" use="concat(@region, '|', @state)" />
    <xsl:key name="byRegionStateDept" 
             match="Row" use="concat(@region, '|', @state, '|', @dept)" />
    <xsl:template 
         match="Row[generate-id() = generate-id(key('byRegion', @region)[1])]">
        <region name="{@region}">
            <xsl:apply-templates
                select="key('byRegion', @region)
                         [generate-id() =
                          generate-id(key('byRegionState',
                                      concat(@region, '|', @state))[1])]"
                mode="states" />
        </region>
    </xsl:template>
    <xsl:template match="Row" mode="states">
        <state name="{@state}">
            <xsl:apply-templates
                select="key('byRegionState', concat(@region, '|', @state))
                         [generate-id() =
                          generate-id(key('byRegionStateDept',
                                concat(@region, '|', @state, '|', @dept))[1])]"
                mode="dept" />
        </state>
    </xsl:template>
    <xsl:template match="Row" mode="dept">
        <dept><xsl:value-of select="@dept" /></dept>
    </xsl:template>
</xsl:stylesheet>

Es produziert die folgende Ausgabe auf Ihre Eingabe:

<region name="East">
    <state name="NY">
        <dept>HR</dept>
        <dept>SD</dept>
        <dept>MM</dept>
    </state>
    <state name="NJ">
        <dept>HR</dept>
        <dept>SD</dept>
    </state>
</region>
<region name="West">
    <state name="CO">
        <dept>SD</dept>
        <dept>MM</dept>
    </state>
</region>

InformationsquelleAutor Wayne Burkett

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.