Buch Liste - erste-Buch-details, von amazon über Excel-VBA-barcode-lookups

Dachte ich, es war einfach googeln, aber entpuppte sich als schwieriger als ich erwartet hatte.

In der Tat, ich war nicht in der Lage zu finden, ein VBA-ISBN-Programm zu erhalten, buchen Sie Daten aus dem web, also beschlossen, das zu machen.

Hier ist ein VBA-makro die Verwendung der Dienste von xisbn.worldcat.org. Beispiele hier.. Die Dienste sind kostenlos und brauchen keine Authentifizierung.

In der Lage sein, um es ausführen, sollten Sie überprüfen unter Extras-> Referenzen (in der VBE-Fenster) die "Microsoft xml 6.0" - Bibliothek.

Dieses makro nimmt die ISBN (10-stellig) aus der aktuellen Zelle und füllt den folgenden beiden Spalten Autor und Titel. Sie sollten in der Lage sein, um eine Schleife durch eine vollständige Spalte leicht.

Der code wurde getestet (naja, ein bisschen), aber es ist keine Fehlerprüfung drin.

 Sub xmlbook()
 Dim xmlDoc As DOMDocument60
 Dim xWords As IXMLDOMNode
 Dim xType As IXMLDOMNode
 Dim xword As IXMLDOMNodeList
 Dim xWordChild As IXMLDOMNode
 Dim oAttributes As IXMLDOMNamedNodeMap
 Dim oTitle As IXMLDOMNode
 Dim oAuthor As IXMLDOMNode
 Set xmlDoc = New DOMDocument60
 Set xWords = New DOMDocument60
 xmlDoc.async = False
 xmlDoc.validateOnParse = False
 r = CStr(ActiveCell.Value)

 xmlDoc.Load ("http://xisbn.worldcat.org/webservices/xid/isbn/" _
              + r + "?method=getMetadata&format=xml&fl=author,title")

 Set xWords = xmlDoc

     For Each xType In xWords.ChildNodes
         Set xword = xType.ChildNodes
         For Each xWordChild In xword
             Set oAttributes = xWordChild.Attributes
             On Error Resume Next
             Set oTitle = oAttributes.getNamedItem("title")
             Set oAuthor = oAttributes.getNamedItem("author")
             On Error GoTo 0
         Next xWordChild
     Next xType
  ActiveCell.Offset(0, 1).Value = oTitle.Text
  ActiveCell.Offset(0, 2).Value = oAuthor.Text
 End Sub

Habe ich nicht über Amazon, weil Ihre neue "einfache" Authentifizierung-Protokoll ...

InformationsquelleAutor Dr. belisarius

Ich habe gerade diesen thread gefunden, als ich versuchte, das gleiche zu tun. Leider bin ich auf einen MAC, so dass diese Antworten nicht helfen. Mit ein wenig Forschung, ich war in der Lage zu tun, dass es funktioniert in MAC-Excel mit diesem Modul:

Option Explicit

' execShell() function courtesy of Robert Knight via StackOverflow
' http://stackoverflow.com/questions/6136798/vba-shell-function-in-office-    2011-for-mac

Private Declare Function popen Lib "libc.dylib" (ByVal command As String,       ByVal mode As String) As Long
Private Declare Function pclose Lib "libc.dylib" (ByVal file As Long) As Long
Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long

Function execShell(command As String, Optional ByRef exitCode As Long) As String
    Dim file As Long
    file = popen(command, "r")

    If file = 0 Then
        Exit Function
    End If

    While feof(file) = 0
        Dim chunk As String
        Dim read As Long
        chunk = Space(50)
        read = fread(chunk, 1, Len(chunk) - 1, file)
        If read > 0 Then
            chunk = Left$(chunk, read)
            execShell = execShell & chunk
        End If
    Wend

    exitCode = pclose(file)
End Function

Function HTTPGet(sUrl As String) As String

    Dim sCmd As String
    Dim sResult As String
    Dim lExitCode As Long
    Dim sQuery As String

    sQuery = "method=getMetadata&format=xml&fl=*"
    sCmd = "curl --get -d """ & sQuery & """" & " " & sUrl
    sCmd = "curl --get -d """ & sQuery & """" & " " & sUrl

    sResult = execShell(sCmd, lExitCode)

    ' ToDo check lExitCode

    HTTPGet = sResult

End Function

Function getISBNData(isbn As String) As String
  Dim sUrl As String
  sUrl = "http://xisbn.worldcat.org/webservices/xid/isbn/" & isbn
  getISBNData = HTTPGet(sUrl)

End Function



Function getAttributeForISBN(isbn As String, info As String) As String
  Dim data As String
  Dim start As Integer
  Dim finish As Integer


 data = getISBNData(isbn)
 start = InStr(data, info) + Len(info) + 2
 finish = InStr(start, data, """")
 getAttributeForISBN = Mid(data, start, finish - start)


End Function

Dies ist nicht meine ursprüngliche Arbeit, klebte ich es zusammen von einer anderen Seite, dann hat meine eigene Arbeit. Jetzt können Sie Sachen wie tun:

getAttributeForISBN("1568812019","title")

Zurückkehren den Titel des Buches. Natürlich können Sie anwenden dieser Formel auf alle ISBN-Nummern in Spalte A zu suchen, bis mehrere Titel oder Autoren oder was auch immer.

Ich hoffe, dies hilft jemand da draußen!

InformationsquelleAutor Danny