Bestimmen Sie, ob Benutzer Zeilen hinzufügen oder löschen

Könnte man einen Bereich definieren, Namen wie
RowMarker =$A$1000

Dann diesen code in Ihre change-Ereignis wird speichern Sie die position dieser Markierung gegen es die Vorherige position, und melden Sie jede änderung (dann speichert die neue position)

Private Sub Worksheet_Change(ByVal Target As Range)
    Static lngRow As Long
    Dim rng1 As Range
    Set rng1 = ThisWorkbook.Names("RowMarker").RefersToRange
    If lngRow = 0 Then
    lngRow = rng1.Row
        Exit Sub
    End If
    If rng1.Row = lngRow Then Exit Sub
    If rng1.Row < lngRow Then
        MsgBox lngRow - rng1.Row & " rows removed"
    Else
        MsgBox rng1.Row - lngRow & " rows added"
    End If
    lngRow = rng1.Row
End Sub

InformationsquelleAutor der Antwort brettdj

Annahme: "die Unterscheidung zwischen den beiden" Unterscheidung hinzufügen/löschen einer Zeile aus einer anderen Art von Veränderung. Wenn Sie bedeutete, wie Sie sagen, wenn die änderung war eine Zeile hinzufügen ODER Zeile löschen, dann Ignoriere meine Antwort unten.

Bei einfügen oder löschen einer Zeile, das Ziel.Zellen.Zählung werden alle Zellen in der Zeile. So können Sie diese If-Anweisung zu erfassen. Beachten Sie, dass ich die Verwendung von Zellen.Spalten.zählen, da könnte es anders sein für jede Datei. Es wird auch ausgelöst, wenn der Benutzer selektiert eine ganze Zeile und trifft die "delete" (zum löschen der Werte), so müssen Sie code ein workaround dafür, aber...

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

If Target.Cells.Count = Cells.Columns.Count Then
    MsgBox "Row added or deleted"
End If

End Sub

InformationsquelleAutor der Antwort aevanko

Einige von dem, was Ihre end-Zweck der Unterscheidung zwischen Einfüge-und Löschoperationen endet, wird bestimmen, wie Sie Vorgehen möchten einmal eine insertion oder deletion identifiziert worden. Die folgenden können, ist wohl der Schnitt deutlich gesunken ist, aber ich habe versucht, jeden möglichen Szenario.

Private Sub Worksheet_Change(ByVal Target As Range)

    On Error GoTo bm_Safe_Exit
    Application.EnableEvents = False
    Application.ScreenUpdating = False
    Dim olr As Long, nlr As Long, olc As Long, nlc As Long

    With Target.Parent.Cells
        nlc = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
        nlr = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Application.Undo    'undo the last change event
        olc = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
        olr = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Application.Repeat  'redo the last change event
    End With

    If nlr <> olr Or nlc <> olc Then
        Select Case nlr
            Case olr - 1
                Debug.Print "One (1) row has been deleted"
            Case Is < (olr - 1)
                Debug.Print (olr - nlr) & " rows have been deleted"
            Case olr + 1
                Debug.Print "One (1) row has been inserted"
            Case Is > (olr + 1)
                Debug.Print (nlr - olr) & " rows have been inserted"
            Case olr
                Debug.Print "No rows have been deleted or inserted"
            Case Else
                'don't know what else could happen
        End Select
        Select Case nlc
            Case olc - 1
                Debug.Print "One (1) column has been deleted"
            Case Is < (olc - 1)
                Debug.Print (olc - nlc) & " columns have been deleted"
            Case olc + 1
                Debug.Print "One (1) column has been inserted"
            Case Is > (olc + 1)
                Debug.Print (nlc - olc) & " columns have been inserted"
            Case olc
                Debug.Print "No columns have been deleted or inserted"
            Case Else
                'don't know what else could happen
        End Select
    Else
        'deal with standard Intersect(Target, Range) events here
    End If

bm_Safe_Exit:
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Im wesentlichen, dieser code ermittelt die Letzte Zelle der Spalte-wise und die Letzte Zelle Zelle-Zeile-Weise. Es dann rückgängig macht den letzten Vorgang und prüft wieder. Vergleich beider Ergebnisse ermöglicht es zu ermitteln, ob eine Zeile/Spalte wurde eingefügt/gelöscht werden. Sobald die vier Messungen wurden ergriffen, es wiederholt den letzten Vorgang, so dass alle anderen mehr standard Worksheet_Change-Operationen verarbeitet werden können.

InformationsquelleAutor der Antwort Jeeped

Capture-Reihe von Ergänzungen und Löschungen in das worksheet_change-Ereignis.

Ich erstellen Sie eine named range namens "CurRowCnt"; Formel: =ZEILEN(Tabelle1).
Access im VBA-code mit:

CurRowCnt = Evaluate(Application.Names("CurRowCnt").RefersTo)

Dieser benannte Bereich wird immer die Anzahl der Zeilen 'nach' eine Zeile(N) einfügen oder löschen. Ich finde, es gibt eine stabilere CurRowCnt als die Verwendung einer global-oder Modul-Ebene-variable, besser für Programmierung, testen und Debuggen.

Speichere ich die CurRowCnt, um eine benutzerdefinierte Dokument-Eigenschaft, wieder für Stabilität Zwecke.

ThisWorkbook.CustomDocumentProperties("RowCnt").Value = Evaluate(Application.Names("CurRowCnt").RefersTo)

Meine Worksheet_Change Event-Struktur ist wie folgt:

Dim CurRowCnt as Double
CurRowCnt = Evaluate(Application.Names("CurRowCnt").RefersTo)
Select Case CurRowCnt

    '' ########## ROW(S) ADDED
     Case Is > ThisWorkbook.CustomDocumentProperties("RowCnt").Value
         Dim r As Range
         Dim NewRow as Range

         ThisWorkbook.CustomDocumentProperties("RowCnt").Value = _
         Evaluate(Application.Names("CurRowCnt").RefersTo)

         For Each r In Selection.Rows.EntireRow
             Set NewRow = Intersect(Application.Range("Table1"), r)
             'Process new row(s) here
         next r

    '' ########## ROW(S) DELETED
     Case Is < ThisWorkbook.CustomDocumentProperties("RowCnt").Value

         ThisWorkbook.CustomDocumentProperties("RowCnt").Value = _
         Evaluate(Application.Names("CurRowCnt").RefersTo)

         'Process here

    '' ########## CELL CHANGE
    'Case Is = RowCnt

        'Process here

    '' ########## PROCESSING ERROR
    Case Else 'Should happen only on error with CurRowCnt or RowCnt
        'Error msg here

End Select

InformationsquelleAutor der Antwort phillfri