Extrahieren von Tabellen aus pdf-Datei (excel), pref. w/ vba

Haben Sie eine Reihe von Möglichkeiten, um zu sezieren, eine text-Datei und je nachdem, wie Komplex es ist, werden Sie möglicherweise lehnen eine oder andere Weise. Ich habe diese und es kam ein wenig aus der hand... genießen.

Basierend auf der Probe, die Sie haben und die zusätzlichen Kommentare, bemerkte ich Folgendes. Einige von Ihnen funktionieren gut für einfache Dateien, aber kann man unhandlich mit größeren komplexeren Dateien. Darüber hinaus kann es etwas effizienter Methoden oder tricks zu dem, was ich hier verwendet habe, aber diese werden auf jeden Fall erhalten Sie eine erzielen das gewünschte Ergebnis. Hoffentlich macht das Sinn in Verbindung mit dem code:

• Sie können Boolesche Werte, um Ihnen zu helfen herauszufinden, was 'Abschnitt' der text-Datei, die Sie sind in. Dh InStr auf der aktuellen Zeile zu
  bestimmen Sie in einer Tabelle nach der Suche nach dem text 'Tabelle' und dann
  sobald Sie wissen, dass Sie in das 'Table' - Abschnitt der Datei starten
  Suche für das "Vermögen" § usw
• Können Sie ein paar Methoden, um zu bestimmen, die Anzahl der Jahre (oder Spalten), die Sie haben. Die Split Funktion zusammen mit einer Schleife tun
  die job.
• Wenn deine Dateien immer in gleichbleibender Formatierung, auch nur in bestimmten teilen, können Sie diese Vorteile nutzen. Zum Beispiel, wenn Sie wissen, dass Ihr
  Datei Zeile haben immer ein dollar-Zeichen vor der zu Ihnen, dann
  Sie weiß, dass dies definieren Sie die Spaltenbreite und Sie können diese auf
  die folgenden Zeilen text.

Den folgenden code extrahieren wird das Vermögen der Informationen aus der text-Datei, Sie können die mod es zu extrahieren, die anderen Abschnitte. Es sollte in der Lage mehrere Zeilen. Hoffentlich habe ich kommentiert es ausreichend. Werfen Sie einen Blick und ich werde Sie Bearbeiten, wenn nötig zu helfen, weiter.

 Sub ReadInTextFile()
    Dim fs As Scripting.FileSystemObject, fsFile As Scripting.TextStream
    Dim sFileName As String, sLine As String, vYears As Variant
    Dim iNoColumns As Integer, ii As Integer, iCount As Integer
    Dim bIsTable As Boolean, bIsAssets As Boolean, bIsLiabilities As Boolean, bIsNetAssets As Boolean

    Set fs = CreateObject("Scripting.FileSystemObject")
    sFileName = "G:\Sample.txt"
    Set fsFile = fs.OpenTextFile(sFileName, 1, False)

    'Loop through the file as you've already done
    Do While fsFile.AtEndOfStream <> True
        'Determine flag positions in text file
        sLine = fsFile.Readline

        Debug.Print VBA.Len(sLine)

        'Always skip empty lines (including single spaceS)
        If VBA.Len(sLine) > 1 Then

            'We've found a new table so we can reset the booleans
            If VBA.InStr(1, sLine, "Table") > 0 Then
                bIsTable = True
                bIsAssets = False
                bIsNetAssets = False
                bIsLiabilities = False
                iNoColumns = 0
            End If

            'Perhaps you want to also have some sort of way to designate that a table has finished.  Like so
            If VBA.Instr(1, sLine, "Some text that designates the end of the table") Then
                bIsTable = False
            End If 

            'If we're in the table section then we want to read in the data
            If bIsTable Then
                'Check for your different sections.  You could make this constant if your text file allowed it.
                If VBA.InStr(1, sLine, "Assets") > 0 And VBA.InStr(1, sLine, "Net") = 0 Then bIsAssets = True: bIsLiabilities = False: bIsNetAssets = False
                If VBA.InStr(1, sLine, "Liabilities") > 0 Then bIsAssets = False: bIsLiabilities = True: bIsNetAssets = False
                If VBA.InStr(1, sLine, "Net Assests") > 0 Then bIsAssets = True: bIsLiabilities = False: bIsNetAssets = True

                'If we haven't triggered any of these booleans then we're at the column headings
                If Not bIsAssets And Not bIsLiabilities And Not bIsNetAssets And VBA.InStr(1, sLine, "Table") = 0 Then
                    'Trim the current line to remove leading and trailing spaces then use the split function to determine the number of years
                    vYears = VBA.Split(VBA.Trim$(sLine), " ")
                    For ii = LBound(vYears) To UBound(vYears)
                        If VBA.Len(vYears(ii)) > 0 Then iNoColumns = iNoColumns + 1
                    Next ii

                    'Now we can redefine some variables to hold the information (you'll want to redim after you've collected the info)
                    ReDim sAssets(1 To iNoColumns + 1, 1 To 100) As String
                    ReDim iColumns(1 To iNoColumns) As Integer
                Else
                    If bIsAssets Then
                        'Skip the heading line
                        If Not VBA.Trim$(sLine) = "Assets" Then
                            'Increment the counter
                            iCount = iCount + 1

                            'If iCount reaches it's limit you'll have to redim preseve you sAssets array (I'll leave this to you)
                            If iCount > 99 Then
                                'You'll find other posts on stackoverflow to do this
                            End If

                            'This will happen on the first row, it'll happen everytime you
                            'hit a $ sign but you could code to only do so the first time
                            If VBA.InStr(1, sLine, "$") > 0 Then
                                iColumns(1) = VBA.InStr(1, sLine, "$")
                                For ii = 2 To iNoColumns
                                    'We need to start at the next character across
                                    iColumns(ii) = VBA.InStr(iColumns(ii - 1) + 1, sLine, "$")
                                Next ii
                            End If

                            'The first part (the name) is simply up to the $ sign (trimmed of spaces)
                            sAssets(1, iCount) = VBA.Trim$(VBA.Mid$(sLine, 1, iColumns(1) - 1))
                            For ii = 2 To iNoColumns
                                'Then we can loop around for the rest
                                sAssets(ii, iCount) = VBA.Trim$(VBA.Mid$(sLine, iColumns(ii) + 1, iColumns(ii) - iColumns(ii - 1)))
                            Next ii

                            'Now do the last column
                            If VBA.Len(sLine) > iColumns(iNoColumns) Then
                                sAssets(iNoColumns + 1, iCount) = VBA.Trim$(VBA.Right$(sLine, VBA.Len(sLine) - iColumns(iNoColumns)))
                            End If
                        Else
                            'Reset the counter
                            iCount = 0
                        End If
                    End If
                End If

            End If
        End If
    Loop

    'Clean up
    fsFile.Close
    Set fsFile = Nothing
    Set fs = Nothing
End Sub

InformationsquelleAutor CuberChase