XSLT Ignorieren Sie doppelte Elemente zu

Ich habe gerade angefangen zu lernen, XSLT und habe Probleme ignorieren duplizierten Elementen.

Habe ich die Suche durch Stack-Overflow und habe gesehen, dass Leute Fragen ähnliche Fragen. Ich habe versucht, ein kleines Beispiel, um zu sehen, wo ich gelaufen war, auf meine Datei, und war in der Lage, Sie zu ignorieren duplizierten Elementen. Aber das problem bei mir scheint zu entstehen, wenn ich mehr als einen Typ eines Elements.

Beispiel:

File1.xml

<?xml-stylesheet type="text/xsl" href="merge2.xsl"?>

<Main>
    <Records>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
</Main>

merge2.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/Transform">
<xsl:output method="html"/>
<xsl:template match="/">
    <table border="1">
        <tr>
            <th>Type</th>
            <th>Count</th>
        </tr>
        <xsl:for-each select="Main/Records/Record">
            <xsl:if test ="not(preceding-sibling::Record(Description/text() = current()/Description/text()])">
                <tr>
                    <td><xsl:value-of select="Description"/></td>
                    <td><xsl:value-of select="count(//Record[Description/text()=current()/Description/text()])"/></td>
                </tr>
            </xsl:if>
        </xsl:for-each>
    </table>
</xsl:template>
</xsl:stylesheet>

Dies funktioniert gut und gibt mir die gewünschten Ergebnisse.

Type    Count
 A        2
 B        1
 C        1

Jedoch wenn ich eine weitere hinzufügen-Datensätze-element scheint es für die beiden eine nach der anderen, z.B.

<?xml-stylesheet type="text/xsl" href="merge2.xsl"?>

<Main>
    <Records>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
    <Records>
        <Record>
            <Description>B</Description>
        </Record>
        <Record>
            <Description>A</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
        <Record>
            <Description>C</Description>
        </Record>
    </Records>
</Main>

Diese produzieren würde, die folgenden.

Type        Count
 A            3
 B            2
 C            3
 B            2
 A            3
 C            3

Wo es scheint, um Prozess der ersten Instanz von Aufzeichnungen, die dann auf den nächsten Zug. Gibt es eine Möglichkeit, es so zu machen, dass es Duplikate entfernen auf die beiden?

Ich habe versucht, die änderung der for-each Durchlaufen jede Instanz von Aufzeichnungen, und haben versucht, erstellen Sie eine separate Vorlage für Sie, aber ich immer noch, scheint etwas zu fehlen, wie ich es noch nicht geschafft haben es zum laufen zu bringen.

Vielen Dank für jede Hilfe.

InformationsquelleAutor user2795778 | 2013-09-19

Versuchen, anstelle preceding-sibling mit nur preceding in Ihrem xsl:if statement.

Ihnen hatte die richtige Idee, um Ihr Handwerk test, so dass Sie Strahlen nur einen tr einmal pro gestoßen Description Wert. Allerdings preceding-sibling hält die überprüfung zurück durch die unmittelbar untergeordneten Elemente des übergeordneten Elements; preceding weiterhin die überprüfung früher in diesem Dokument, ist das, was Sie wollen zu vermeiden, die Vervielfältigung über Records.

Zur info, es gibt auch ein Tippfehler, wo Record( sollte Record[. Hier ist eine komplette, operative Umsetzung, einschließlich dieser änderungen:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <table border="1">
      <tr>
        <th>Type</th>
        <th>Count</th>
      </tr>
      <xsl:for-each select="Main/Records/Record">
        <xsl:if test ="not(preceding::Record[Description/text() = current()/Description/text()])">
          <tr>
            <td><xsl:value-of select="Description"/></td>
            <td><xsl:value-of select="count(//Record[Description/text()=current()/Description/text()])"/></td>
          </tr>
        </xsl:if>
      </xsl:for-each>
    </table>
  </xsl:template>
</xsl:stylesheet>

Hi danke für die Antwort. Ihr ganz rechts kann nicht glauben, ich vermisste diese. Vielen Dank.

InformationsquelleAutor kjhughes

Obwohl @kjhughes war in der Lage, die Frage zu beantworten, die Sie haben, für einen effizienteren Ansatz, den Sie verwenden möchten, werden die Muenchain Methode.

Zu tun, definieren Sie eine Taste, um Gruppe auf

<xsl:key name="Record-by-Description" match="Record" use="Description"/>

Dann Gruppe diejenigen Elemente, die mit diesem Schlüssel

<xsl:apply-templates select="Record[generate-id() = generate-id(key('Record-by-Description', Description)[1])]" mode="group"/>

Und verwenden Sie dann die Taste, um zählen nur diejenigen, die bestimmte Elemente

<xsl:value-of select="count(key('Record-by-Description', Description))"/>

Dieser Prozess sehr viel effizienter und erfordert keine Navigation in der gesamten Struktur zu jeder Zeit.

Insgesamt also, wenn man diese XML -

<Main>
  <Records>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>B</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
  </Records>
  <Records>
    <Record>
      <Description>B</Description>
    </Record>
    <Record>
      <Description>A</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
    <Record>
      <Description>C</Description>
    </Record>
  </Records>
</Main>

Anwenden von XSLT ist es

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:output method="xml" indent="yes" />
  <xsl:key name="Record-by-Description" match="Record" use="Description"/>

  <xsl:template match="@* | node()">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:template>

  <xsl:template match="Main">
    <table>
      <tr>
        <th>Type</th>
        <th>Count</th>
      </tr>
      <xsl:apply-templates select="Records"/>
    </table>
  </xsl:template>

  <xsl:template match="Records">
    <xsl:apply-templates select="Record[generate-id() = generate-id(key('Record-by-Description', Description)[1])]" mode="group"/>
  </xsl:template>

  <xsl:template match="Record" mode="group">
    <tr>
      <td>
        <xsl:value-of select="Description"/>
      </td>
      <td>
        <xsl:value-of select="count(key('Record-by-Description', Description))"/>
      </td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

Es erzeugt diese Ausgabe

<table>
  <tr>
    <th>Type</th>
    <th>Count</th>
  </tr>
  <tr>
    <td>A</td>
    <td>3</td>
  </tr>
  <tr>
    <td>B</td>
    <td>2</td>
  </tr>
  <tr>
    <td>C</td>
    <td>3</td>
  </tr>
</table>

Hi danke für die Antwort. Tolle Erklärung, die Muenchain Methode ist etwas, das ich sah Menschen, die zu erwähnen bei der Suche nach einer Antwort, aber nie vollständig Begriffen es, also danke für die Hilfe.
Ich habe versucht, Ihr Beispiel und es funktioniert Super. Wäre es möglich, verwenden Sie diese Methode für mehrere xml-Dateien, wenn ich eine index.xml enthalten eine Liste von den Dateien? Vielen Dank.
Ich glaube, es wird so lange wie Sie haben einen Schlüssel, die funktionieren würde. Ich denke, es könnte erfordern die Kombination mit den anderen Dateien, in die man jedoch zuerst und dann den Schlüssel zu erstellen, die auf den Ergebnis-Baum-fragment, das alle XML-zusammengestellt. Ich wäre eine wirklich gute Frage zu Fragen, wenn Sie haben ein Beispiel.
Ich stellte die Frage auf StackOverflow und habe einige gute Antworten. Bitte siehe link wenn Sie neugierig sind, wie diese gelöst wurde. Nochmals vielen Dank für all die Hilfe.

InformationsquelleAutor Matthew Green

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.