Abrufen aller Datensätze, die mit Perl DBI

Habe ich ein Perl-Skript, dass verwendet eine DBI Verbindung. Ich öffnen und Lesen der SQL-Skript-Datei über eine sub-routine. Ich Schreibe nur einen Eintrag, wo ich noch zwei (drei Datensätze insgesamt). Wie bekomme ich alle Datensätze?

Ergebnis:

Alert:OUTBOUND_DATA:0

Skript:

my $dbh_oracle = DBI->connect(
          $CFG{oracle_dbi_connect},
          $CFG{db_user},
          $CFG{db_cred},
          {AutoCommit => 0,
           RaiseError => 0,
           PrintError => 0}) or die ("Cannot connect to the database: ".$DBI::errstr."\n");

my ($val1, $val2) = get_data();
print "Alert:$val1:$val2\n";

send_email("Alert:$val1:$val2");

sub get_data
{
  undef $/;
  open (my $QFH, "< /sql/summary.sql") or die "error can't open this file $!";
  my $sth= $dbh_oracle->prepare(<$QFH>) or
      die ("Cannot connect to the database: ".$DBI::errstr."\n");
  $sth->execute;
  close $QFH;
  my $row = $sth->fetchrow_hashref;
  $sth->finish;
  return @$row{'MYTABLE','FLAG'};
}

sub send_email {
    my $message = shift;
    open (MAIL, "|/usr/sbin/sendmail -t") or die "Can't open sendmail: $!";
    print MAIL "To: me\@test.com\n";
    print MAIL "From: Data\n";
    print MAIL "\n";
    print MAIL $message;
    close MAIL;
}
exit;

ERGEBNISSE aus der Abfrage: (mehr als 1 rec)

MYTABLE                  FLAG
----------------------- ----------
OUTBOUND_DATA         0
MSGS_BY_DIM                  0
INBOUND_DATA         0

3 rows selected.

Sie könnte RaiseError => 1 und beseitigen Sie die Notwendigkeit für diejenigen, die () - Aufrufe.
Auch Stelle ich fest, dass Sie beide RaiseError und PrintError deaktiviert. Die erste bewirkt, dass Fehler tödlich sein und der zweite wird mindestens drucken Sie (aber nicht kill your code). Sie sollten wahrscheinlich mindestens einer dieser auf den Wert true, damit Ihre Fehler stillschweigend verworfen.

InformationsquelleAutor cjd143SD | 2012-04-20

dbi perl

2

Es hängt auch davon ab, wie Sie die Strukturierung Ihrer gesamten Skript. Ihre get_data() nennen, nur ein einziges paar Werte zurückgegeben werden. Ich sehe zumindest ein paar Optionen: entweder zurück ein hash (Referenz), in der alle Daten und lassen Sie die main montieren, oder verwenden Sie die loop-Konstrukte, die bereits erwähnt und fertigen die Körper der Nachricht innerhalb der Unterroutine, wenn nur ein einzelner skalarer string.

Zur Rückgabe aller Daten als hash-Referenz, die get_data Unterroutine könnte wie folgt Aussehen (Hinweis: ich bin mit fetchall_hashref statt fetchrow_hashref:
```
sub get_data
{
  undef $/;
  open (my $QFH, "< /sql/summary.sql") or die "error can't open this file $!";
  my $sth= $dbh_oracle->prepare(<$QFH>) or
      die ("Cannot connect to the database: ".$DBI::errstr."\n");
  $sth->execute;
  close $QFH;
  my $hash_ref = $sth->fetchall_hashref('MYTABLE');
  $sth->finish;
  return $hash_ref;
}
```
Und rufen Sie es von main und verwenden Sie die Ausgabe wie folgt:
```
my $hash_ref = get_data();
my $message = "";
foreach my $table (sort keys %$hash_ref) {
    $message .= join(":", "Alert", $table, $$hash_ref{$table}{'FLAG'}) . "\n";
}
```
Dadurch wird $message mit:
```
Alert:INBOUND_DATA:0
Alert:MSGS_BY_DIM:0
Alert:OUTBOUND_DATA:0
```
Ist und möchten Sie vielleicht höflich:
```
$dbh_oracle->disconnect;
```
bevor Sie verlassen.

Dieser hat einige Probleme, für Beispiel, Sie habe die SQL versteckt in einem externen Skript, aber ich habe gegriffen zu hart codierte Schlüssel (MYTABLE, ich bin vorausgesetzt ist einzigartig in Ihrer Abfrage) und den Wert (FLAG) in der Skript, welches die Begrenzung später, wenn Sie erweitern möchten.

Dies ist, was ich suchte. ich war, und versuchte, sich auf die Verwendung eines Unterprogramms. Vielen Dank für die Bereitstellung der Verwendung von main Beispiel als eine Möglichkeit, zu montieren die Ausgabe.

InformationsquelleAutor gkaupas
8

Gibt es viele verschiedene Möglichkeiten können Sie abrufen von Daten aus einer Anweisung verarbeiten. Die häufigsten sind Recht einfach, und Ihre Verwendung ist unten dargestellt:
```
my @row_array = $sth->fetchrow_array;
my $array_ref = $sth->fetchrow_arrayref;
my $hash_ref  = $sth->fetchrow_hashref;
```
Den ersten, fetchrow_array, zurück, die jede Zeile wiederum als array. Ein Beispiel mit Daten zurückgegeben, die von der select-oben könnte sein:
```
while (my @row_array = $sth->fetchrow_array) {
    print $row_array[0], " is ", $row_array[1], " years old, and has a " , 
          $row_array[2], "\n";
}
```
Das zweite Beispiel ist ähnlich, aber liefert eine array-Referenz anstatt eines Arrays:
```
while (my $array_ref = $sth->fetchrow_arrayref) {
    print $array_ref->[0], " is ", $array_ref->[1], 
          " years old, and has a " , $array_ref->[2], "\n";
}
```
Dem Dritten Beispiel fetchrow_hashref, oft die meisten lesbar:
```
while (my $hash_ref = $sth->fetchrow_hashref) {
    print $hash_ref->{name}, " is ", $hash_ref->{age}, 
          " years old, and has a " , $hash_ref->{pet}, "\n";
}
```
Ein Hinweis zu fetchrow_hashref, werden die Tasten der oberen Gehäuse-es sei denn, Sie ändern die FetchHashKeyName - Attribut.
danke für die Beispiele.
Diese Antwort ist nicht vollständig ohne die Erwähnung @gpojd 's Antwort mit den selectall_ Funktionen

InformationsquelleAutor Ωmega
3

Diese Linie sollte eine Schleife:
```
my $row = $sth->fetchrow_hashref;
```
Sollte es sein:
```
my @rows;
while ( my $row = $sth->fetchrow_hashref ) {
    push @rows, $row;
}
return @rows;
```
Wenn Sie das lieber haben-DBI-do die Schleife für Sie, überprüfen Sie heraus selectall_arrayref oder selectall_hashref

wo lege ich $sth->finish? wäre das nach ich return @$row?
wenn Sie fertig sind, wird der loop $sth- > fetchrow_hashref wird return undef und "Ende" selbst.

InformationsquelleAutor gpojd
2

Den fetchrow_ Methoden buchstäblich nur fetch eine Zeile zu einem Zeitpunkt.

Wenn Sie möchten, dass alle Zeilen, in der einige Spalten, Sie können schlecht schieben um Daten-Strukturen, oder verwenden Sie einen Anruf bedeutete für Ihre situation.

Es scheint mir, die Sie verwenden möchten selectcol_arrayref in:
```
my $ary_ref = $dbh->selectcol_arrayref(
    "select id, name from table",
    { Columns=>[1,2] }
);
```
Die Spalte Indizes beziehen sich auf die position der Spalten im ResultSet, nicht in der ursprünglichen Tabelle.

Die Art und Weise Sie die zurückgegebenen Ergebnisse werden auch geändert werden müssen, um alle Zeilen zurückgegeben werden.

Außerdem haben Sie:
```
sub get_data
{
  undef $/;
```
weil Sie schlürfen die Datei mit den SQL. Allerdings $/ ist eine Globale variable. Sollten Sie verwenden lokale $/ im kleinstmöglichen Umfang. Also:
```
my $sql = do { local $/; <$fh> };
```
ja, ich Stimme in diesen Fällen möchte ich alles aus der Abfrage scheint es selectcol_arrayref wäre die Wahl. Dein Vorschlag für die Verwendung local $/, würde ich das als Unterprogramm oder lassen Sie diese außerhalb? danke.

InformationsquelleAutor Sinan Ünür

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.