Delphi - gibt es irgendein äquivalent zu C# lock?

(Un -) glücklicherweise sind Sie nicht sperren kann auf beliebige Objekte in Delphi 6 (obwohl Sie kann in den neueren Versionen 2009 und höher), so dass Sie brauchen, um einen separaten lock-Objekt, in der Regel ein Kritischer Abschnitt.

TCriticalSection (Hinweis: die Dokumentation ist von FreePascal, aber es gibt es in Delphi auch):

Beispiel-code:

type
  TSomeClass = class
  private
    FLock : TCriticalSection;
  public
    constructor Create();
    destructor Destroy; override;

    procedure SomeMethod;
  end;

constructor TSomeClass.Create;
begin
  FLock := TCriticalSection.Create;
end;

destructor TSomeClass.Destroy;
begin
  FreeAndNil(FLock);
end;

procedure TSomeClass.SomeMethod;
begin
  FLock.Acquire;
  try
    //...do something with mySharedObj
  finally
    FLock.Release;
  end;
end;

Zwar nicht ganz so einfach wie c#, Folgendes könnte für Sie arbeiten.

  with Lock(mySharedObj) do
  begin
    //...do something with mySharedObj
    UnLock;
  end;

In einer nussschale

• eine list gehalten, für jeden Instanz Sie schützen möchten.
• wenn eine zweite thread-cals der Lock(mySharedObj), der internen Liste gesucht wird eine vorhandene Sperre. Ein neues Schloss wird angelegt, wenn keine vorhandene Sperre zu finden ist. Der neue thread wird gesperrt, wenn in einem anderen thread hat immer noch die Sperre.
• die Unlock ist notwendig, weil wir nicht sicher sein können, dass der Verweis auf die ILock-Instanz wird aus dem Geltungsbereich am Ende der Methode aufrufen Lock. (Wenn wir könnten, die Unlock entfernt werden konnte).

Beachten Sie, dass in diesem design, eine TLock angelegt wird, für jede Objekt-Instanz, die Sie schützen möchten, ohne dass es freigegeben, bis die Anwendung beendet wird.

Dies konnte berücksichtigt werden, aber es würde bedeuten, Herumspielen mit _AddRef & _Release.

unit uLock;

interface

type
  ILock = interface
    ['{55C05EA7-D22E-49CF-A337-9F989006D630}']
    procedure UnLock;
  end;

function Lock(const ASharedObj: TObject): ILock;

implementation

uses
  syncobjs, classes;

type
  _ILock = interface
    ['{BAC7CDD2-0660-4375-B673-ECFA2BA0B888}']
    function SharedObj: TObject;
    procedure Lock;
  end;

  TLock = class(TInterfacedObject, ILock, _ILock)
  private
    FCriticalSection: TCriticalSection;
    FSharedObj: TObject;
    function SharedObj: TObject;
  public
    constructor Create(const ASharedObj: TObject);
    destructor Destroy; override;
    procedure Lock;
    procedure UnLock;
  end;

var
  Locks: IInterfaceList;
  InternalLock: TCriticalSection;

function Lock(const ASharedObj: TObject): ILock;
var
  I: Integer;
begin
  InternalLock.Acquire;
  try
    //***** Does a lock exists for given Shared object
    for I := 0 to Pred(Locks.Count) do
      if (Locks[I] as _ILock).SharedObj = ASharedObj then
      begin
        Result := ILock(Locks[I]);
        Break;
      end;

    //***** Create and add a new lock for the shared object
    if not Assigned(Result) then
    begin
      Result := TLock.Create(ASharedObj);
      Locks.Add(Result);
    end;
  finally
    InternalLock.Release;
  end;
  (Result as _ILock).Lock;
end;

{ TLock }

constructor TLock.Create(const ASharedObj: TObject);
begin
  inherited Create;
  FSharedObj := ASharedObj;
  FCriticalSection := TCriticalSection.Create;
end;

destructor TLock.Destroy;
begin
  FCriticalSection.Free;
  inherited Destroy;
end;

procedure TLock.Lock;
begin
  FCriticalSection.Acquire;
end;

function TLock.SharedObj: TObject;
begin
  Result := FSharedObj;
end;

procedure TLock.UnLock;
begin
  FCriticalSection.Release;
end;

initialization
  Locks := TInterfaceList.Create;
  InternalLock := TCriticalSection.Create;

finalization
  InternalLock.Free;
  Locks := nil

end.

Mit Klasse Helfern können Sie diese verwenden. Funktioniert nicht mit älteren Versionen, wenn. Aber ich würde raten, mit TMonitor nur in XE5. Da es oft viel langsamer als TRTLCriticalSection.

http://www.delphitools.info/2013/06/06/tmonitor-vs-trtlcriticalsection/

THelper = class helper for TObject
  procedure Lock;
  procedure Unlock;
end;

procedure THelper.Lock;
begin
  System.TMonitor.Enter(TObject(Self));
end;

procedure THelper.Unlock;
begin
  System.TMonitor.Exit(TObject(Self));
end;