Automatisierte Methode zum exportieren von Enterprise Architect Diagramme?

Problem: viele unserer design-und Architektur-Dokumentation wurden erstellt und gepflegt, in Enterprise Architect - für besser oder schlechter, das ist, wie es ist. Diese Dokumente werden gespeichert in unserem subversion-repository - das funktioniert ziemlich gut für die Leute, die erstellen und aktualisieren Sie Sie -, da haben wir Lizenzen für EA -, aber viele von den Entwicklern (interne und externe), die auf unsere codebase und müssen, um die Verwendung der Abbildungen, aber nicht alle haben die EA-Lizenzen.

Schlechte Lösung: Wir könnten manuell exportieren der EA-Dokumente auf ein tragbares format und überprüfen Sie die, aber es gibt bestimmt mal, wenn das tragbare format-version veraltet ist mit dem EA-Dokument, da es stützt sich auf die Menschen zu nehmen, die Schritte zum manuellen konvertieren.

Bessere Lösung: Wir haben uns für eine Methode zur Automatisierung der Konvertierung. Dies könnte ausgeführt werden, wie ein post-commit-hook oder als Teil unseres continuous-integration-Systems. Dem Teil fehlt ist das Stück, das ermöglicht uns die Automatisierung der Konvertierung. Irgendwelche Ideen?

InformationsquelleAutor Shane C. Mason | 2009-09-17

enterprise-architect

In der Beispiel code, den ich gerade entdeckt, eine Funktion whish wird genau das tun, was Sie wollen. Aber versteckt von der nicht so hilfsbereit Namen ProjectInterfaceExample:

option explicit

!INC Local Scripts.EAConstants-VBScript

'
' Examples of how to access and use the Project Interface.
' 
' Related APIs
' =================================================================================
' Project Interface API - http://www.sparxsystems.com/uml_tool_guide/sdk_for_enterprise_architect/project_2.html
'

' Global reference to the project interface
dim projectInterface as EA.Project

sub ProjectInterfaceExample()

    ' Show the script output window
    Repository.EnsureOutputVisible "Script"

    Session.Output( "VBScript PROJECT INTERFACE EXAMPLE" )
    Session.Output( "=======================================" )


    set projectInterface = Repository.GetProjectInterface()

    ' Iterate through all model nodes
    dim currentModel as EA.Package
    for each currentModel in Repository.Models

        ' Iterate through all child packages and save out their diagrams
        dim childPackage as EA.Package
        for each childPackage in currentModel.Packages
            DumpDiagrams childPackage
        next
    next

    Session.Output( "Done!" )

end sub

'
' Recursively saves all diagrams under the provided package and its children
'
sub DumpDiagrams ( thePackage )

    ' Cast thePackage to EA.Package so we get intellisense
    dim currentPackage as EA.Package
    set currentPackage = thePackage

    ' Iterate through all diagrams in the current package
    dim currentDiagram as EA.Diagram
    for each currentDiagram in currentPackage.Diagrams

        ' Open the diagram
        Repository.OpenDiagram( currentDiagram.DiagramID )

        ' Save and close the diagram
        Session.Output( "Saving " & currentDiagram.Name )
        projectInterface.SaveDiagramImageToFile "c:\\temp\\" + currentDiagram.Name + ".emf"
        Repository.CloseDiagram( currentDiagram.DiagramID )
    next

    ' Process child packages
    dim childPackage as EA.Package
    for each childPackage in currentPackage.Packages    
        DumpDiagrams childPackage
    next

end sub

ProjectInterfaceExample

Sie müssen möglicherweise Feinabstimmung es noch ein bisschen (ich.E. nicht schreiben alles in C:\Temp -) aber es ist ein guter Anfang.

InformationsquelleAutor Martin

1

Ich bin nicht vertraut mit diesem Produkt, aber die Website, die Sie verknüpfen, nennt ein Automation-interface. Dies sollte Ihnen ermöglichen, zu Steuern, Enterprise Architect über eine Skriptsprache wie VBScript oder JavaScript. Kann es möglich sein, drucken über diese Schnittstelle werden; wenn dem so ist, können Sie installieren eine PDF-Drucker-Treiber (oder drucken Sie eine Datei mit einem generischen PostScript-Drucker-Treiber und verwenden Sie GhostScript zu konvertieren in das PDF-Format.

InformationsquelleAutor Ken Keenan
1

Wir haben Enterprise Architect und wir haben es gut integriert mit Word. Wir schrieben unsere eigene Wicket - /Jetty-WebApp veröffentlicht, die links zu EA diragrams wie eine HTTP-URL, die wir dann "Insert&Links" in unserer UCR (oder etwas anderes) Dokumente. Die web-app zeigt einem Baum wie Struktur von links, eine für jedes Paket und dann haben wir einfach den link kopieren in das word-Dokument.

Es funktioniert wirklich gut. Können wir machen, wie viele änderungen wir wie in EA und dann in das Word-Dokument gehen Sie einfach STRG+A, um alle auszuwählen und drücken Sie F9 zur Aktualisierung aller links. Leider hatte ich nicht den code so schreiben, kann ich Ihnen nicht genau sagen, wie es ist veröffentlicht von EA. Ich denke, es gibt einige Java-code, der nur abfragt, die EA-server und saugt alles, wenn es erkennt änderungen.

Das ist interessant, ich nehme an, der take-away Punkt ist, dass es mindestens einige Java-API, die wir nutzen können. Aber wir sind nicht mit einem EA-server - nur die stand-alone-app.

InformationsquelleAutor Richard Perfect

VBScript ist wirklich eine einfache und schnelle Möglichkeit. Ich fand heraus, ein kleines script, dass es ermöglicht den export eines Diagramms. Die nur denken, Sie haben zu wissen, ist es die GUID.

Set MyRep = CreateObject("EA.Repository")

If NOT MyRep.OpenFile("D:\Repository.eap") Then
  MsgBox("Error opening file")
  WScript.Quit -1
End If

Set Project = MyRep.GetProjectInterface

My_Diagram_GUID = "{2256B231-99F6-4c78-9AB0-72E24486D578}"

'Vector export emf/wmf
Project.PutDiagramImageToFile My_Diagram_GUID,"D:\Test.emf",0

'Bitmap export png/bmp/...
Project.PutDiagramImageToFile My_Diagram_GUID,"D:\Test.png",1

Schönen start. Aber was würden wir brauchen, ist ein Weg, um exportieren Sie alle Diagramme in einem Rutsch. Es sollte möglich sein, mit Einem VBA-Skript.

InformationsquelleAutor Robert

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.