Auswahl des letzten Wertes einer Spalte

Ich habe ein Tabellenblatt mit einigen Werten in Spalte G. Einige Zellen leer sind, in zwischen, und ich brauche, um den letzten Wert aus dieser Spalte in eine andere Zelle.

Etwas wie:

=LAST(G2:G9999)

außer dass LAST ist nicht eine Funktion.

InformationsquelleAutor der Frage cambraca | 2010-11-12

google-apps-script google-spreadsheet

47

Also diese Lösung nimmt einen string als parameter. Es findet, wie viele Zeilen in das Blatt. Es bekommt alle Werte in der angegebenen Spalte. Es durchläuft die Werte vom Ende zum Anfang, bis er findet, ein Wert, der nicht eine leere Zeichenfolge. Endlich ist es retunrs der Wert.

Skript:
```
function lastValue(column) {
  var lastRow = SpreadsheetApp.getActiveSheet().getMaxRows();
  var values = SpreadsheetApp.getActiveSheet().getRange(column + "1:" + column + lastRow).getValues();

  for (; values[lastRow - 1] == "" && lastRow > 0; lastRow--) {}
  return values[lastRow - 1];
}
```
Verwendung:
```
=lastValue("G")
```
EDIT:

Antwort auf den Kommentar Fragen nach der Funktion zur automatischen Aktualisierung ein:

Der beste Weg, die ich finden konnte, ist die Verwendung dieses mit dem obigen code:
```
function onEdit(event) {
  SpreadsheetApp.getActiveSheet().getRange("A1").setValue(lastValue("G"));
}
```
Wäre es nicht mehr erforderlich, um die Funktion in einer Zelle wie der Nutzung Abschnitt Staaten. Stattdessen sind Sie harte Codierung der Zelle, die Sie aktualisieren möchten, und die Spalte, die Sie möchten, zu verfolgen. Es ist möglich, dass es ein eloquenter Art und Weise der Umsetzung dieser (hoffentlich eine, die nicht hart codiert), aber diese ist die beste die ich finden konnte für jetzt.

Beachten Sie, dass wenn Sie die Funktion in der Zelle, wie bereits erwähnt, erfolgt die Aktualisierung auf neu laden. Vielleicht gibt es einen Weg, um Haken in onEdit() und Kraft in der Zelle, die Funktionen zu aktualisieren. Ich kann einfach nicht finden, es in der Dokumentation.

InformationsquelleAutor der Antwort tinifni
155

Ähnliche Antwort auf caligari Antwort, aber wir können ordentlich es nur durch Angabe des vollständigen Spalte Bereich:
```
=INDEX(G2:G, COUNT(G2:G))
```
InformationsquelleAutor der Antwort dohmoose
52

Tatsächlich fand ich eine einfachere Lösung hier:

http://www.google.com/support/forum/p/Google+Docs/thread?tid=20f1741a2e663bca&hl=de

Sieht es wie folgt aus:
```
=FILTER( A10:A100 , ROW(A10:A100) =MAX( FILTER( ArrayFormula(ROW(A10:A100)) , NOT(ISBLANK(A10:A100)))))
```
InformationsquelleAutor der Antwort Getas
40

LAST () - Funktion ist nicht implementiert im moment, um zu wählen Sie die Letzte Zelle in einem Bereich. Jedoch, nach Ihrer Beispiel:
```
=LAST(G2:G9999)
```
sind wir in der Lage, um die Letzte Zelle mit den paar Funktionen INDEX() und COUNT() in dieser Weise:
```
=INDEX(G2:G; COUNT(G2:G))
```
Es ist ein live-Beispiel am spreedsheet, wo ich Sie gefunden (und gelöst) das gleiche problem (Blatt Orzamentos Zelle I5). Beachten Sie, dass es perfekt funktioniert, auch auf anderen Blättern innerhalb des Dokuments.

InformationsquelleAutor der Antwort caligari
21

Zusammenfassung:
```
=INDEX( FILTER( G2:G , NOT(ISBLANK(G2:G))) , COUNTA(G2:G) )
```
Details:

Habe ich durchgeschaut und habe versucht, einige Antworten, und hier ist, was ich gefunden habe:
Die einfachste Lösung (siehe Dohmoose' Antwort) funktioniert, wenn es keine Leerzeichen:
```
=INDEX(G2:G; COUNT(G2:G))
```
Wenn Sie Leerzeichen, es schlägt fehl.

Können Sie behandeln eine leere, nur durch ein ändern von COUNT zu COUNTA (Siehe user3280071 Antwort):
```
=INDEX(G2:G; COUNTA(G2:G))
```
Jedoch, diese Fehler für einige Kombinationen von Rohlingen. (1 blank 1 blank 1 ausfällt für mich.)

Der folgende code funktioniert (Siehe Nader ' s Antwort und Jasons Kommentar):
```
=INDEX( FILTER( G2:G , NOT(ISBLANK(G2:G))) , ROWS( FILTER( G2:G , NOT(ISBLANK(G2:G)) ) ) )
```
aber es erfordert, darüber nachzudenken, ob Sie verwenden möchten COLUMNS oder ROWS für einen bestimmten Bereich.

Jedoch, wenn COLUMNS ersetzt mit COUNT ich scheinen, um eine zuverlässige, blank-Nachweis der Umsetzung von LAST:
```
=INDEX( FILTER( G2:G , NOT(ISBLANK(G2:G))) , COUNT( FILTER( G2:G , NOT(ISBLANK(G2:G)) ) ) ) 
```
Und da COUNTA hat der filter eingebaut ist, können wir vereinfachen weiter mit
```
=INDEX( FILTER( G2:G , NOT(ISBLANK(G2:G))) , COUNTA(G2:G) )
```
Dies ist etwas einfacher, und richtig. Und Sie müssen nicht sorgen zu machen, ob die Anzahl der Zeilen oder Spalten. Und im Gegensatz zu Skript-Lösungen, it-automatisch updates mit änderungen an der Tabelle.

Und wenn Sie wollen, um den letzten Wert in einer Zeile, ändern Sie einfach die Daten-Bereich:
```
=INDEX( FILTER( A2:2 , NOT(ISBLANK(A2:2))) , COUNTA(A2:2) )
```
InformationsquelleAutor der Antwort Doug Bradshaw
7

Um den letzten Wert aus einer Spalte der text-Werte müssen Sie mit COUNTA, so müssten Sie diese Formel:
```
=INDEX(G2:G; COUNTA(G2:G))
```
InformationsquelleAutor der Antwort user3280071

Sieht es aus wie Google Apps Script unterstützt jetzt reicht als Parameter der Funktion. Diese Lösung akzeptiert ein Angebot:

//Returns row number with the last non-blank value in a column, or the first row
//  number if all are blank.
//Example: =rowWithLastValue(a2:a, 2)
//Arguments
//  range: Spreadsheet range.
//  firstRow: Row number of first row. It would be nice to pull this out of
//    the range parameter, but the information is not available.
function rowWithLastValue(range, firstRow) {
  //range is passed as an array of values from the indicated spreadsheet cells.
  for (var i = range.length - 1;  i >= 0;  -- i) {
    if (range[i] != "")  return i + firstRow;
  }
  return firstRow;
}

Siehe auch die Diskussion in der Google Apps Script-Hilfe-forum: Wie kann ich die Kraft, die Formeln neu zu berechnen?

InformationsquelleAutor der Antwort craig3353

5

Sah ich mir die vorherigen Antworten, und Sie scheinen, wie Sie arbeiten zu hart. Vielleicht scripting-Unterstützung hat sich einfach verbessert. Ich denke, die Funktion ist so Ausdrücken:
```
function lastValue(myRange) {
    lastRow = myRange.length;
    for (; myRange[lastRow - 1] == "" && lastRow > 0; lastRow--)
    { /*nothing to do*/ }
    return myRange[lastRow - 1];
}
```
In meiner Tabelle, die ich dann verwenden:
```
= lastValue(E17:E999)
```
In der Funktion, ich bekomme ein array von Werten mit einer pro referenzierte Zelle, und das gerade iteriert wird vom Ende des Arrays nach hinten, bis es findet einen nicht-leeren Wert oder läuft out-of-Elemente. Blatt Referenzen interpretiert werden sollten, bevor die Daten an die Funktion übergeben. Nicht fancy genug, um multi-Dimensionen. Die Frage haben bitten für die Letzte Zelle in einer Spalte, so dass es zu passen scheint. Es wird wahrscheinlich sterben, wenn man die Daten auch.

Kann Ihre Laufleistung variieren, aber das funktioniert für mich.

InformationsquelleAutor der Antwort Ted H.
5

versuchen Sie dies:
=INDIRECT("B"&arrayformula(max((B3:B<>"")*row(B3:B))))

Nehme an, dass die Spalte in der Sie suchen, für den letzten Wert ist B.

Und ja, es funktioniert auch mit Leerzeichen.

InformationsquelleAutor der Antwort Andrew Anderson
4

In einer Spalte mit Leerzeichen, können Sie den letzten Wert mit
```
=+sort(G:G,row(G:G)*(G:G<>""),)
```
InformationsquelleAutor der Antwort JPV

Bekommt dieser den letzten Wert und Griffe leere Werte:

=INDEX(  FILTER( H:H ; NOT(ISBLANK(H:H))) ; ROWS( FILTER( H:H ; NOT(ISBLANK(H:H)) ) ) )

InformationsquelleAutor der Antwort Nader

function lastRow(column){
  var sheet = SpreadsheetApp.getActiveSpreadsheet();
  var lastRow = sheet.getLastRow();
  var lastRowRange=sheet.getRange(column+startRow);
  return lastRowRange.getValue();
}

ohne harte Codierung.

InformationsquelleAutor der Antwort desnyki

3

Dieser arbeitet für mich:
```
=INDEX(I:I;MAX((I:I<>"")*(ROW(I:I))))
```
InformationsquelleAutor der Antwort Pedro
2

Ist es akzeptabel, eine Antwort auf die ursprüngliche Frage mit streng off topic Antwort:)
Schreiben Sie eine Formel in das Arbeitsblatt, um dies zu tun. Hässlich vielleicht? aber effektiv in die normalen Betriebsbedingungen von einer Tabellenkalkulation.
```
=indirect("R"&ArrayFormula(max((G:G<>"")*row(G:G)))&"C"&7)


(G:G<>"") gives an array of true false values representing non-empty/empty cells
(G:G<>"")*row(G:G) gives an array of row numbers with zeros where cell is empty
max((G:G<>"")*row(G:G)) is the last non-empty cell in G
```
Dies ist als Gedanke für eine Reihe von Fragen, die im script-Bereich, der konnte zuverlässig geliefert mit array-Formeln, die haben den Vorteil, dass Sie Häufig in ähnliche fashion in excel und openoffice.

InformationsquelleAutor der Antwort DavidF

function getDashboardSheet(spreadsheet) {
  var sheetName = 'Name';
  return spreadsheet.getSheetByName(sheetName);
}
      var spreadsheet = SpreadsheetApp.openByUrl(SPREADSHEET_URL);  
      var dashboardSheet = getDashboardSheet(spreadsheet);
      Logger.log('see:'+dashboardSheet.getLastRow());

InformationsquelleAutor der Antwort Marian

2

Die Antwort
```
$ =INDEX(G2:G; COUNT(G2:G))
```
funktioniert nicht korrekt in LibreOffice. Allerdings mit einer kleinen änderung, es funktioniert perfekt.
```
$ =INDEX(G2:G100000; COUNT(G2:G100000))
```
Es funktioniert immer nur dann, wenn die true range ist kleiner als (G2:G10000)

InformationsquelleAutor der Antwort Manuel Ferreira

Spielte ich mit dem code von @tinfini, und dachte, die Leute nutzen könnten, was ich denke, das ist eine etwas elegantere Lösung (Hinweis: ich glaube nicht, dass Skripten gearbeitet, ganz auf die gleiche Weise, wenn er erstellt die original-Antwort)...

//Note that this function assumes a single column of values, it will 
//not  function properly if given a multi-dimensional array (if the 
//cells that are captured are not in a single row).

function LastInRange(values) 
{
  for (index = values.length - 1; values[index] == "" && index > 0; index--) {}
  return String(values[index]);
}

In der Nutzung würde es so Aussehen:

=LastInRange(D2:D)

InformationsquelleAutor der Antwort Jonathan Cavell

1

Bezüglich @Jon_Schneider Kommentar, wenn die Spalte leere Zellen verwenden Sie einfach COUNTA()
```
=INDEX(G2:G; COUNT**A**(G2:G))
```
InformationsquelleAutor der Antwort pedro
1

Ich bin überrascht, dass niemand jemals diese Antwort vor. Aber dies sollte der kürzeste und es funktioniert auch in excel :
```
=ARRAYFORMULA(LOOKUP(2,1/(G2:G<>""),G2:G))
```
G2:G<>"" erstellt ein array von 1/true(1) und 1/false(0). Da LOOKUP funktioniert ein top-down-Ansatz zu finden 2 und Da es nie finden sich 2,kommt es bis zur letzten nicht leeren Zeile und gibt die position, dass.

Den anderen Weg, dies zu tun, wie andere erwähnt haben, ist:
```
=INDEX(G2:G,MAX((ISBLANK(G2:G)-1)*-ROW(G2:G))-1)
```
Finden die MAXimum ROW des nicht-leere Zeile und Einspeisung zu INDEX

Einer null-leere Unterbrechung array, Mit INDIRECT RC notation mit COUNTBLANK ist eine weitere option. Wenn V4:V6 ist besetzt mit Einträgen, dann

V18:
```
=INDIRECT("R[-"&COUNTBLANK(V4:V17)+1&"]C",0)
```
geben die position der V6.

InformationsquelleAutor der Antwort I'-'I
1

Ich einen anderen Weg gefunden werden kann, wird es Ihnen helfen,

=INDEX( SORT( A5:D ; 1 ; FALSE) ; 1 ) -zurück Letzte Zeile

Mehr info von anab hier:
https://groups.google.com/forum/?fromgroups=#!Thema/How-to-Dokumente/if0_fGVINmI

InformationsquelleAutor der Antwort irriss

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.

Zusammenfassung:

Details: