die Anzahl der vorkommen eines Strings in XML mit Hilfe von XSLT

Möchte ich calcutae die Anzahl von vorkommen einer Zeichenfolge in einem bestimmten Knoten im XML-Dokument mithilfe von XSLT.
Betrachten Sie dieses Beispiel

 <mainNode>
<book>
    <price> 100 </price>
    <city> chennai </city>
    <list>
        <language> c java ruby </language>
    </list>
</book>

<book>
    <price> 200 </price>
    <city> banglore </city>
    <list>
        <language> c java </language>
    </list>
</book>

<book>
    <price> 300 </price>
    <city> delhi </city>
    <list>
        <language> java ruby </language>
    </list>
</book>
</mainNode>

Hier möchte ich zum zählen der vorkommen von "java"

Möchte ich eine Ausgabe wie diese:: java -- 3

Wie mache ich das??? keine Ahnung???

Gute Frage, +1. Siehe meine Antwort für eine komplette, kurze und einfache one-liner XPath-Ausdruck Lösung. 🙂
Kleiner Punkt, aber XML ist irgendwie schlecht geplant. Man sollte wirklich eine Liste der <language> Elemente, wie diese: <list><language>java</language><language>ruby</language></list> werden, anstatt in eine durch Leerzeichen getrennte Liste in ein einzelnes element; es hätte dies trivial zu beantworten, mit count(//language[.='java']).
Auch haben Sie nicht aufgeführt, es in ein Beispiel, aber es könnte javascript erscheinen in der Liste der Sprachen?

InformationsquelleAutor Sathish | 2011-07-13

  1. 6

    Verwenden:

    count(/*/*/list/language[contains(., 'java')])

    Das komplette XSLT-transformation:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
     java -- <xsl:value-of select=
       "count(/*/*/list/language[contains(., 'java')]) "/>
 </xsl:template>
</xsl:stylesheet>

    , wenn angewandt auf das XML-Dokument:

    <mainNode>
    <book>
        <price> 100 </price>
        <city> chennai </city>
        <list>
            <language> c java ruby </language>
        </list>
    </book>
    <book>
        <price> 200 </price>
        <city> banglore </city>
        <list>
            <language> c java </language>
        </list>
    </book>
    <book>
        <price> 300 </price>
        <city> delhi </city>
        <list>
            <language> java ruby </language>
        </list>
    </book>
</mainNode>

    die wollten, das richtige Ergebnis produziert wird:

     java -- 3

    Update:

    Wenn wir zählen alle vorkommen der Zeichenfolge -- nicht nur alle Knoten, die die Zeichenfolge enthalten-hier ist, wie es zu tun:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes"/>
    <xsl:param name="pWord" select="' java '"/>

    <xsl:template match="/">
        <xsl:variable name="vResult">
            <xsl:apply-templates/>
        </xsl:variable>
        <xsl:value-of select="concat($pWord, '--- ')"/>
        <xsl:value-of select="string-length($vResult)"/>
    </xsl:template>

    <xsl:template match="list/language" name="countWord">
        <xsl:param name="pText" select="."/>

        <xsl:if test="contains($pText, $pWord)">
            <xsl:text>X</xsl:text>
            <xsl:call-template name="countWord">
                <xsl:with-param name="pText"
                 select="concat(' ', substring-after($pText, $pWord))"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

    <xsl:template match="text()"/>
</xsl:stylesheet>

    wenn diese transformation, angewandt auf das XML-Dokument:

    <mainNode>
    <book>
        <price> 100 </price>
        <city> chennai </city>
        <list>
            <language> c java ruby </language>
        </list>
    </book>
    <book>
        <price> 200 </price>
        <city> banglore </city>
        <list>
            <language> c java </language>
        </list>
    </book>
    <book>
        <price> 300 </price>
        <city> delhi </city>
        <list>
            <language> java java ruby </language>
        </list>
    </book>
</mainNode>

    die wollten, das richtige Ergebnis produziert wird:

     java --- 4
    Nur aus Neugier, wer downvoted? Es funktioniert gut für die Probe gegeben.
    Dieser code ist die Arbeit gut. Angenommen, der Knoten Sprache enthält mehr als ein java-wie, <language> java-java-ruby <language>. Jetzt sollte die Zählung um 1 erhöht, aber Sie zeigen immer noch 3. Wie man 4?
    Das ist eine ganz andere Frage. Am besten wäre es, toas dies als eine separate Frage. Es ist kurz vor Mitternacht, wo ich bin, also, bitte, erwarten Sie meine Antwort über 8 Stunden ab jetzt.
    Dimitre Novatchev: ok Mann keine probs, pls das für mich tun, ich habe versucht, so viele Male. Ich coudnt bekommen. Dieses Szenario ist für mich sehr wichtig, so versuchen Sie bitte diese....
    Es ist eine ganz andere Antwort, nicht eine andere Frage. Die Frage und der Titel beziehen sich auf das zählen der Anzahl von vorkommen einer Zeichenfolge, nicht die Anzahl der Knoten, die eine Zeichenfolge enthalten.

    InformationsquelleAutor Dimitre Novatchev

  2. 2

    vielleicht können Sie versuchen, diese XSL-Template zu zählen Teilstrings:

    <xsl:template name="substring-count">
  <xsl:param name="string"/>
  <xsl:param name="substr"/>
  <xsl:choose>
    <xsl:when test="contains($string, $substr) and $string and $substr">
      <xsl:variable name="rest">
        <xsl:call-template name="substring-count">
          <xsl:with-param name="string" select="substring-after($string, $substr)"/>
          <xsl:with-param name="substr" select="$substr"/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of select="$rest + 1"/>
    </xsl:when>
    <xsl:otherwise>0</xsl:otherwise>
  </xsl:choose>
</xsl:template>

    Verwendung:

    <xsl:call-template name="substring-count">
  <xsl:with-param name="string" select="'mary had a little lamb'" />
  <xsl:with-param name="substr" select="'lamb'" />
</xsl:call-template>
    Nette Antwort, aber es ist ein Schreibfehler in der Nutzung. Es sollte <xsl:with-param name="string" ....

    InformationsquelleAutor pageman

  3. 1

    Versuchen, diese in eine <xsl:value-of> Aussage:

    count(//language[contains(concat(' ',.,' '), ' java ')])

    Wenn Ihr Dokument-Struktur ist relativ statisch, oder Sie haben Knoten genannt language anderswo, die anderen Zwecken dienen, Sie ersetzen können //language für /mainNode/book/list/language.

    Den concat bit mag ein wenig kompliziert, aber, indem Sie sicher, dass es ein Leerzeichen am Anfang und Ende des Textes, den Sie suchen, und die Suche nach ' java ' mit einem Leerzeichen entweder Seite, werden Sie nicht falsch umfassen andere Bedingungen, die passieren, zu zählen java wie javascript.

    Wenn es möglich ist, mit 'java' zu existieren, mehr als einmal in einem Knoten, dann müssen Sie eine rekursive template. Hier ist eine Möglichkeit:

    <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" />
  <xsl:template match="/">
    <xsl:variable name="list">
      <xsl:for-each select="//language">
        <xsl:call-template name="count">
          <xsl:with-param name="lang">java</xsl:with-param>
        </xsl:call-template>
      </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="concat('java -- ',string-length($list))" />
  </xsl:template>

  <xsl:template name="count">
    <xsl:param name="lang" />
    <xsl:param name="text" select="text()" />
    <xsl:if test="contains(concat(' ',$text,' '),concat(' ',$lang,' '))">
      <xsl:text>0</xsl:text>
      <xsl:call-template name="count">
        <xsl:with-param name="lang" select="$lang" />
        <xsl:with-param name="text" select="substring-after($text,$lang)" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

    Dies ist im wesentlichen erstellt eine Zeichenfolge von 0's, eine für jedes vorkommen von java, und dann nutzt einfach die Länge des Strings.

    Wenn Sie die option XSLT 2.0, können Sie eine Funktion erstellen, die zählt die Anzahl der vorkommen in einem string, und verwenden Sie <xsl:value-of select="sum(mycountfunction(//language))" /> oder etwas ähnliches.

    Als ich wies in einem Kommentar auf Ihre Frage, einer besseren Gestaltung der Quell-XML-hätte erheblich dazu beigetragen; nichts davon ist nötig, wenn jedes vorkommen einer Sprache hatte, es ist ein eigenes element. Natürlich, die außerhalb Ihrer Kontrolle, aber wenn Sie die Möglichkeit haben, dies zu ändern (oder überreden den Anbieter zu ändern) würde ich dringend empfehlen es.

    Seine gute Arbeit. Aus diesem code habe ich erfahren aufrufenden Funktion in XSL. Vielen Dank, Mann.
    Flynn1179::: In der oben genannten Funktion, die Sie haben bestanden "java" als argument. Anstelle von "java" kann ich pass leere Zeichenfolge wie " "? Gewusst wie: übergeben Sie einen leeren string oder char " "?
    Sie können, aber was wäre der Punkt, dass? Ein leerer string übergeben wird wahrscheinlich recurse unendlich und übergeben den Raum geben Ihnen völlig sinnlose Ergebnisse gegeben, dass Sie mit einem Leerzeichen als Trennzeichen.

    InformationsquelleAutor Flynn1179

Schreibe einen Kommentar