Beispiel für eine verzögerte Erweiterung in der Batch-Datei

Kann mir jemand ein Beispiel, wo ein batch-Skript würde anders handeln, mit oder ohne verzögerte Erweiterung? Gibt es irgendwelche Situationen, wo Sie NICHT verwenden möchten, verzögerte Erweiterung? Danke.

InformationsquelleAutor der Frage Neil Weicher | 2012-05-11

  1. 46

    Blick auf die folgenden Beispiele...

    Beispiel 1: Der folgende code NICHT verwendet, verzögert die expansion, also die Variablen in der for-Schleife erweitert werden, nur ein mal. Dies bedeutet, dass %Count% immer zu erweitern, um 0 in jeder iteration der Schleife, egal was wir tun, um es mit dem set-Befehl:

    @echo off
set COUNT=0

for %%v in (1 2 3 4) do (
  set /A COUNT=%COUNT% + 1
  echo Count = %COUNT%
)
pause

    So, in diesem Skript wird die Ausgabe:

    Count = 0
Count = 0
Count = 0
Count = 0

    Dies ist nicht, wie diese Schleife funktionieren soll.

    Beispiel 2: Auf der anderen Seite, wenn wir die verzögerte Erweiterung, haben wir das folgende Skript, welches ausgeführt wird, wie erwartet.

    setlocal ENABLEDELAYEDEXPANSION
set COUNT=0

for %%v in (1 2 3 4) do (
  set /A COUNT=!COUNT! + 1
  echo Count = !COUNT!
)

pause

    und, wie erwartet, wird es ausgegeben wird:

    Count = 1
Count = 2
Count = 3
Count = 4

    Wenn Sie die ENABLEDELAYEDEXPANSION, und erweitern Sie eine variable mit ! statt % ist, wird die variable wieder erweitert jedes mal, und alles funktioniert wie es soll.

    InformationsquelleAutor der Antwort Max

  2. 8

    Max ' Antwort gibt ein Beispiel, wo ein batch-Skript würde anders handeln, mit oder ohne verzögerte Erweiterung.

    Der Vollständigkeit halber, wir beantworten Sie den anderen Teil der Frage-und-show einer situation, wo Sie würden NICHT wollen, um zu verwenden, verzögerte Erweiterung, wenn Ihre Daten enthalten ein Ausrufezeichen ! (und zeigen zwei Möglichkeiten der Verarbeitung solcher Daten):

    @ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion

  set "_auxFile=%temp%\%~n0.txt"
  rem create multiline sample file
  >"%_auxFile%" ( for /L %%G in (1,1,3) do echo line %%G is 100%% valid! Sure! Hurrah!)
  rem create one-line sample file
  >"%_auxFile%" echo this line is 100%% valid! Sure! Hurrah!

  echo(
  echo --- file content 
  type "%_auxFile%"

  echo(
  SETLOCAL EnableDelayedExpansion
    echo --- enabled delayed expansion chokes down unescaped exclamation marks^^^! "^!"
    for /F "usebackq delims=" %%G in ("%_auxFile%") do (
      set "_auxLine=%%~G"
      echo loop var=%%~G
      echo _auxLine=!_auxLine!
    )
  ENDLOCAL
  echo(
  SETLOCAL DisableDelayedExpansion
    echo --- toggled delayed expansion works although might be laborious!
    for /F "usebackq delims=" %%G in ("%_auxFile%") do (
      set "_auxLine=%%G"
      echo loop var=%%G
      SETLOCAL EnableDelayedExpansion
        echo _auxLine=!_auxLine!
      ENDLOCAL
    )
  ENDLOCAL
  echo(
  SETLOCAL DisableDelayedExpansion
    echo --- keep delayed expansion DISABLED: use CALL command!
    for /F "usebackq delims=" %%G in ("%_auxFile%") do (
      set "_auxLine=%%G"
      echo loop var=%%G
      call :ProcessVar
    )
  ENDLOCAL

  rem delete the sample file
  del "%_auxFile%"
ENDLOCAL
goto :eof

:ProcessVar
  echo _auxLine=%_auxLine%
  echo WARNING: neither !_auxLine! nor %%G loop variable is available here!  
goto :eof

    Beachten Sie, dass obige Skript zeigt die richtigen Wege der Flucht

    • % Prozentzeichen durch %% verdoppeln (verzögerte Erweiterung spielt keine Rolle), und
    • ! Ausrufezeichen, wenn verzögerte Erweiterung aktiviert ist:
      • "^!" wenn eingeschlossen, in der ein paar doppelte Anführungszeichen enthält, dann verwenden Sie die cmd - und batch-Skript Allgemeinen escape-Zeichen ^ caret;
      • ^^^! verwenden Sie andernfalls drei ^ carets.

    Ausgabe:

    ==> D:\bat\SO\10558316.bat

--- file content
this line is 100% valid! Sure! Hurrah!

--- enabled delayed expansion chokes down unescaped exclamation marks! "!"
loop var=this line is 100% valid Hurrah
_auxLine=this line is 100% valid Hurrah

--- toggled delayed expansion works although might be laborious!
loop var=this line is 100% valid! Sure! Hurrah!
_auxLine=this line is 100% valid! Sure! Hurrah!

--- keep delayed expansion DISABLED: use CALL command!
loop var=this line is 100% valid! Sure! Hurrah!
_auxLine=this line is 100% valid! Sure! Hurrah!
WARNING: !_auxLine! as well as %G loop variables are not available here!

==>

    InformationsquelleAutor der Antwort JosefZ

  3. 7

    Wollte ich hinzufügen, dass ein großartiges Beispiel, wie "EnableDelayedExpansion" (EDE) kann hilfreich sein, außerhalb der allgegenwärtigen FOR-Schleife Beispiele.

    Hier ist eine Reihe von Erdbeben Daten, die ich Wünsche, zu analysieren (ich nenne es es 1line.txt)

    ak_11574812 2015.04.29.193822 62.9525 -148.8849 1.0 9.5 1 49 km S von Cantwell, Alaska

    Das problem, das ich gestoßen bin, war, dass im letzten segment dieser Linie nicht immer beginnen in der gleichen Spalte Anzahl. So ich brauchte, um zu schaffen ein flexibles SET-Befehl, der genau zu pflücken das Letzte segment dieser Linie.

    ECHO OFF
setlocal enableDelayedExpansion
set where=72
set /p line=<1line.txt
set locate=!line:~%where%,28!
echo %locate%

    EDE erlaubt mir, statt einer variable (wo) in eine andere variable (Zeile). EDE übersetzen Sie die variable in Klammern durch % die erste, dann die variable in Klammern!!! und (in diesem Fall) push-out der Ergebnisse in der "suchen" - variable.

    InformationsquelleAutor der Antwort Bruce Sinkula

Schreibe einen Kommentar