abrufen von Daten aus html-code mit vbscript

Es gibt zwei Möglichkeiten zum abrufen von Informationen aus HTML. Beide sind hier gezeigt:

Option Explicit

Dim goFS : Set goFS = CreateObject("Scripting.FileSystemObject")

Const csURL             = "http://gent/16584664.html"                 ' 'real' const
Dim   csFSpec : csFSpec = goFS.GetAbsolutePathName(".\16584664.html") ' 'pseudo' const

' use comment or order to select a strategy
WScript.Quit useDom()
WScript.Quit useRegExp()

Function useRegExp()
  Dim sAll  : sAll      = goFS.OpenTextFile(csFSpec).ReadAll()
  Dim reCut : Set reCut = New RegExp
  reCut.Global  = True
  reCut.Pattern = "RegistrationDTO.register</td>\s+<td>(\d+)</td>"
  Dim oMTS  : Set oMTS  = reCut.Execute(sAll)
  If 1 = oMTS.Count Then
     WScript.Echo "success:", oMTS(0).SubMatches(0)
  Else
     WScript.Echo "failure"
  End If
  useRegExp = 0
End Function ' useRegExp

Function useDom()
  Dim oDOM  : Set oDOM = CreateObject("HTMLFILE")
' Dim sHTML : sHTML    = getURL(csURL)
  Dim sHTML : sHTML    = goFS.OpenTextFile(csFSpec).ReadAll() ' for testing
  oDOM.write sHTML
  ' descending the tree                HTML          BODY         TABLE         TBODY       5th row       2nd col
  Dim oItem : Set oItem = oDOM.childNodes(0).childNodes(1).childNodes(0).childNodes(0).childNodes(4).childNodes(1)
  ' WScript.Echo "success:", oItem.tagName ' drill down help
  WScript.Echo "success:", oItem.innerHTML
  ' WScript.Echo "success:", oItem.parentNode.childNodes(2).innerHTML ' verification
  useDom = 0
End Function ' useDom

Function getURL(sURL)
  Dim oHTTP : Set oHTTP = CreateObject("Msxml2.XMLHTTP")
  oHTTP.Open "GET", csURL, False
  oHTTP.Send
  If 200 = oHTTP.Status Then
     getURL = oHTTP.responseText
  Else
     ' handle error
  End If
End Function ' getURL

Ausgabe:

cscript 16584664.vbs
success: 1068

Des RegExp-Ansatz offensichtlich setzt Voraus, dass Sie definieren können, ein Muster zur eindeutigen Identifizierung des gewünschten Teils. Der DOM-Ansatz funktioniert nicht mit fehlerhaften HTML-und vielleicht ungeschickt, wenn Sie haben, um auf den gewünschten Menüpunkt-position (wie in diesem Fall). Beide sind sinnvoll, um änderungen an der HTML.

P. S.

csFSpec ist (der vollständige Pfad) eine Datei mit dem angegebenen Beispiel-HTML verpackt in die erforderlichen tags, es legal zu machen. Für die Prüfung, können Sie die SaveAs-die Seite aus dem browser.

Wenn Sie csURL auf die richtige URL ein und aktivieren Sie die getURL () - Zeile in der useDom () - Funktion, müssen Sie nicht die Datei.

P. P. S.

Zur Bewältigung der etwas andere HTML-Emil gab in seinem (wahrscheinlich bald gelöscht werden) andere Frage, musste ich die RegExp-Muster aus:

reCut.Pattern = "RegistrationDTO.register</td>\s+<td>(\d+)</td>"

zu:

reCut.Pattern = "RegistrationDTO.register</td>\s*<td>(\d+)</td>"

Umgang mit whitespace-Zeichen (allgemeiner und daher besser, hätte es vom start)

und die drill-down von:

' descending the tree                HTML          BODY         TABLE         TBODY       5th row       2nd col
Dim oItem : Set oItem = oDOM.childNodes(0).childNodes(1).childNodes(0).childNodes(0).childNodes(4).childNodes(1)

zu:

  ' descending the tree                HTML          BODY             P        TABLE         TBODY       6th row       2nd col
  Dim oItem : Set oItem = oDOM.childNodes(0).childNodes(1).childNodes(0).childNodes(0).childNodes(0).childNodes(5).childNodes(2)

ein zusätzliches P und der geänderten Anzahl von Zeilen berücksichtigt.

Dies verdeutlicht die fragigility der beiden Strategien, die ich oben erwähnt. @Ansgar den Weg der Schleife über eine (hoffentlich) stabile Sammlung und das tun Vergleiche könnten hier helfen.