Analysieren finnischen Datum string zu Datum Geben Sie in VB6

Ich bin immer in der finnischen Datums-Zeichenfolge, die wie folgt aussieht:

29.7.2011 9:27

Ich versuche, die Besetzung dieser string zu einem Date-Objekt in VB6. Ich habe versucht mit der Format-Funktion, aber es scheint nicht zu schlucken, die Datums-Zeichenfolge oder ich mache etwas falsch. Dies sind einige Ansätze, die ich ausprobiert habe:

theDate = Format(dateString, "General Date")

theDate = Format(dateString, "DD.MM.YYYY MM:HH")

Irgendwelche Ideen? Danke.

Getan. Aktualisiert die Frage.

InformationsquelleAutor Phil | 2011-09-13

Anstatt manuell Parsen der string selbst, die ist fehleranfällig, und die wird chaotisch, wenn man mit mehreren Datums-Formate, die Sie nennen können, um die OLE-Automation library (die VB6 verwendet intern für viele Dinge, einschließlich Typ-Konvertierungen), um die Konvertierung für Sie tun. Es kann konvertieren von Zeichenfolgen in beliebigen Datum/Zeit-format, die von Windows unterstützt wieder in ein raw - Datum.

Vollständige Offenlegung: ich Stimme mit der Stimmung in Deanna ist
Antwort: im Allgemeinen sollten Sie versuchen, verwenden Sie einen eindeutigen Datums - /Zeit
format bei der Umwandlung von Datumsangaben und strings, aber wenn Sie nicht tun
für einige Grund, die Lösung hier beschrieben sein sollte, ziemlich robust, solange Sie im Voraus wissen, welche spezifischen format der Eingang string in.

Unten ist ein Beispiel für eine DateFromString - Funktion, verwendet die VarDateFromStr Funktion intern zu konvertieren, die eine formatierte Datum/Uhrzeit - String in eine Datum.

Beispiel Für Die Verwendung

Konvertieren eine finnische Datums-string zu einem Datum und anzeigen:

MsgBox DateFromString("29.7.2011 9:27", fl_FI)

Auf meinem Rechner (Englisch (USA-Einstellungen) diese Anzeige zeigt "7/29/2011 9:27 UHR", welches das richtige Datum und Zeit (Juli 29).

Code

Fügen Sie den folgenden code in ein neues Modul (.bas-Datei) in Ihrem Projekt zu verwenden. Der code derzeit unterstützt Parsen von US-Englisch (de_de) und finnischen (fl_FI) Datum-strings, aber Sie können hinzufügen der Unterstützung für weitere Sprachen, falls erforderlich. Sehen Gebietsschema-IDs zugeordnet, die von Microsoft für eine vollständige Liste der Gebietsschema-ID ist.


Option Explicit

Public Enum LocaleIDs
    en_US = &H409       ' English (United States)
    fl_FI = &H40B       ' Finnish
    ' [[ Add other Locale ID's here as needed ]] '
End Enum

Private Declare Function VarDateFromStr Lib "oleaut32.dll" ( _
    ByVal psDateIn As Long, _
    ByVal lcid As Long, _
    ByVal uwFlags As Long, _
    ByRef dtOut As Date) As Long

Private Const S_OK = 0
Private Const DISP_E_BADVARTYPE = &H80020008
Private Const DISP_E_OVERFLOW = &H8002000A
Private Const DISP_E_TYPEMISMATCH = &H80020005
Private Const E_INVALIDARG = &H80070057
Private Const E_OUTOFMEMORY = &H8007000E

'
' Converts a date string in the specified locale to a VB6 Date.
'
' Example:
'
'   Convert a Finnish date string as follows:
'
'   DateFromString("29.7.2011 9:27", fl_FI)
'
Public Function DateFromString(ByVal sDateIn As String, ByVal lcid As LocaleIDs) As Date

    Dim hResult As Long
    Dim dtOut As Date

    ' Do not want user's own settings to override the standard formatting settings
    ' if they are using the same locale that we are converting from.
    '
    Const LOCALE_NOUSEROVERRIDE = &H80000000

    ' Do the conversion
    hResult = VarDateFromStr(StrPtr(sDateIn), lcid, LOCALE_NOUSEROVERRIDE, dtOut)

    ' Check return value to catch any errors.
    '
    ' Can change the code below to return standard VB6 error codes instead
    ' (i.e. DISP_E_TYPEMISMATCH = "Type Mismatch" = error code 13)
    '
    Select Case hResult

        Case S_OK:
            DateFromString = dtOut
        Case DISP_E_BADVARTYPE:
            Err.Raise 5, , "DateFromString: DISP_E_BADVARTYPE"
        Case DISP_E_OVERFLOW:
            Err.Raise 5, , "DateFromString: DISP_E_OVERFLOW"
        Case DISP_E_TYPEMISMATCH:
            Err.Raise 5, , "DateFromString: DISP_E_TYPEMISMATCH"
        Case E_INVALIDARG:
            Err.Raise 5, , "DateFromString: E_INVALIDARG"
        Case E_OUTOFMEMORY:
            Err.Raise 5, , "DateFromString: E_OUTOFMEMORY"
        Case Else
            Err.Raise 5, , "DateFromString: Unknown error code returned from VarDateFromStr (0x" & Hex(hResult) & ")"
    End Select

End Function

omg das ist so gut. Die Menge der Arbeit, die Sie in dieser verdient +10. Du hast +1 zumindest 🙂
Oh ich gelernt, alle zu Datum-Konvertierung vor kurzem, denn ich war die Befestigung ein Vermächtnis VB6-Anwendung auf ein standardisiertes Datumsformat intern (vor es würde nur funktionieren, richtig mit Computern verwenden " m/d/y format), und ich dachte mir, diese auf dem Weg 😉

InformationsquelleAutor Mike Spross

2

Können Sie DateSerial und "TimeSerial" in der folgenden Weise
```
dateString = "29.7.2011 9:27"

Dim theDate as Date

dim yyyy as Integer
dim mm as Integer
dim dd as Integer
dim hh as integer
dim mm as integer

yyyy = mid(dateString,6,4)
mm = mid(dateString,4,1)
dd = mid(dateString,1,2)
hh = mid(dateString,11,1)
mm = mid(dateString,13,2)

theDate = DateSerial(yyyy,mm,dd) + TimeSerial(hh,mm,0)
```
nun Sie theDate ist ein Datum-Objekt und formatiert werden können, wie Sie wollen
```
MsgBox Format(theDate,"yyyy-MMM-dd")  'This will display the a message with 2011-Jul-29
```
Wenn Ihr den Datums-string nicht mit Nullen aufgefüllt (Beispiel: 2.4.2011 statt 02.04.2011), dann musst du eine Schleife über den string zu finden, die bits und Teile das Datum, die Sie benötigen werden.
- Es ist nicht mit Nullen aufgefüllt. Ich werde kombinieren Sie Ihre Antwort mit den anderen, da es möglich ist, teilen Sie die Zeichenfolge durch die Zeiten.
- Mit (festen) von Teilstrings ist nicht wirklich praktisch mit beliebigen Daten mit variabler Länge. Ihre Probe bricht auch auf die ersten 9 Tage des Monats, im Oktober, November und Dezember, und ab 10 UHR, an jedem Tag.
InformationsquelleAutor Ahmad
2

Finnisch-Systeme sollten in der Lage sein, zu analysieren, richtig mit CDate(). Wenn Sie analysieren es auf einer nicht Finnisch-system und das format ist behoben, dann müssen Sie es aufteilen in code:
```
Dim Parts() as string, dateParts() As String, timeParts() as string
parts = Split(dateString, " ")
dateParts = Split(parts(0), ".") 
timeParts = Split(parts(1), ":")
theDate = DateSerial(dateParts(2), dateParts(1), dateParts(0)) + TimeSerial(timeParts(0), timeParts(1), 0)
```
Werden Sie probbaly hinzufügen möchten, Fehlerbehandlung und ' sanity checks zu machen, aber das ist die Grundidee.

Beachten Sie, dass die Konvertierung von Daten in und aus string-Werte werden fehleranfällig, es sei denn mit sehr expliziten verfügbar vereinbarten Formaten wie ISO 8601, RFC 822 Termine und iCal - RFC 2445 standard.
- meinst du timeParts = Split(teilen(1), ":") ?
- Danke, habe ich falsch verstanden, das Beispiel Datum
InformationsquelleAutor Deanna

Analyse chaotisch ist am besten, aber hier ist eine kürzere Probe, wie es zu tun

Private Sub Command1_Click()
    MsgBox Format$(TryParse("29.7.2011 9:27"), "yyyymmdd hh:mm:ss")
End Sub

Private Function TryParse(sFinnishDate As String) As Date
    Dim vSplit As Variant

    vSplit = Split(Replace(Replace(sFinnishDate, ".", " "), ":", " "))
    On Error Resume Next
    TryParse = DateSerial(vSplit(2), vSplit(1), vSplit(0)) + TimeSerial(vSplit(3), vSplit(4), 0)
    On Error GoTo 0
End Function

InformationsquelleAutor wqw

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.