Batch-split eine text-Datei

Habe ich diese batch-Datei zu splitten, eine txt-Datei:

@echo off
for /f "tokens=1*delims=:" %%a in ('findstr /n "^" "PASSWORD.txt"') do for /f "delims=~" %%c in ("%%~b") do >"text%%a.txt" echo(%%c
pause

Es funktioniert, aber es spaltet es Zeile für Zeile. Wie kann ich sicherstellen, teilen Sie es alle 5000 Zeilen. Vielen Dank im Voraus.

Edit:

I have just tried this:

@echo off
setlocal ENABLEDELAYEDEXPANSION
REM Edit this value to change the name of the file that needs splitting. Include the extension.
SET BFN=passwordAll.txt
REM Edit this value to change the number of lines per file.
SET LPF=50000
REM Edit this value to change the name of each short file. It will be followed by a number indicating where it is in the list.
SET SFN=SplitFile

REM Do not change beyond this line.

SET SFX=%BFN:~-3%

SET /A LineNum=0
SET /A FileNum=1

For /F "delims==" %%l in (%BFN%) Do (
SET /A LineNum+=1

echo %%l >> %SFN%!FileNum!.%SFX%

if !LineNum! EQU !LPF! (
SET /A LineNum=0
SET /A FileNum+=1
)

)
endlocal
Pause
exit

Aber ich bekomme eine Fehlermeldung: Not enough storage is available to process this command

InformationsquelleAutor 09stephenb | 2014-05-11

Dies wird geben Sie a basic skeleton. Anzupassen, wie gebraucht

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "nLines=5000"
    set "line=0"

    for /f "usebackq delims=" %%a in ("passwords.txt") do (
        set /a "file=line/%nLines%", "line+=1"
        setlocal enabledelayedexpansion
        for %%b in (!file!) do (
            endlocal
            >>"passwords_%%b.txt" echo(%%a
        )
    )

    endlocal

BEARBEITET

Als Kommentare angegeben, eine 4,3 GB-Datei ist schwer zu verwalten. for /f laden muss die komplette Datei in den Speicher und der Puffer, die benötigt wird, ist die doppelte Größe wie die Datei in unicode konvertiert, in Erinnerung.

Dies ist eine ad-hoc-Lösung. Ich habe es nicht getestet über eine Datei hoch, aber zumindest in der Theorie sollte es funktionieren (es sei denn, 5000 Zeilen braucht eine Menge Speicher, es hängt von der Länge der Linie)

Ja, mit so einer Datei, es wird LANGSAM

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "line=0"
    set "tempFile=%temp%\passwords.tmp"

    findstr /n "^" passwords.txt > "%tempFile%"
    for /f %%a in ('type passwords.txt ^| find /c /v "" ') do set /a "nFiles=%%a/5000"

    for /l %%a in (0 1 %nFiles%) do (
        set /a "e1=%%a*5", "e2=e1+1", "e3=e2+1", "e4=e3+1", "e5=e4+1"
        setlocal enabledelayedexpansion
        if %%a equ 0 (
            set "e=/c:"[1-9]:" /c:"[1-9][0-9]:" /c:"[1-9][0-9][0-9]:" /c:"!e2![0-9][0-9][0-9]:" /c:"!e3![0-9][0-9][0-9]:" /c:"!e4![0-9][0-9][0-9]:" /c:"!e5![0-9][0-9][0-9]:" "
        ) else (
            set "e=/c:"!e1![0-9][0-9][0-9]:" /c:"!e2![0-9][0-9][0-9]:" /c:"!e3![0-9][0-9][0-9]:" /c:"!e4![0-9][0-9][0-9]:" /c:"!e5![0-9][0-9][0-9]:" "
        )
        for /f "delims=" %%e in ("!e!") do (
            endlocal & (for /f "tokens=1,* delims=:" %%b in ('findstr /r /b %%e "%tempFile%"') do @echo(%%c)>passwords_%%a.txt
        )
    )

    del "%tempFile%" >nul 2>nul

    endlocal

BEARBEITET, wieder: den Vorherigen code wird nicht korrekt funktionieren für Linien, beginnend mit einem Doppelpunkt, als es hat gewesen verwendet als Trennzeichen in der for Befehl separaten Zeile zahlen von Daten.

Für eine alternative, noch Reine batch, aber immer noch LANGSAM

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "nLines=5000"
    set "line=0"
    for /f %%a in ('type passwords.txt^|find /c /v ""') do set "fileLines=%%a"

    < "passwords.txt" (for /l %%a in (1 1 %fileLines%) do (
        set /p "data="
        set /a "file=line/%nLines%", "line+=1"
        setlocal enabledelayedexpansion
        >>"passwords_!file!.txt" echo(!data!
        endlocal
    ))

    endlocal

Vielen Dank ich habe es gerade ausprobiert und es sagt: Not enough storage is available to process this command
Wie groß ist deine Datei? Mehrere GB?
Sein 4,3 GB Größe.
Die for Befehl kann nicht Parsen einer Datei, die groß ist. Ich habe keine Referenz, aber es kann auch ein limit im Speicher, bin ich nicht sicher. Auf meinem 32 bit-system in der Vergangenheit fand ich eine Datei ungefähr 3 GB ausfallen würde. Eine Ebene für das script sehr langsam auf eine Datei in der Nähe, die Größe auch.
code aktualisiert, versuchen Sie es, wenn Sie Geduld haben genug 😉

InformationsquelleAutor MC ND

3

Test: die input-Datei ist "file.txt" - und output-Dateien sind "splitfile-5000.txt" zum Beispiel.

Diese wird eine helper-batch-Datei namens findrepl.bat - download von: https://www.dropbox.com/s/rfdldmcb6vwi9xc/findrepl.bat

Ort findrepl.bat im gleichen Ordner wie die batch-Datei oder auf dem Weg.
```
@echo off
:: splits file.txt into 5000 line chunks. 
set chunks=5000

set /a s=1-chunks
:loop
set /a s=s+chunks
set /a e=s+chunks-1
echo %s% to %e%
call findrepl /o:%s%:%e% <"file.txt" >"splitfile-%e%.txt"
for %%b in ("splitfile-%e%.txt") do (if %%~zb EQU 0 del "splitfile-%e%.txt" & goto :done)
goto :loop
:done
pause
```
Eine Einschränkung ist die Anzahl der Zeilen in der Datei und die echte größte Zahl ist 2^31 - 1 wo batch-Mathematik-tops aus.
- Vielen Dank, aber ich zu sein scheinen immer diese Fehlermeldung: CScript Error: Can't find script engine "JScript" for script "C:\Users\09stephenb\Desktop\batch\findrepl.bat".
- Welche Windows version verwenden Sie? Ist es gesperrt ES vielleicht?
- Windows-7-32bit.
- Ich änderte den code wegen einer langen Verzögerung und null-byte-Dateien - aber die jscript-Problem sein könnte, da Ihr Windows ist gesperrt in Ihrem Unternehmen.
InformationsquelleAutor foxidrive

@echo off
setlocal EnableDelayedExpansion

findstr /N "^" PASSWORD.txt > temp.txt
set part=0
call :splitFile < temp.txt
del temp.txt
goto :EOF

:splitFile
set /A part+=1
(for /L %%i in (1,1,5000) do (
   set "line="
   set /P line=
   if defined line echo(!line:*:=!
)) >  text%part%.txt
if defined line goto splitFile
exit /B

Wenn die input-Datei keine leeren Zeilen, Vorherige Methode kann modifiziert werden, um schneller zu laufen.

InformationsquelleAutor Aacini

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.