Anhängen an eine Datei statt overwritting die Datei jedes mal in VBScript

Ich versuche nur, um eine log-Datei hier. Ich habe versucht, etwas zu tun mit OpenTextFile statt CreateTextFile, aber dann ist es eben schreibt nichts und ich bin wirklich nicht sicher, warum, und ich habe Probleme bei der Suche nach der info, die ich brauche.

'Nick Repella 10/29/13

'Needed in case object does not exist (outdated list)
On Error Resume Next

Function IsCompDisabled(strLine)
    Dim objComputer
    objComputer = "LDAP://cn="
    objComputer = objComputer & strLine
    objComputer = objComputer & ",ou=HIDDENOU,dc=HIDDENDC,dc=HIDDENDC,dc=HIDDENDC"
    IsCompDisabled = GetObject(objComputer).AccountDisabled
End Function 

'Set the file to read computer names from (Change C:\scripts\text.txt to the 
'target file)
Set objFileToRead = CreateObject("Scripting.FileSystemObject").OpenTextFile("C:\scripts\text.txt", 1)

Dim strLine

Do While Not objFileToRead.AtEndOfStream
    strLine = objFileToRead.ReadLine()
    If (IsCompDisabled(strLine) = True) Then
        outFile="c:\scripts\compDisableCheck.log"
        Set objFSO = CreateObject("Scripting.FileSystemObject")
        Set objFile = objFSO.CreateTextFile(outFile, True)
        objFile.Write strLine & "has been deleted"
        objFile.Close        
    Else
        WScript.Echo strLine & " computer is enabled no action taken"
    End If
Loop

MsgBox "Done"

InformationsquelleAutor user2939192 | 2013-10-30

  1. 5

    Studie der docs gezielt. Definieren, ForAppending, .OpenTextfile(sFSpec, ForAppending, True) die Ausgabe-Datei vor, und schließen Sie es nach der Schleife.

    (UNGETESTETEN) code:

    Option Explicit

Const ForAppending = 8

'No global OERN

'Function to tell if the computer is disabled
Function IsCompDisabled( strLine )
    ' type prefix fraud!
    Dim objComputer
    objComputer = "LDAP://cn="
    objComputer = objComputer & strLine
    objComputer = objComputer & ",ou=HIDDENOU,dc=HIDDENDC,dc=HIDDENDC,dc=HIDDENDC"
  ' Needed  H E R E  in case object does not exist (outdated list)
  On Error Resume Next
    IsCompDisabled = GetObject(objComputer).AccountDisabled
    ' should be logged; pass otp file as parameter
  On Error GoTo 0
End Function

'Set the file to read computer names from (Change C:\scripts\text.txt to the target file)
Dim oFS : Set oFS = CreateObject("Scripting.FileSystemObject")
Dim objFileToRead : Set objFileToRead = goFS.OpenTextFile("C:\scripts\text.txt") ' Using defaults, no magiv number
' delete otp file here, if you want logs per session
Dim objFile : Set objFile = goFS.OpenTextFile("c:\scripts\compDisableCheck.log", ForAppending, True)
'objFile[ToAppend] ?

Dim strLine

'Read from file until end of file
'If computer disabled say so /If computer enabled say so
Do Until objFileToRead.AtEndOfStream ' not while not
    strLine = objFileToRead.ReadLine()
    If IsCompDisabled(strLine) Then ' no camparison against boolean literals
       ' timestamp?
       objFile.WriteLine strLine & " has been deleted"
    Else
       ' ? objFile.WriteLine ...
       WScript.Echo strLine & " computer is enabled, no action taken"
    End If
Loop
objFile.Close
objFileToRead.Close

MsgBox "Done"
    Ihnen fehlt das " n " auf Ihre deklarierte Konstante ForAppendig... 🙂
    Danke. Behoben.

    InformationsquelleAutor Ekkehard.Horner

Schreibe einen Kommentar