Clojure Gebäude der URL Bestandteile

In Python würde ich das folgende tun:

>>> q = urllib.urlencode({"q": "clojure url"})
>>> q
'q=clojure+url'

>>> url = "http://stackoverflow.com/search?" + q
>>> url
'http://stackoverflow.com/search?q=clojure+url'

Wie mache ich alle die Codierung, die für mich getan oben in Clojure? In anderen Worten, wie mache ich so etwas wie die folgenden:

=> (build-url "http://stackoverflow.com/search" {"q" "clojure url"})
"http://stackoverflow.com/search?q=clojure+url"
InformationsquelleAutor qrest | 2010-09-04
  1. 12

    Hier ist eine Möglichkeit:

    user=> (import [java.net URLEncoder])                                                      
java.net.URLEncoder
user=> (str "http://stackoverflow.com/search?q=" (URLEncoder/encode "clojure url" "UTF-8"))
"http://stackoverflow.com/search?q=clojure+url"

    Ich weiß, das ist nicht genau das gleiche wie Ihre Python-snippet, obwohl. Bitte sehen Sie sich den folgenden Beitrag aus der Clojure-mailing-Liste für eine vollständige Antwort:

    http://www.mail-archive.com/[email protected]/msg29338.html

    Den code von dort wird Ihnen erlauben, dies zu tun:

    user=> (encode-params {"q" "clojure url"})
"q=clojure+url"
    • Zu bemerken Bearbeiten, ich denke, ich sollte nicht die Mühe gemacht, das schreiben alle, dass... naja. +1 für die erste Antwort. Ich mag mein Named-handling-version, so dass ich verlassen bin, dass hier. 🙂
    InformationsquelleAutor Michael Kohl
  2. 19

    Es ist ein url-encode - Funktion in der Ring-s ring.util.codec namespace:

    (ring.util.codec/url-encode "clojure url")
; => "clojure+url"

    Ich bin mir nicht sicher ob es eine vorgefertigte Funktion ein, um eine Karte in einen query-string, aber vielleicht könnte dies der job:

    (use '[ring.util.codec :only [url-encode]])

(defn make-query-string [m]
  (->> (for [[k v] m]
         (str (url-encode k) "=" (url-encode v)))
       (interpose "&")
       (apply str)))

    Beispiel:

    user> (make-query-string {"q" "clojure url" "foo" "bar"})
"q=clojure+url&foo=bar"

    Alles, was bleibt, ist die Verkettung das Ergebnis wird an das Ende der URL:

    (defn build-url [url-base query-map]
  (str url-base "?" (make-query-string query-map)))

    Scheint zu funktionieren:

    user> (build-url "http://stackoverflow.com/search" {"q" "clojure url"})
"http://stackoverflow.com/search?q=clojure+url"

    Update:

    Vielleicht eine modifizierte version machen könnte, für eine Clojure-freundliche Erfahrung. Behandelt auch die Codierung über ein Ring-Stil optionales argument mit utf-8 als Standard.

    (defn make-query-string [m & [encoding]]
  (let [s #(if (instance? clojure.lang.Named %) (name %) %)
        enc (or encoding "UTF-8")]
    (->> (for [[k v] m]
           (str (url-encode (s k) enc)
                "="
                (url-encode (str v) enc)))
         (interpose "&")
         (apply str))))

(defn build-url [url-base query-map & [encoding]]
  (str url-base "?" (make-query-string query-map encoding)))

    So, jetzt können wir tun

    user> (build-url "http://example.com/q" {:foo 1})
"http://example.com/q?foo=1"
    • Ah, fast vergessen: ring.util.codec nimmt auch einen optionalen encoding argument, säumige UTF-8.
    InformationsquelleAutor Michał Marczyk
  3. 11

    Dies ist der genaue REPL äquivalent zu Ihrem python-session, mit clj-http.

    user=> (require ['clj-http.client :as 'client])
nil
user=> (str "http://stackoverflow.com/search?"
user=*      (client/generate-query-string {"q" "clojure url"}))
"http://stackoverflow.com/search?q=clojure+url"

    aber clj-http macht es noch einfacher:

    user=> (client/get "http://stackoverflow.com/search?"
user=*             {:query-params {"q" "clojure url"}})
... <a lot of output, omitted to protect the innocent>...

    unter der Annahme, dass Sie möchten, führen Sie eine GET-Anforderung ist.

    InformationsquelleAutor 0x89
  4. 2

    clj-apache-http ist ziemlich nützlich. Mit es können Sie Folgendes tun:

    user=> (require ['com.twinql.clojure.http :as 'http])
nil
user=> (def q (http/encode-query {"q" "clojure url"}))
#'user/q
user=> (def url (str "http://stackoverflow.com/search?" q))
#'user/url
user=> url
"http://stackoverflow.com/search?q=clojure+url"
    InformationsquelleAutor dnolen
  5. 0

    Eine einfache Lösung mit str(ings):

    (def q (str "clojure+url"))
(def url (str "http://stackoverflow.com/search?" q))
    • Auch Sie geben + als eine Eingabe, so dass Sie nicht wirklich lassen Clojure Kodieren Sie die Zeichenfolge für Sie.
    InformationsquelleAutor bruce
Schreibe einen Kommentar