VBScript, um ein Dialogfeld zu öffnen, wählen Sie einen Dateipfad

Zurzeit bin ich eine Datei öffnen mit meinem vbscript wie folgt:

strFile = "C:\Users\test\file.txt"
Set objFile = objFSO.OpenTextFile(strFile)

Möchte ich dies ändern, so, dass eine Datei ausgewählt werden kann/navigiert durch den Benutzer, und diese Datei ist in dem Skript verwendet. Wie kann ich diese Fähigkeit? Ich habe versucht zu suchen, wie Sie eine Datei laden dialog/den Benutzer auffordern, eine Datei usw. nur nicht sicher, wie Sie Sie zu vervollständigen in einem VBScript.

InformationsquelleAutor StuartM | 2014-02-04

  1. 21

    Gibt es eine andere Lösung fand ich interessant, aus MS TechNet weniger Anpassung, aber bekommt, was Sie erreichen wollte. Dies gibt den vollständigen Pfad der ausgewählten Datei.

    Set wShell=CreateObject("WScript.Shell")
Set oExec=wShell.Exec("mshta.exe ""about:<input type=file id=FILE><script>FILE.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).WriteLine(FILE.value);close();resizeTo(0,0);</script>""")
sFileSelected = oExec.StdOut.ReadLine
wscript.echo sFileSelected
    Danke. Erfolgreich getestet auf 64-bit-Windows 10 Pro.

    InformationsquelleAutor PatricK

  2. 3

    Hier gehen Sie:

    http://www.robvanderwoude.com/vbstech_ui_fileopen.php

    strFile = GetFileName("C:\Users\test\", "Text files|*.txt")
Set objFile = objFSO.OpenTextFile(strFile)

Function GetFileName( myDir, myFilter )
  ' Written by Rob van der Woude
  ' http://www.robvanderwoude.com

  ' Standard housekeeping
  Dim objDialog

  ' Create a dialog object
  Set objDialog = CreateObject( "UserAccounts.CommonDialog" )

  ' Check arguments and use defaults when necessary
  If myDir = "" Then
    ' Default initial folder is "My Documents"
    objDialog.InitialDir = CreateObject( "WScript.Shell" ).SpecialFolders( "MyDocuments" )
  Else
    ' Use the specified initial folder
    objDialog.InitialDir = myDir
  End If
  If myFilter = "" Then
    ' Default file filter is "All files"
    objDialog.Filter = "All files|*.*"
  Else
    ' Use the specified file filter
    objDialog.Filter = myFilter
  End If

  ' Open the dialog and return the selected file name
  If objDialog.ShowOpen Then
    GetFileName = objDialog.FileName
  Else
    GetFileName = ""
  End If
End Function
    Hilft zu testen, oder zumindest erwähnen gilt, dass UserAccounts.CommonDialog nicht verfügbar ist, auf einem beliebigen 64-bit-host aus.
    UserAccounts.CommonDialog-funktioniert nur auf Windows XP.

    InformationsquelleAutor Nathan Rice

Schreibe einen Kommentar