Anhängen von +1 bis-Datum in batch-Datei

Ich habe eine batch Datei erstellt, die das heutige Datum ganz gut. Jetzt muss ich es aktualisieren, um zu zeigen, das morgige Datum. Jede Hilfe ist sehr willkommen:

@echo off
set TimeStamp=12:00:00


FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B

FOR /F "TOKENS=1,2 eol=/DELIMS=/" %%A IN ('DATE/T') DO SET mm=%%B

FOR /F "TOKENS=1,2 DELIMS=/eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B

FOR /F "TOKENS=2,3 DELIMS=/" %%A IN ('echo %CDATE%') DO SET yyyy=%%B

SET date="%yyyy%-%mm%-%dd% %TimeStamp%"

echo %date%

InformationsquelleAutor YoungDev | 2013-08-08

Das 'problem' ist, dass Sie brauchen, um darüber nachzudenken. Februar, Sprung-Jahre, etc.

Paul Tomasi geschrieben hat, brilliante Skript auf seiner Website wo er erklärt es vollständig, sogar mit einem Flussdiagramm.

::================================================
:: TOMORROW.BAT - Written by Paul Tomasi (c)2010
::
:: Function to return tomorrow's date
::================================================
@echo off

set /a d=%date:~0,2%
set /a m=%date:~3,2%
set /a y=%date:~6,4%

:loop
   set /a d+=1

   if %d% gtr 31 (
      set d=1
      set /a m+=1

      if %m% gtr 12 (
         set m=1
         set /a y+=1
      )
   )

xcopy /d:%m%-%d%-%y% /h /l "%~f0" "%~f0\" >nul 2>&1 || goto loop

echo %d%/%m%/%y%

::------------------------------------------------

Anhängen von +1 bis-Datum in batch-Datei

So, es ist entweder das, oder Tauchen in hybrid-batch-Skripte.

Hoffe, das hilft!

InformationsquelleAutor GitaarLAB

3
```
@echo off &SETLOCAL
SET "today=%date%"
ECHO(today is       %today%
CALL:DateToJDN %today% todayNo
ECHO(this is day no.        %todayNo%
SET /a tomorrowNo=todayNo+1
ECHO(tomorrow is day no.    %tomorrowNo%
CALL:JDNToDate %tomorrowNo% tomorrow
ECHO(tomorrow is        %tomorrow%
GOTO:EOF

rem Convert the date to Julian Day Number

:DateToJDN dd.mm.yyyy jdn=
setlocal
set date=%1
set /A yy=%date:~-4%, mm=1%date:~-7,2% %% 100, dd=1%date:~-10,2% %% 100
set /A a=mm-14, jdn=(1461*(yy+4800+a/12))/4+(367*(mm-2-12*(a/12)))/12-(3*((yy+4900+a/12)/100))/4+dd-32075
endlocal & set %2=%jdn%
exit /B

rem Convert Julian Day Number back to date

:JDNToDate jdn dd.mm.yyyy=
setlocal
set /A l=%1+68569,n=(4*l)/146097,l=l-(146097*n+3)/4,i=(4000*(l+1))/1461001,l=l-(1461*i)/4+31,j=(80*l)/2447,dd=l-(2447*j)/80,l=j/11,mm=j+2-(12*l),yy=100*(n-49)+i+l
if %dd% lss 10 set dd=0%dd%
if %mm% lss 10 set mm=0%mm%
endlocal & set %2=%dd%.%mm%.%yy%
exit /B

endlocal
```
```
heute ist 08.08.2013 
dies ist Tag keine. 2456513 
morgen ist Tag keine. 2456514 
morgen wird 09.08.2013 
```
Hallo Endoro, ich bin immer der folgende Fehler beim ausführen von code Beispiel: code ** heute ist Donnerstag 08/08/2013 Ungültige Zahl. Numerische Konstanten sind entweder dezimale (17), hexadezimale (0x11) oder oktale (021). dies ist Tag keine. morgen ist Tag keine. 1 morgen ist der 25.11.-4713**
Die date - format hängt von den lokalen Einstellungen (Ihre Einstellungen für Land). Mein Datumsformat ist dd.mm.yyyy, wie Sie sehen können, in der Skript-Ausgabe Teil.
Keine dieser Optionen für mich gearbeitet und mit PowerShell war nicht eine option. Was ich am Ende tun war das verwenden von VBScript erstellt, die das Datum in einem format, das ich wollte. Dann habe ich auch erstellt .batch-Datei on-the-fly. Da mein Konto neu ist, es wird nicht lassen Sie mich beantworten Sie meine Frage. Ich werde versuchen, die Lösung posten später.
Sie können einstellen, mein code für das Datum-format. Ich könnte es machen, auch wenn ich wusste, dass es.
Ich bin ein bisschen nervös, dass das nicht perfekt umsetzen das Julianische Datum-Konvertierung. Ich gebe es einen Schuss, und wieder sein, wenn Dinge scheitern, über Weihnachten / Schaltjahre 😉

InformationsquelleAutor Endoro
1

Sorry, ich kann nicht sagen, was Sie tun, mit Ihrem Batch-code. Können Sie Kommentar diesem?
Warum müssen Sie den Zeitstempel von 12:00?

In meiner deutschen version sagt es mir:
```
"eingeschaltet-- 12:00:00"
```
nach dem ausführen

(eingeschaltet bedeutet "eingeschaltet" oder "auf" oder ähnliches)

Würden Powershell eine option sein? Speichern Sie Ihre geistige Gesundheit...
```
$Today = Get-Date
$Tomorrow = $Today.AddDays(1)

Write-Host "Tomorrow: $Tomorrow"
```
Ja, Sie können starten Sie eine Powershell-Skript aus Batch:

Powershell starten, und geben Sie "Set-ExecutionPolicy Unrestricted"

(oder melden Sie Ihr Skript, wenn andere Menschen brauchen, um ausführen)
Sie können in der Nähe Powershell-jetzt müssen wir nur brauchte es für diesen einmaligen Schritt

In Ihrem Batch (vorausgesetzt, das Skript wird als "Add-Tage.ps1")
```
set script="Add-Days.ps1"
powershell.exe -NoProfile -File "%script%"
```
Hallo, vielen Dank für Ihre prompte Antwort. Wenn ich das Skript hier ist die Ausgabe, die ich bekomme ""2013-08-08 12:00:00". Alle, die ich brauchen, ist zum Anhängen +1, um das Datum nur. Ich bin nicht vertraut mit der powershell, aber ich würde nicht dagegen, es zu versuchen. Der code was ich gepostet ist nur ein Teil der batch-Datei-operation, die nutzt dieses Datum als input-variable. Kann powershell ausgeführt werden innerhalb einer batch-Datei?
Sorry, siehe meine Antwort bearbeitet, Kommentare haben noch so kleinen Raum. Ich habe allerdings keine Ahnung, wie man die Ausgabe wieder in Batch.
href="http://stackoverflow.com/a/18538751/2098699">stackoverflow.com/a/18538751/2098699

InformationsquelleAutor Dreami
0

Ich mag Paul Tomasi Lösung (vorgeschlagen von GitaarLAB), aber ich fand es hat sich ein kleiner Fehler, es funktioniert nicht für "08" und "09" Tagen des Monats.

Dies ist, weil die führende null bedeutet, dass das system denkt, Sie sind ungültige oktale zahlen und so mit dieser Aussage:
```
set /a d=%date:~0,2%
```
Generiert die folgende Fehlermeldung mit system-Termine wie 08/03/2017 oder 09/03/2017 (vorausgesetzt, dd/mm/yyyy-format auf Ihre Termine):

Ungültige Zahl. Numerische Konstanten sind entweder dezimale (17),
hexadezimale (0x11) oder oktale (021).

Fand ich die Lösung an anderer Stelle auf hier (siehe Umgang mit oktal-Variablen im batch-Skript), müssen Sie hinzufügen und dann subtrahieren Sie 100 den Umgang mit der führenden null, nach dieser Aussage:
```
set /a d=(1%d: =0%-100)
```
Hier ist das aktualisierte Skript im Wortlaut:
```
::=====================================================
:: TOMORROW.BAT - Written by Paul Tomasi (c)2010
::
:: Function to return tomorrow's date
::    
:: updated to work for 08 and 09 days of the month
::             and for 08 and 09 months of the year
::=====================================================
@echo off

set d=%date:~0,2%
set m=%date:~3,2%
set y=%date:~6,4%

set /a d=(1%d: =0%-100)
set /a m=(1%m: =0%-100)

:loop

   if %d% gtr 31 (
      set d=1
      set /a m+=1

      if %m% gtr 12 (
         set m=1
         set /a y+=1
      )
   )

xcopy /d:%m%-%d%-%y% /h /l "%~f0" "%~f0\" >nul 2>&1 || goto loop

echo %d%/%m%/%y%

::------------------------------------------------
```
InformationsquelleAutor SI_2000

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.