Batch-Datei mehrzeiligen Befehl mit doppelten Anführungszeichen

Wenn mit dem ^ - symbol geben Sie eine mehrzeilige Befehle mit Argumenten bei der Verwendung von Anführungszeichen zu verwenden, Zeichenfolgen mit Leerzeichen, das ^ - symbol ist auch bestanden, kann das jemand erklären so ist?

arbeiten.cmd

@echo off 
call openfiles.cmd ^
C:\dir\filename.txt ^
C:\another_dir\another_file.txt

notworking.cmd

@echo off 
call openfiles.cmd ^
"C:\dir with spaces\file with spaces.txt" ^
"C:\another dir with spaces\another file with spaces.txt"

openfiles.cmd sieht aus wie

@echo off
for %%x in (%*) do (

    IF EXIST %%x (
        call "c:\Program Files\Notepad++\notepad++.exe" %%x
    ) ELSE (
        call echo Not found %%x
    )

)

pause

die Fehler, die ich bekomme so Aussehen wie

C:\>call openfiles.cmd "C:\dir with spaces\file with spaces.txt" ^
ELSE was unexpected at this time.

Denkt für den Versuch im obigen Beispiel habe ich extra Leerzeichen vor dem Anführungszeichen das original nicht, es scheint mein problem zu beheben
Es nicht, da die quotes escaped und daher sind die Räume aufgeteilt werden kann die Dateinamen in kleinere Teile
"Doppel" ist mein neues Lieblings-Wort.

InformationsquelleAutor Mazaka | 2015-11-16

7

Das problem ist, dass das Zitat am Anfang der zweiten Zeile wird entgangen durch die multi-line-caret.

Also das Letzte Zitat in der Zeile beginnt das zitieren statt zu stoppen, und so wird der Cursor in die zweite Zeile behandelt wird als normales Zeichen.
```
call openfiles.cmd ^"C:\dir with spaces\file with spaces.txt" ^
**This is a seperate line** "C:\another dir with spaces\another file with spaces.txt"
```
Caret-Regel:

Einem caret-Zeichen entgeht der nächste Charakter, so dass der Charakter verliert alle special effects.

Wenn das nächste Zeichen ein Zeilenvorschub diese fallen und nehmen das nächste Zeichen (auch wenn das auch ein Zeilenvorschub).

Mit dieser einfachen Regel können Sie die Dinge erklären, wie
```
echo #1 Cat^&Dog
echo #2 Cat^
&Dog
echo #3 Redirect to > Cat^
 Dog

setlocal EnableDelayedExpansion
set linefeed=^


echo #4 line1!linefeed!line2
```
#3 erstellt eine Datei namens "Katze Hund" als Raum entgangen war und nicht arbeiten als Trennzeichen mehr.

Aber es ist immer noch möglich, um diese Regel zu brechen!

Sie müssen nur eine Umleitung kurz vor dem caret-Zeichen, ist es immer noch Tropfen den Zeilenvorschub (multiline funktioniert immer noch), aber der nächste Charakter nicht entkommen mehr.
```
echo #5 Line1< nul ^
& echo Line2
```
So können Sie auch verwenden diese, um Ihre mehrzeiligen Befehl
```
call openfiles.cmd < nul ^
"C:\dir with spaces\file with spaces.txt" < nul ^
"C:\another dir with spaces\another file with spaces.txt"
```
Oder mit einem makro
```
set "\n=< nul ^"
call openfiles.cmd %\n%
"C:\dir with spaces\file with spaces.txt" %\n%
"C:\another dir with spaces\another file with spaces.txt"
```
InformationsquelleAutor jeb
3

Nach dem Versuch einige verschiedene Dinge, die ich geschafft, es funktioniert nur mit einem extra Raum direkt vor dem Anführungszeichen.
Änderungen notworking.cmd den folgenden arbeitete
```
@echo off 
call openfiles.cmd ^
 "C:\dir with spaces\file with spaces.txt" ^
 "C:\another dir with spaces\another file with spaces.txt"
```
beachten Sie die Leerzeichen vor dem Anführungszeichen
- notepad++ sagt, dass mein Zeilenenden sind CR-LF, wenn ich Ansicht->Symbole->alle zeigen Zeichen also noch nicht sicher, warum das Leerzeichen hat mir geholfen
- Oh, ja, kann ich reproduzieren. Die Sache ist die, ich habe noch nie daran gedacht, mit der continuation lines ohne Einrücken von Ihnen (in der Regel mit einem TAB)...
- Vielen Dank für dein feed back, es hat mein problem zu lösen.
- Das problem, das Sie gearbeitet haben, um mit dem space ist, dass die ^ nicht nur entgeht der newline sondern auch das erste Zeichen nach dem Zeilenumbruch und so Ihre erste " wurde als ein Zeichen interpretiert, anstatt zu zitieren und Ihr Angebot am Ende der zweiten Zeile zitiert die ^ Charakter, so dass es verliert seine Funktionalität. Durch ein Leerzeichen am Anfang der zweiten Zeile, die erste " auf der zweiten Zeile nicht entkommen mehr und der Befehl funktioniert wie erwartet. Weitere details in meiner Antwort.
InformationsquelleAutor Mazaka
2

kurz:

" Zeichen werden müssen ^-entkommen, ansonsten cmd wörtlich kopiert ^ Zeichen, die zwischen " Paare.

Warnung: ^ kopiert das Zeichen nach der Einfügemarke buchstäblich es verlieren alle Metazeichen Funktionalität, wenn es hatte. In einer multi-line-Szenario nicht nur die newline/linefeed kopiert wörtlich, aber auch das erste Zeichen in der neuen Linie ist auch entgangen

Erklärung:

Die ^ caret Metazeichen

Folgende definition kopiert wird sub-Abschnitt des Artikels die "Alle Zitate Befehl Linie Argumente der falsche Weg", die von Daniel Colascione am April 23, 2011

Eine bessere Methode zu zitieren,

Während der " Metazeichen nicht vollständig schützen Metazeichen in unserem
Befehlszeilen gegen unbeabsichtigtes shell-interpretation, die ^
Metazeichen können. Wenn cmd verwandelt eine Befehlszeile und sieht eine ^ ist, ignoriert das ^ - Zeichen selbst an und kopiert das nächste Zeichen in der neuen Kommandozeilen-buchstäblich, Metazeichen oder nicht.
Das ist, warum ^ arbeitet als Zeilenfortsetzungszeichen: es erzählt cmd zum kopieren einer nachfolgenden
newline als selbst statt, im Bezug auf das newline als Befehl
terminator. Wenn wir das Präfix mit ^ alle Metazeichen im argument
string, cmd transformiert die Zeichenfolge, in die wir bedeuten, zu verwenden.

nun für die wichtig relevanten Teil der vorgestellten problem:

Ist es wichtig, auch ^-Flucht " Zeichen: ansonsten, cmd würde buchstäblich kopieren ^ Zeichen, die zwischen " Paare, mangeln der argument-string in den Prozess.

Beachten Sie, dass wenn Sie ^", die " verliert seine Funktionalität, wie das zitieren, so seien Sie vorsichtig getroffen werden müssen.

Demo:

ohne ^-Flucht "
```
"c:\Program^
 Files\test.bat"
```
wird
```
"c:\Program^
Files\test.bat"
```
mit ^-Flucht "
```
^"c:\Program^
 Files\test.bat^"
```
wird
```
"c:\Program Files\test.bat"
```
und führt das Programm

Beachten Sie, dass ^-escaping der Anführungszeichen macht Sie verlieren Ihre zitieren-Funktionalität, so dass dieser Befehl könnte auch ausgeführt werden, wie: c:\Program^ Files\test.bat . Der Grund, warum wir normalerweise setzen Sie ihn in Anführungszeichen zu entfernen, die Abgrenzung der Funktion des Raumes Metazeichen, aber caret Flucht das Leerzeichen die gleiche Funktionalität bietet.

mit ^-Flucht ", aber der Platz verschoben zur vorherigen Zeile
```
^"c:\Program ^
Files\test.bat^"
```
wird
```
"c:\Program Files\test.bat"
```
aber der Befehlszeile Berichte 'c:\Program' wird nicht erkannt...

Dies ist denn mit dem Leerzeichen in der ersten Zeile und der "Charakter ^-entkommen, die <space> wird als Trennzeichen interpretiert und nicht als Zeichen.

Mit dem zweiten Beispiel der <space> ist das erste Zeichen in der Zeile nach einem ^ und ist dabei entkommen und interpretiert als Zeichen und nicht als Trennzeichen verwendet werden.

Quellen:
Microsoft-Blog-Artikel
- Aber das problem ist, das erste Zitat ist entgangen, deshalb bekam Sie Probleme mit etwas link echo bla ^<LF>"cat & dog"
- yup du hast Recht, es scheint, als ob ^ nicht nur kopiert wörtlich die <LF>, aber die " auf der neuen Linie aswell, so dass es Metazeichen verlieren Ihre Funktionalität zu zitieren. und dann die & interpretiert die Metazeichen anstelle von text. ^-auf der Flucht vor der & oder ein Leerzeichen am Anfang der neuen Zeile ist ein work-around, den ich gefunden habe.
- So, ich bin zu dem Schluss gekommen, das ich sage, das gleiche wie das angenommen Beantworter geschrieben, meine Antwort ist ein wenig redundant, dann obwohl es eine andere "Lösung" in bestimmten Fällen. Ich werde aktualisieren, meine Antwort zu warnen, auch dafür, vielen Dank für das feedback.
InformationsquelleAutor Pau Coma Ramirez

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.

Caret-Regel:

Die ^ caret Metazeichen

Eine bessere Methode zu zitieren,

Demo:

Die `^` caret Metazeichen