as3: Wie kopieren Sie ein Objekt von Wert

function clone ( arr:Array ):Array
{
    return arr.map( function( item:*, ..r ):*
        {
            return item;
        } );
}

edit:

Enthält möglicherweise einige syntax-Fehler...

public class MyObject
{
    private var arr:Array;
    private var bool:Boolean;

    //...

    public function clone ():MyObject
    {
        var obj:MyObject = new MyObject();

        //clone values
        obj.arr = this.arr.slice();
        obj.bool = this.bool;

        return obj;
    }
}

Hier ist eine alternative zu der beschriebenen Methode von poke:

Möchte ich zunächst einige Punkte über die poke ' s post.

1. "Definieren Sie Ihre eigenen Klon-Funktion für das jeweilige Objekt. Es gibt keine Besondere Funktion, also automatisch für jedes beliebige Objekt." Falsch. ActionScript hat eine eingebaute Methode zum serialisieren aufgerufen, AMF (ActionScript Message Format). AMF kann verwendet werden, um eine Kopie der nicht-primitiven Objekte.

2. "Mithilfe einer benutzerdefinierten clone-Methode hat den großen Vorteil, dass man genau entscheiden, was kopiert werden soll, und wie es sein wird kopiert..." Das ist genau das, was Sie tun, wenn Sie serialise ein Objekt, so dass es keinen Vorteil der benutzerdefinierten clone-Methode, dass von über serialisieren.

3. "...und, dass die Rückkehr der Typ korrekt ist (d.h. Sie brauchen nicht zu werfen)." Sie brauchen nicht zu werfen eine serialisierte Objekt entweder. Aber serialisieren hat den Vorteil, dass Sie generisch, so dass die Funktion zum kopieren von dynamischen, und nicht beschränkt auf bestimmte Arten.

4. "[Implementierung einer Schnittstelle] (das wäre höchst unpassend, da die clone gibt ein Objekt der besonderen Art)" zu definieren, eine Rückkehr geben wird das statische, die Schlösser, die Sie mit bestimmten Arten. Wenn wir die dynamischen Attribute der Sprache, die wir machen können, die einen generischen Klon-Methode und nicht Pflege zu geben. Es ist nichts unangemessenes über die.

5. ", Dass Sie eine Kopie eines Objekts, wenn du unserialize ein serialisiertes Objekt zweimal, ist nur ein zusätzlicher Effekt der Serialisierung." Die Tatsache, Sie bekommen eine Kopie eines array durch Aufruf von slice() oder concat() ohne Argumente ist einfach ein Nebeneffekt dieser Methoden. Ich weiß nicht wirklich sehen, dein Punkt hier. Auch serialisieren kopieren in Ihrem Herzen. Der Akt der serialising dann de-serialising ist die Rechtshandlung, mit der eine Kopie. Sie nicht irgendwie bekommen, die genau die gleichen Speicher zurück, mit Referenzen und alle intakt.

Und ich habe eine Frage: Wie würden Sie umgehen mit geschachtelten nicht-primitiven Typen in der clone-Methode?

In Ihrer Frage, geben Sie "Kann jemand mir helfen, zu verstehen, wie kopiere ich z.B. das array per value, nicht per reference)" ich denke, beim kopieren von Objekten, ist es wichtig zu wissen, den Unterschied zwischen flach und deep kopiert.

Flache Kopien

Den Lösungen hier (Array.slice () und Array.concat()) sind bekannt als flach kopiert. Was Sie bekommen, ist eine Kopie des Arrays. Wenn der Inhalt des Arrays primitive Typen (diejenigen, die als Wert übergeben werden, nicht als Verweis), dann haben Sie zwei einzigartige Objekte, das original und die Kopie. Wenn man sich jedoch ein array enthält Objekte werden per Referenz übergeben, dann Sie beide, das original und die Kopie des array müssen die exakt gleiche Inhalt. Wenn Sie änderungen an einem Objekt im ursprünglichen array an, die änderungen werden in das array kopiert. Dies mag zwar manchmal, was Sie sich wünschen, ist es nicht immer.

Tiefe Kopien

Einer tiefen Kopie werden, Durchlaufen Sie die Hierarchie, der das Objekt, das Sie kopieren möchten, und machen Sie Kopien von jedem Objekt, das er findet. Sie werden dann erlaubt werden, um änderungen an dem kopierten Objekt ohne änderungen in das original übernommen.

Wenn Sie zum definieren einer benutzerdefinierten clone-Methode als Sack schlägt, dann kopieren nicht prinitive Arten wird übermäßig kompliziert. Würden Sie haben zu gehen durch die Eigenschaften des Objekts und rufen Sie eine benutzerdefinierte clone () - Methode auf jedem nicht-primitiven Typ. Jedoch, wenn Sie auftreten, wird ein built-in nicht-primitiven Typs, wie Array oder ein Dictionary, dann müsste man neu erstellen Sie das Objekt, Schleife durch seine Inhalte, und starten Sie alle immer wieder überprüfen, ob es nicht primitive, den Aufruf der clone () - Methode, wenn es einen hat, oder den Umgang mit Arrays und Dictionaries. Es wird übermäßig kompliziert. Um zusammenzufassen, diese Methode hat zwei Probleme: Sie haben für den Umgang mit Arrays und Dictionaries (und der Einbau von nicht-primitiven Typ) selbst; Sie müssen speziell Aufruf der clone-Methode auf verschachtelte Objekte (und wissen, dass Sie die clone-Methode definiert).

Andere Methode ist das verwenden von AMF für den serialise und dann de-serialise das Objekt, so dass Sie eine Tiefe Kopie. Dies funktioniert direkt aus der box für Arrays, Dictionaries und andere, nicht-primitiven, die sich auf öffentliche Liegenschaften.

var t:Array = [];
t[0] = [1, 2, 3];
t[1] = new Dictionary();
t[1]['hello'] = 'world';
t[2] = {'my': 'object'}
trace(t, t[1]['hello'], t[2]['my']); //[trace] 1,2,3,[object Dictionary],[object Object] world object
var t2:Array = clone(t);
trace(t2, t2[1]['hello'], t2[2]['my']); //[trace] 1,2,3,[object Dictionary],[object Object] world object
t[0] = [4, 5, 6];
t[1]['hello'] = 'earth';
t[2]['my'] = 'other object';
trace('modified values');  //[trace] modified values
trace(t, t[1]['hello'], t[2]['my']);  //[trace] 4,5,6,[object Dictionary],[object Object] earth other object
trace(t2, t2[1]['hello'], t2[2]['my']);  //[trace] 1,2,3,[object Dictionary],[object Object] world object

function clone(source:*):* {
    var b:ByteArray = new ByteArray();
    b.writeObject(source);
    b.position = 0;
    return(b.readObject());
}

Dieser deckt das erste problem mit einem custom clone-Methode und ein Punkt weiter oben. Wie Sie sehen können, werden alle Objekte und deren Inhalte kopiert wurden, mithilfe der integrierten Methoden.

Habe ich gezeigt, dass eine Umsetzung, wie das erstellen der clone-Methode hier, aber Sie können finden, in: mx.utils.ObjectUtil.

Wenn Sie wollen, um Tiefe Kopie eines Objekts, speichert seine Daten privat, dann müssen Sie implementieren, die IExternalizable-Schnittstelle. Zwingen Sie zwei Methoden implementieren:

public function writeExternal(output:IDataOutput):void
public function readExternal(input:IDataInput):void

Innerhalb dieser Funktionen, die Sie schreiben, Ihre privaten Variablen, um die Ausgabe-Objekt, Lesen Sie Sie dann aus dem Eingang, um Ihre privaten Variablen. Dann, wenn Sie anrufen Klon erhalten Sie eine vollständige Kopie des Objekts. Denken Sie daran, dies zu tun für alle verschachtelten Objekte.

Hier ist eine einfache Implementierung-Beispiel mit zwei Klassen:

package {

    import flash.utils.IExternalizable;
    import flash.utils.IDataInput;
    import flash.utils.IDataOutput;
    import flash.net.registerClassAlias;

    public class Car implements IExternalizable {

    private var type:String;
        private var contents:Array;

        public function Car() {
            registerClassAlias("Car", Car);
        }

    public function setVars(type:String, contents:Array):void {
            this.type = type;
            this.contents = contents;
        }

    public function setType(type:String):void {
            this.type = type;
        }


        public function writeExternal(output:IDataOutput):void {
            output.writeUTF(type);
            output.writeObject(contents);
        }

    public function readExternal(input:IDataInput):void {
            type = input.readUTF();
            contents = input.readObject();
    }

        public function toString():String {
            return "[Car type = " + type + ", contents = " + contents + "]";
    }

    }

}

Und:

package {

    import flash.utils.IExternalizable;
    import flash.utils.IDataInput;
    import flash.utils.IDataOutput;
    import flash.net.registerClassAlias;

    public class Person implements IExternalizable {

    private var firstName:String;
        private var secondName:String;

        public function Person() {
            registerClassAlias("Person", Person);
        }

    public function setVars(firstName:String, secondName:String):void {
            this.firstName = firstName;
            this.secondName = secondName;
        }

        public function writeExternal(output:IDataOutput):void {
            output.writeUTF(firstName);
            output.writeUTF(secondName);
        }

    public function readExternal(input:IDataInput):void {
            firstName = input.readUTF();
            secondName = input.readUTF();
        }

        public function toString():String {
            return "[Person firstName = " + firstName + ", secondName = " + secondName + "]";
        }

    }

}

Testen Sie:

package {

    import flash.display.Sprite;
    import flash.utils.ByteArray;
    import flash.utils.Dictionary;

    public class Serial extends Sprite {

    public function Serial() {

            var person0:Person = new Person();
            person0.setVars("John", "Doe");
            var person1:Person = new Person();
            person1.setVars("Jane", "Doe");
            var car0:Car = new Car();
            car0.setVars("Ford", [person0, person1]);

            var person2:Person = new Person();
            person2.setVars("Joe", "Bloggs");
            var car1:Car = new Car();
            car1.setVars("Vauxhall", [person2]);

            var street:Array = [car0, car1];
            trace("street = " + street); //[trace] street = [Car type = Ford, contents = [Person firstName = John, secondName = Doe],[Person firstName = Jane, secondName = Doe]],[Car type = Vauxhall, contents = [Person firstName = Joe, secondName = Bloggs]]

            var street2:Array = clone(street);
            trace("street2 = " + street2); //[trace] street2 = [Car type = Ford, contents = [Person firstName = John, secondName = Doe],[Person firstName = Jane, secondName = Doe]],[Car type = Vauxhall, contents = [Person firstName = Joe, secondName = Bloggs]]

            person0.setVars("Max", "Headroom");
            person1.setVars("Simon", "Le Bon");
            car0.setType("Mini");

            person2.setVars("Harry", "Wotsit");
            car1.setType("Austin");

        trace("modified values of street"); //[trace] modified values of street
            trace("street = " + street); //[trace] street = [Car type = Mini, contents = [Person firstName = Max, secondName = Headroom],[Person firstName = Simon, secondName = Le Bon]],[Car type = Austin, contents = [Person firstName = Harry, secondName = Wotsit]]
            trace("street2 = " + street2); //[trace] street2 = [Car type = Ford, contents = [Person firstName = John, secondName = Doe],[Person firstName = Jane, secondName = Doe]],[Car type = Vauxhall, contents = [Person firstName = Joe, secondName = Bloggs]]

        }

        private function clone(source:*):* {
            var b:ByteArray = new ByteArray();
            b.writeObject(source);
            b.position = 0;
            return(b.readObject());
    }

    }

}

Dies umfasst das zweite problem mit einem custom clone-Methode. Wie Sie sehen können, wir hatten nicht zu sorgen über den Aufruf von jedem Klon-Methoden, das hat sich alles erledigt für uns.

Ich sage nicht, es ist nicht ganz ohne Nachteile, aber es bietet einige Funktionen, die zu Tiefe Objekte kopieren.

Einige Nachteile sind:

1. Sie können alle erforderlichen Parameter im Konstruktor.
2. Es nicht speichern von Referenzdaten, so dass, wenn zwei Objekte enthalten, die die gleiche Referenz haben, erhalten Sie zwei verschiedene Objekte zurück.
3. Wo die clone-Methode. Ich denke, es gehört wirklich auf das Objekt, auf das Vorbild vielleicht. Dies hätte den zusätzlichen Vorteil, dass jedes Objekt kopierbar, und wenn Sie möchten, können Sie genau festlegen, wie das Objekt wird kopiert.

Finden Sie unter Adobe ' s Sicht auf das kopieren von arrays: http://livedocs.adobe.com/flex/3/html/help.html?content=10_Lists_of_data_6.html

Beachten Sie auch, dass Adobe Stahlen diese Technik, die von Java.