Das finden der Differenz zwischen 2 Daten in xslt

Ist es einer weniger als kludgey Weg zu finden, der die Differenz in Tagen zwischen 2 Daten in xslt? Wenn ja, können Sie zeigen mich in die richtige Richtung. Ich erhalte ein Datum im format mm/dd/yyyy.

  • Sind Sie stecken mit XSLT 1 oder Sie verwenden können, XSLT2?
  • In XSLT 1.0 Sie haben EXSLT date:difference umgesetzt von Jeni Tennison in exslt.org/date/functions/difference/...
  • Ich würde empfehlen die Verwendung von XSLT 2.0/XPath 2.0 für diese.
InformationsquelleAutor Mike T | 2011-04-04
  1. 4

    XSLT 2.0 XPath (2.0) für diese:

    <xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="my:my">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:variable name="vDate1"
        select="my:dateFromUsDate(/*/d1)"/>
     <xsl:variable name="vDate2"
        select="my:dateFromUsDate(/*/d2)"/>

   <xsl:sequence select=
   "($vDate1 - $vDate2) div xs:dayTimeDuration('P1D')"/>
 </xsl:template>

 <xsl:function name="my:dateFromUsDate" as="xs:date">
  <xsl:param name="pUsDate" as="xs:string"/>

  <xsl:sequence select=
  "xs:date(concat(substring($pUsDate,7,4),
                  '-',
                  substring($pUsDate,1,2),
                  '-',
                  substring($pUsDate,4,2)
                 )
          )
  "/>
 </xsl:function>
</xsl:stylesheet>

    wenn diese transformation angewendet wird, auf das folgende XML-Dokument:

    <t>
 <d1>04/06/2011</d1>
 <d2>01/11/2010</d2>
</t>

    die wollten, das richtige Ergebnis (der Unterschied beträgt 450 Tage) produziert wird:

    450
    InformationsquelleAutor Dimitre Novatchev
  2. 7

    Ein schöner (und kürzere) alternative für XSLT 1.0 ist die Berechnung der äquivalenten Julian Termine und subtrahieren Sie.

    Vorlage:

    <xsl:template name="calculate-julian-day">
    <xsl:param name="year"/>
    <xsl:param name="month"/>
    <xsl:param name="day"/>

    <xsl:variable name="a" select="floor((14 - $month) div 12)"/>
    <xsl:variable name="y" select="$year + 4800 - $a"/>
    <xsl:variable name="m" select="$month + 12 * $a - 3"/>

    <xsl:value-of select="$day + floor((153 * $m + 2) div 5) + $y * 365 + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045"/>

    Verwendung:

    <xsl:variable name="dateInv" select="'20120406'" />
<xsl:call-template name="calculate-julian-day">
    <xsl:with-param name="year" select="substring($date,1,4)"/>
    <xsl:with-param name="month" select="substring($date,5,2)"/>
    <xsl:with-param name="day" select="substring($date,7,2)"/>
</xsl:call-template>

    Wiederholen Sie für das zweite date und erhalten Sie zwei Ganzzahlen. Dann einfach subtrahieren Sie.

    InformationsquelleAutor Buffalo
  3. 6

    Könnte dies leicht getan werden mit dem folgenden Ausdruck:

    days-from-duration(xs:date('yyyy-MM-dd')-xs:date('yyyy-MM-dd'))

    Beispiel:

    days-from-duration(xs:date('2012-06-30')-xs:date('2012-06-18'))

    geben Ergebnis 12

    InformationsquelleAutor Abdelhameed Mahmoud
Schreibe einen Kommentar