Zoom canvas-Bereich, in Delphi

Ich etwas, das aussieht wie die Farbe in Delphi. Ich fand, wie man zoom-Funktion:

procedure SetCanvasZoomFactor(Canvas: TCanvas; AZoomFactor: Integer);
var
  i: Integer;
begin
  if AZoomFactor = 100 then
    SetMapMode(Canvas.Handle, MM_TEXT)
  else
  begin
    SetMapMode(Canvas.Handle, MM_ISOTROPIC);
    SetWindowExtEx(Canvas.Handle, AZoomFactor, AZoomFactor, nil);
    SetViewportExtEx(Canvas.Handle, 100, 100, nil);
  end;
end;



procedure TMainForm.btnZoomPlusClick(Sender: TObject);
var
  bitmap: TBitmap;
begin 

  bitmap := TBitmap.Create;
  if(zoomVal < 1000) then
      zoomVal:=zoomVal+zoomConst; //zoomVal = 100 by default; zoomConst = 150;
  try
    bitmap.Assign(MainForm.imgMain.Picture.Bitmap);
    SetCanvasZoomFactor(bitmap.Canvas, zoomVal);
    Canvas.Draw(MainForm.imgMain.Left,MainForm.imgMain.Top, bitmap); 
  finally
    bitmap.Free
  end;
end;

Aber, das problem ist, es vergrößert nur die oberen linken Bereich des Bildes.

Beispiel
vor zoom:
Zoom canvas-Bereich, in Delphi
nach dem Zoomen:

Ich möchte in der Lage sein, sich zu bewegen durch alle Bild-Bereich, selbst nach dem Zoomen. Wie kann ich das machen?

Hier ist ein animated zoom selector und hier ist, wie zu make animated panning.
Heilige delphi, es ist nicht so einfach, wie ich dachte! Nun, wenn es keinen anderen Weg, um solche zoom, verwende ich für eine solche Lösung
Es muss nicht so Komplex sein. Es kommen glatte Animationen gibt. Es sieht aus und fühlt sich schön an Kontrolle, aber wenn Sie nicht brauchen, Animationen, warten, für eine einfachere Lösung 😉
nun ja, eigentlich brauche ich nicht flüssige animation oder so ähnlich. Zumindest jetzt. Aber danke für die links!

InformationsquelleAutor DanilGholtsman | 2013-10-19

Können Sie SetWorldTransform für jeden DC.
Ein Beispiel für die Implementierung könnte wie folgt Aussehen:

Procedure SetCanvasZoomAndRotation(ACanvas: TCanvas; Zoom: Double;
  Angle: Double; CenterpointX, CenterpointY: Double);
var
  form: tagXFORM;
  rAngle: Double;
begin
  rAngle := DegToRad(Angle);
  SetGraphicsMode(ACanvas.Handle, GM_ADVANCED);
  SetMapMode(ACanvas.Handle, MM_ANISOTROPIC);
  form.eM11 := Zoom * Cos(rAngle);
  form.eM12 := Zoom * Sin(rAngle);
  form.eM21 := Zoom * (-Sin(rAngle));
  form.eM22 := Zoom * Cos(rAngle);
  form.eDx := CenterpointX;
  form.eDy := CenterpointY;
  SetWorldTransform(ACanvas.Handle, form);
end;

Procedure ResetCanvas(ACanvas: TCanvas);
begin
  SetCanvasZoomAndRotation(ACanvas, 1, 0, 0, 0);
end;

Könnten Sie definieren, Zoom, X-Y-Offest und rotation für die gewünschte Leinwand vor dem malen.
In Ihrem Fall wählen Sie einen Zoom, Farbe auf die Leinwand und auf scrollen/verringern Sie den Wert für X und/oder Y und rufen Sie die Prozedur mit den gleichen zoom wieder und malen Sie Ihre Grafik.

BEARBEITEN
Um zu zeigen, wie um die Prozedur zu verwenden. Dieser code

procedure TForm2.PaintBox1Paint(Sender: TObject);
var
  i, w, h: Integer;
  C: TCanvas;
begin
  C := TPaintBox(Sender).Canvas;
  w := TPaintBox(Sender).Width;
  h := TPaintBox(Sender).Height;
  for i := 0 to 9 do
  begin
    SetCanvasZoomAndRotation(C, 1 + i / 5, i * 36, w div 2, h div 2);
    C.Draw(0, 0, Image1.Picture.Graphic);
    C.Brush.Style := bsClear;
    C.TextOut(50, 0, Format('Hi this is an example %d', [i]));
  end;
end;

wird verwendet, um anzuzeigen, Folgendes Ergebnis:
Zoom canvas-Bereich, in Delphi

Als Antwort auf Ihren Kommentar, wie es mit trackbars, Sie umzusetzen etwas wie

procedure TForm2.FormCreate(Sender: TObject);
begin
  DoubleBuffered := true;
end;

procedure TForm2.PaintBox1Paint(Sender: TObject);
var             // a Paintbox aligned alClient
  C:TCanvas;
begin
  TrackBarHorz.Max := Round(Image1.Picture.Graphic.Width * SpinEditZoomInPercent.Value / 100 - TPaintBox(Sender).Width);
  TrackBarVert.Max := Round(Image1.Picture.Graphic.Height * SpinEditZoomInPercent.Value / 100 - TPaintBox(Sender).Height);
  C := TPaintBox(Sender).Canvas;
  SetCanvasZoomAndRotation(c , SpinEditZoomInPercent.Value / 100, 0
                           , - TrackBarHorz.Position
                           , - TrackBarVert.Position);
  C.Draw(0,0,Image1.Picture.Graphic);
end;

procedure TForm2.SpinEditZoomInPercentChange(Sender: TObject);
begin
   PaintBox1.Invalidate;
end;

procedure TForm2.BothTrackbarsEvent(Sender: TObject);
begin
   PaintBox1.Invalidate;
end;

oh, vielen Dank! Ich habe versucht, es zu benutzen, aber es funktioniert nicht so (ich habe trackbar, weil es mit einfach zu überprüfen was verpasst) hier ist der code pastebin.com/X4umbmTX Was hab ich falsch gemacht?
Oh, vielen Dank! Aber ist es möglich, um es mit TImage, nicht TPaintBox?
Sie können verwenden Sie es mit jedem Leinwand (auch Drucker), wenn Sie TImage werden Sie sich die enthaltene Bitmap (z.B. Image1.Bild.Bitmap := nil) vor dem Lackieren wieder, wenn die neue Grafik gezeichnet wird, die nicht decken das gesamte Bild, sonst finden Sie vielleicht eine kleine bitmap zeichnen, die über einen vor ziehen "größer" ein. Spielen Sie einfach um, Sie werden finden die beste Möglichkeit für Ihre Ansprüche, je nach Zweck.

InformationsquelleAutor bummi

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.