custom sort-Methode in Delphi zur Liste Sortieren von strings

Ich versuche zu Sortieren, eine Liste der Dateien (Sie gespeichert sind, als Liste von strings) in Delphi, deren Namen wie folgt Aussehen

a_1.xml
a_20.xml
a_10.xml
a_2.XML

wenn ich schnelle Art zu sort den Datei-Namen, sortiert das System die Datei-Namen wie unten

a_1.xml
a_10.xml
a_2.xml
a_20.XML

Aber, ich möchte die Dateinamen werden sortiert in der unten Mode

a_1.xml
a_2.xml
a_10.xml
a_20.XML

Jede Hilfe wird sehr geschätzt.

InformationsquelleAutor rookie_developer | 2013-03-06

19

Können Sie die gleichen compare-Funktion, die Explorer verwendet, nämlich StrCmpLogicalW.
```
function StrCmpLogicalW(psz1, psz2: PWideChar): Integer; stdcall;
  external 'shlwapi.dll';

function StrCmpLogical(const s1, s2: string): Integer;
begin
  Result := StrCmpLogicalW(PChar(s1), PChar(s2));
end;
```
Wenn Sie Ihre Saiten in einem TStringList - Instanz können Sie die CustomSort Methode. Diese erwartet eine compare-Funktion von dieser form:
```
TStringListSortCompare = function(List: TStringList; 
  Index1, Index2: Integer): Integer;
```
So, feed CustomSort diese Funktion:
```
function StringListCompareLogical(List: TStringList; 
  Index1, Index2: Integer): Integer;
begin
  Result := StrCmpLogical(List[Index1], List[Index2]);
end;
```
- es könnte ein seltener Fall, wo die 'shlwapi.dll' manipuliert wurde oder fehlt. Dann funktioniert die Anwendung nicht.
- Wenn shlwapi.dll fehlt, wird der Benutzer wahrscheinlich nicht starten Sie Ihr Programm trotzdem. Es ist ein wichtiger Bestandteil der Windows-shell, und StrCmpLogicalW wurde Hinzugefügt, mit Windows XP. Die wichtigsten Vorsicht ist, dass sein Verhalten ändern KANN (MSDN: Beachten Sie das Verhalten dieser Funktion, und daher die Ergebnisse, die es gibt, können von Version zu Version ändern. Es sollte nicht verwendet werden, für die kanonische Sortierung der Anwendungen.)
- Ich verstehe, dass die 'shlwapi.dll' DLL enthält Funktionen für UNC-und URL-Pfade, registry-Einträge und Farbeinstellungen .. warum manipulieren Sie diese Datei auf application starten ?
- Angenommen ich würde windows explorer haben Probleme bei der Ausführung ohne es, es sei denn, jemand in MS dachte, es war ein großes Bedürfnis zu laufen, explorer, ohne eine Datei, die enthalten war in Win95
- Manipulation ist nicht ein Problem. Alle Programme, die Sie schreiben, verlassen Sie sich auf system-Bibliotheken.
- Verdammt! Ich bin erstaunt, wie viele Prozeduren und Funktionen Delphi hat einen Tag!!
- wo bekomme ich die exceptions, die ausgelöst werden durch StrCmpLogicalW() Funktion ??
- Es erhöht nicht den Ausnahmen. Ist es nicht ein Fehler zurückgegeben. Es wird nicht fehlschlagen, wenn Sie die Regeln zu befolgen und es zu versorgen, null-terminierte " strings.
- Hi. Ich couldnot damit es funktioniert. Es gibt Inkompatible Typen: 'Char' und 'WideChar' - Fehler. Auch ich Verstand nicht, wie sich zu ernähren CustomSort. Welche Art sollte ich für index1 und index2. Können Sie bitte ein Beispiel? BTW ich verwende delphi7 und windows7
- Sie sind mit einem pre-Unicode-Delphi, also der Typ stimmt nicht überein. Konvertieren von Zeichenfolgen zu WideString, und dann gegossen, um PWideChar. So, StrCmpLogicalW(PWideChar(WideString(s1)), PWideChar(WideString(s2)); dann rufen Sie StringList.CustomSort(StringListCompareLogical)
- ok, es funktionierte jetzt. vielen Dank für deine Antwort.
- ja es funktioniert jetzt. nochmals vielen Dank.
InformationsquelleAutor David Heffernan

Eine leichte Lösung, angepasst an Ihre genaue situation ist wie folgt:

function compare(List: TStringList; Index1, Index2: Integer): Integer;
var
  n1, n2: integer;
begin
  n1 := StrToInt(Copy(List[Index1], 3, Length(List[Index1]) - 6));
  n2 := StrToInt(Copy(List[Index2], 3, Length(List[Index2]) - 6));
  result := n1 - n2;
end;

var
  sl: TStringList;

procedure AddAndSort;
begin
  sl := TStringList.Create;
  sl.Add('a_1.xml');
  sl.Add('a_20.xml');
  sl.Add('a_10.xml');
  sl.Add('a_2.XML');
  sl.CustomSort(compare);
end;

Dies funktioniert, wenn ich bereits wissen, den Namen der Datei und, wenn die Länge der Zeichen, die als zahlen sind immer konstant.
Natürlich. Aus Ihrer Q-ich habe den Eindruck, dass das der Fall war.

InformationsquelleAutor Andreas Rejbrand

Die Antwort von Andreas Rejbrand war ok. Aber besser, Sie verwenden meine compare-Funktion für die Allgemeine Verwendung:

function compare(List: TStringList; Index1, Index2: Integer): Integer;
begin
  if Length(List[Index1]) = Length(List[Index2]) then
    begin
      if List[Index1] = List[Index2] then
        result := 0
      else
        if List[Index1] < List[Index2] then
          result := -1
        else
          result := 1;
    end
  else
    if Length(List[Index1]) < Length(List[Index2]) then
      result := -1
    else
      result := 1;
end;

//------------------------------------------------------------------

var sl: TStringList;

procedure AddAndSort;
begin
  sl := TStringList.Create;
  sl.Add('a_1.xml');
  sl.Add('a_20.xml');
  sl.Add('a_10.xml');
  sl.Add('a_2.XML');
  sl.CustomSort(compare);
end;

Ich denke, das wird Art falsch - kürzere Zeichenfolgen werden immer vor den längeren.

InformationsquelleAutor Ingo

Als ich dies schrieb einer vor ein paar Jahren als Antwort hier. Es ist ein bisschen langwierig, aber es funktioniert der trick.

function GTSmartCompare(List: TStringList; Index1, Index2: Integer): Integer;

  procedure ExtractPart(var s: string; out Result: string; out Numbers: Boolean);
  var
    n: integer;
  begin
    Numbers := False;
    n := 1;
    while (s[n] in ['0'..'9']) and (n <= Length(s)) do
      Inc(n);

    { n > 1 if there were digits at the start of the string}
    if n > 1 then
    begin
      Result := Copy(s, 1, n - 1);
      Delete(s, 1, n - 1);
      Numbers := True;
    end
    else
    begin
      { No digits }
      n := 1;
      while (not (s[n] in ['0'..'9']) ) and (n <= Length(s)) do
        Inc(n);

      if n > 1 then
      begin
        Result := Copy(s, 1, n - 1);
        Delete(s, 1, n - 1);
      end
    end;
  end; //ExtractPart()


  function CompareNextPart(var s1, s2: string): Integer;
  var
    n1, n2: Boolean;
    p1, p2: string;
  begin
    { Extract the next part for comparison }
    ExtractPart(s1, p1, n1);
    ExtractPart(s2, p2, n2);

    { Both numbers? The do a numerical comparison, otherwise alfabetical }
    if n1 and n2 then
      Result := StrToInt(p1) - StrToInt(p2)
    else
      Result := StrIComp(PChar(p1), PChar(p2));
  end; //CompareNextPart()

var
  str1, str2, ext1, ext2: string;

begin
  Result := 0;
  { For 'normal' comparison
    str2 := List[Index1];
    str2 := List[Index2];
    For comparing file names }

  ext1 := ExtractFileExt(List[Index1]);
  ext2 := ExtractFileExt(List[Index2]);
  str1 := ChangeFileExt(List[Index1], '');
  str2 := ChangeFileExt(List[Index2], '');

  while (str1 <> '') and (str2 <> '') and (Result = 0) do
    Result := CompareNextPart(str1, str2);

  { Comparing found no numerical differences, so repeat with a 'normal' compare. }

  if Result = 0 then
    Result := StrIComp(PChar(List[Index1]), PChar(List[Index2]));

  { Still no differences? Compare file extensions. }

  if Result = 0 then
    Result := StrIComp(PChar(ext1), PChar(ext2));

end;

[Bearbeiten]

Aber warum die Mühe, wenn David wach ist. :p zu meiner Verteidigung, damals viele Leute nicht haben, Windows XP, das ist die version, in der StrCmpLogicalW eingeführt wurde.

Dies ist fair genug, wenn Sie nicht über XP. Aber in diesem Fall würde ich erwägen, die Umsetzung der StrCmpLogicalW aus Wein!! Ich erwarte, dass die Umsetzung alle Nuancen des echten Windows-version.
Sicher. Dies ist die eigentliche alte code. Ich wüsste nicht, warum würden Sie unterstützen pre-XP-Versionen überhaupt. Auch bin ich mir nicht sicher, ob dieser code ist unicode sicher. Ich lass es einfach hier, um einige Punkte sammeln -er - für pädagogische Zwecke, aber mit StrCmpLogicalW mehr Sinn macht.

InformationsquelleAutor GolezTrol

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.